dev-libs/gmp/gmp-6.1.2-r1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit flag-o-matic eutils libtool multilib-minimal
   7
   8 MY_PV=${PV/_p*}
   9 MY_PV=${MY_PV/_/-}
  10 MY_P=${PN}-${MY_PV}
  11 PLEVEL=${PV/*p}
  12 DESCRIPTION="Library for arbitrary-precision arithmetic on different type of numbers"
  13 HOMEPAGE="http://gmplib.org/"
  14 SRC_URI="ftp://ftp.gmplib.org/pub/${MY_P}/${MY_P}.tar.xz
  15         mirror://gnu/${PN}/${MY_P}.tar.xz
  16         doc? ( http://gmplib.org/${PN}-man-${MY_PV}.pdf )"
  17
  18 LICENSE="|| ( LGPL-3+ GPL-2+ )"
  19 # The subslot reflects the C & C++ SONAMEs.
  20 SLOT="0/10.4"
  21 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~x64-cygwin ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  22 IUSE="+asm doc cxx static-libs"
  23
  24 DEPEND="sys-devel/m4
  25         app-arch/xz-utils"
  26 RDEPEND=""
  27
  28 S=${WORKDIR}/${MY_P%a}
  29
  30 DOCS=( AUTHORS ChangeLog NEWS README doc/configuration doc/isa_abi_headache )
  31 HTML_DOCS=( doc )
  32 MULTILIB_WRAPPED_HEADERS=( /usr/include/gmp.h )
  33
  34 PATCHES=(
  35         "${FILESDIR}"/${PN}-6.1.0-noexecstack-detect.patch
  36 )
  37
  38 src_prepare() {
  39         default
  40
  41         # note: we cannot run autotools here as gcc depends on this package
  42         elibtoolize
  43
  44         # https://bugs.gentoo.org/536894
  45         if [[ ${CHOST} == *-darwin* ]] ; then
  46                 eapply "${FILESDIR}"/${PN}-6.1.2-gcc-apple-4.0.1.patch
  47         fi
  48
  49         # GMP uses the "ABI" env var during configure as does Gentoo (econf).
  50         # So, to avoid patching the source constantly, wrap things up.
  51         mv configure configure.wrapped || die
  52         cat <<-\EOF > configure
  53         #!/usr/bin/env sh
  54         exec env ABI="${GMPABI}" "$0.wrapped" "$@"
  55         EOF
  56         # Patches to original configure might have lost the +x bit.
  57         chmod a+rx configure{,.wrapped} || die
  58 }
  59
  60 multilib_src_configure() {
  61         # Because of our 32-bit userland, 1.0 is the only HPPA ABI that works
  62         # http://gmplib.org/manual/ABI-and-ISA.html#ABI-and-ISA (bug #344613)
  63         if [[ ${CHOST} == hppa2.0-* ]] ; then
  64                 GMPABI="1.0"
  65         fi
  66
  67         # ABI mappings (needs all architectures supported)
  68         case ${ABI} in
  69                 32|x86)       GMPABI=32;;
  70                 64|amd64|n64) GMPABI=64;;
  71                 [onx]32)      GMPABI=${ABI};;
  72         esac
  73         export GMPABI
  74
  75         #367719
  76         if [[ ${CHOST} == *-mint* ]]; then
  77                 filter-flags -O?
  78         fi
  79
  80         tc-export CC
  81         ECONF_SOURCE="${S}" econf \
  82                 --localstatedir="${EPREFIX}"/var/state/gmp \
  83                 --enable-shared \
  84                 $(use_enable asm assembly) \
  85                 $(use_enable cxx) \
  86                 $(use_enable static-libs static)
  87 }
  88
  89 multilib_src_compile() {
  90         emake
  91 }
  92
  93 multilib_src_test() {
  94         emake check
  95 }
  96
  97 multilib_src_install() {
  98         emake DESTDIR="${D}" install
  99
 100         # should be a standalone lib
 101         rm -f "${ED}"/usr/$(get_libdir)/libgmp.la
 102         # this requires libgmp
 103         local la="${ED}/usr/$(get_libdir)/libgmpxx.la"
 104         use static-libs \
 105                 && sed -i 's:/[^ ]*/libgmp.la:-lgmp:' "${la}" \
 106                 || rm -f "${la}"
 107 }
 108
 109 multilib_src_install_all() {
 110         einstalldocs
 111         use doc && cp "${DISTDIR}"/gmp-man-${MY_PV}.pdf "${ED}"/usr/share/doc/${PF}/
 112 }