dev-libs/glib/glib-2.62.5.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 PYTHON_COMPAT=( python{3_6,3_7} )
   6
   7 inherit flag-o-matic gnome.org gnome2-utils linux-info meson multilib multilib-minimal python-any-r1 toolchain-funcs xdg
   8
   9 DESCRIPTION="The GLib library of C routines"
  10 HOMEPAGE="https://www.gtk.org/"
  11
  12 LICENSE="LGPL-2.1+"
  13 SLOT="2"
  14 IUSE="dbus debug elibc_glibc fam gtk-doc kernel_linux +mime selinux static-libs systemtap test utils xattr"
  15 RESTRICT="!test? ( test )"
  16
  17 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
  18
  19 # * libelf isn't strictly necessary, but makes gresource tool more useful, and
  20 # the check is automagic in gio/meson.build. gresource is not a multilib tool
  21 # right now, thus it doesn't matter if non-native ABI libelf exists or not
  22 # (non-native binary is overwritten, it doesn't matter if libelf was linked to).
  23 # * Technically static-libs is needed on zlib, util-linux and perhaps more, but
  24 # these are used by GIO, which glib[static-libs] consumers don't really seem
  25 # to need at all, thus not imposing the deps for now and once some consumers
  26 # are actually found to static link libgio-2.0.a, we can revisit and either add
  27 # them or just put the (build) deps in that rare consumer instead of recursive
  28 # RDEPEND here (due to lack of recursive DEPEND).
  29 RDEPEND="
  30         !<dev-util/gdbus-codegen-${PV}
  31         >=virtual/libiconv-0-r1[${MULTILIB_USEDEP}]
  32         >=dev-libs/libpcre-8.31:3[${MULTILIB_USEDEP},static-libs?]
  33         >=virtual/libffi-3.0.13-r1:=[${MULTILIB_USEDEP}]
  34         >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
  35         >=virtual/libintl-0-r2[${MULTILIB_USEDEP}]
  36         kernel_linux? ( >=sys-apps/util-linux-2.23[${MULTILIB_USEDEP}] )
  37         selinux? ( >=sys-libs/libselinux-2.2.2-r5[${MULTILIB_USEDEP}] )
  38         xattr? ( !elibc_glibc? ( >=sys-apps/attr-2.4.47-r1[${MULTILIB_USEDEP}] ) )
  39         virtual/libelf:0=
  40         fam? ( >=virtual/fam-0-r1[${MULTILIB_USEDEP}] )
  41 "
  42 DEPEND="${RDEPEND}"
  43 # libxml2 used for optional tests that get automatically skipped
  44 BDEPEND="
  45         app-text/docbook-xsl-stylesheets
  46         dev-libs/libxslt
  47         >=sys-devel/gettext-0.19.8
  48         gtk-doc? ( >=dev-util/gtk-doc-1.20
  49                 app-text/docbook-xml-dtd:4.2
  50                 app-text/docbook-xml-dtd:4.5 )
  51         systemtap? ( >=dev-util/systemtap-1.3 )
  52         ${PYTHON_DEPS}
  53         test? ( >=sys-apps/dbus-1.2.14 )
  54         virtual/pkgconfig[${MULTILIB_USEDEP}]
  55 "
  56 # TODO: >=dev-util/gdbus-codegen-${PV} test dep once we modify gio/tests/meson.build to use external gdbus-codegen
  57
  58 PDEPEND="
  59         dbus? ( gnome-base/dconf )
  60         mime? ( x11-misc/shared-mime-info )
  61 "
  62 # shared-mime-info needed for gio/xdgmime, bug #409481
  63 # dconf is needed to be able to save settings, bug #498436
  64
  65 MULTILIB_CHOST_TOOLS=(
  66         /usr/bin/gio-querymodules$(get_exeext)
  67 )
  68
  69 pkg_setup() {
  70         if use kernel_linux ; then
  71                 CONFIG_CHECK="~INOTIFY_USER"
  72                 if use test ; then
  73                         CONFIG_CHECK="~IPV6"
  74                         WARNING_IPV6="Your kernel needs IPV6 support for running some tests, skipping them."
  75                 fi
  76                 linux-info_pkg_setup
  77         fi
  78         python-any-r1_pkg_setup
  79 }
  80
  81 src_prepare() {
  82         if use test; then
  83                 # TODO: Review the test exclusions, especially now with meson
  84                 # Disable tests requiring dev-util/desktop-file-utils when not installed, bug #286629, upstream bug #629163
  85                 if ! has_version dev-util/desktop-file-utils ; then
  86                         ewarn "Some tests will be skipped due dev-util/desktop-file-utils not being present on your system,"
  87                         ewarn "think on installing it to get these tests run."
  88                         sed -i -e "/appinfo\/associations/d" gio/tests/appinfo.c || die
  89                         sed -i -e "/g_test_add_func/d" gio/tests/desktop-app-info.c || die
  90                 fi
  91
  92                 # gdesktopappinfo requires existing terminal (gnome-terminal or any
  93                 # other), falling back to xterm if one doesn't exist
  94                 #if ! has_version x11-terms/xterm && ! has_version x11-terms/gnome-terminal ; then
  95                 #       ewarn "Some tests will be skipped due to missing terminal program"
  96                 # These tests seem to sometimes fail even with a terminal; skip for now and reevulate with meson
  97                 # Also try https://gitlab.gnome.org/GNOME/glib/issues/1601 once ready for backport (or in a bump) and file new issue if still fails
  98                 sed -i -e "/appinfo\/launch/d" gio/tests/appinfo.c || die
  99                 # desktop-app-info/launch* might fail similarly
 100                 sed -i -e "/desktop-app-info\/launch-as-manager/d" gio/tests/desktop-app-info.c || die
 101                 #fi
 102
 103                 # https://bugzilla.gnome.org/show_bug.cgi?id=722604
 104                 sed -i -e "/timer\/stop/d" glib/tests/timer.c || die
 105                 sed -i -e "/timer\/basic/d" glib/tests/timer.c || die
 106
 107                 ewarn "Tests for search-utils have been skipped"
 108                 sed -i -e "/search-utils/d" glib/tests/meson.build || die
 109
 110                 # Play nice with network-sandbox, but this approach would defeat the purpose of the test
 111                 #sed -i -e "s/localhost/127.0.0.1/g" gio/tests/gsocketclient-slow.c || die
 112         else
 113                 # Don't build tests, also prevents extra deps, bug #512022
 114                 sed -i -e '/subdir.*tests/d' {.,gio,glib}/meson.build || die
 115         fi
 116
 117         # Don't build fuzzing binaries - not used
 118         sed -i -e '/subdir.*fuzzing/d' meson.build || die
 119
 120         # gdbus-codegen is a separate package
 121         sed -i -e '/install_dir/d' gio/gdbus-2.0/codegen/meson.build || die
 122
 123         # Same kind of meson-0.50 issue with some installed-tests files; will likely be fixed upstream soon
 124         sed -i -e '/install_dir/d' gio/tests/meson.build || die
 125
 126         cat > "${T}/glib-test-ld-wrapper" <<-EOF
 127                 #!/usr/bin/env sh
 128                 exec \${LD:-ld} "\$@"
 129         EOF
 130         chmod a+x "${T}/glib-test-ld-wrapper" || die
 131         sed -i -e "s|'ld'|'${T}/glib-test-ld-wrapper'|g" gio/tests/meson.build || die
 132
 133         xdg_src_prepare
 134         gnome2_environment_reset
 135         # TODO: python_name sedding for correct python shebang? Might be relevant mainly for glib-utils only
 136 }
 137
 138 multilib_src_configure() {
 139         if use debug; then
 140                 append-cflags -DG_ENABLE_DEBUG
 141         else
 142                 append-cflags -DG_DISABLE_CAST_CHECKS # https://gitlab.gnome.org/GNOME/glib/issues/1833
 143         fi
 144
 145         # TODO: figure a way to pass appropriate values for all cross properties that glib uses (search for get_cross_property)
 146         #if tc-is-cross-compiler ; then
 147                 # https://bugzilla.gnome.org/show_bug.cgi?id=756473
 148                 # TODO-meson: This should be in meson cross file as 'growing_stack' property; and more, look at get_cross_property
 149                 #case ${CHOST} in
 150                 #hppa*|metag*) export glib_cv_stack_grows=yes ;;
 151                 #*)            export glib_cv_stack_grows=no ;;
 152                 #esac
 153         #fi
 154
 155         local emesonargs=(
 156                 -Ddefault_library=$(usex static-libs both shared)
 157                 $(meson_feature selinux)
 158                 $(meson_use xattr)
 159                 -Dlibmount=true # only used if host_system == 'linux'
 160                 -Dinternal_pcre=false
 161                 -Dman=true
 162                 $(meson_use systemtap dtrace)
 163                 $(meson_use systemtap)
 164                 -Dgtk_doc=$(multilib_native_usex gtk-doc true false)
 165                 $(meson_use fam)
 166                 -Dinstalled_tests=false
 167                 -Dnls=enabled
 168                 -Doss_fuzz=disabled
 169         )
 170         meson_src_configure
 171 }
 172
 173 multilib_src_compile() {
 174         meson_src_compile
 175 }
 176
 177 multilib_src_test() {
 178         export XDG_CONFIG_DIRS=/etc/xdg
 179         export XDG_DATA_DIRS=/usr/local/share:/usr/share
 180         export G_DBUS_COOKIE_SHA1_KEYRING_DIR="${T}/temp"
 181         export LC_TIME=C # bug #411967
 182         unset GSETTINGS_BACKEND # bug #596380
 183         python_setup
 184
 185         # Related test is a bit nitpicking
 186         mkdir "$G_DBUS_COOKIE_SHA1_KEYRING_DIR"
 187         chmod 0700 "$G_DBUS_COOKIE_SHA1_KEYRING_DIR"
 188
 189         meson_src_test --timeout-multiplier 2 --no-suite flaky
 190 }
 191
 192 multilib_src_install() {
 193         meson_src_install
 194         keepdir /usr/$(get_libdir)/gio/modules
 195 }
 196
 197 multilib_src_install_all() {
 198         einstalldocs
 199
 200         # These are installed by dev-util/glib-utils
 201         # TODO: With patching we might be able to get rid of the python-any deps and removals, and test depend on glib-utils instead; revisit now with meson
 202         rm "${ED}/usr/bin/glib-genmarshal" || die
 203         rm "${ED}/usr/share/man/man1/glib-genmarshal.1" || die
 204         rm "${ED}/usr/bin/glib-mkenums" || die
 205         rm "${ED}/usr/share/man/man1/glib-mkenums.1" || die
 206         rm "${ED}/usr/bin/gtester-report" || die
 207         rm "${ED}/usr/share/man/man1/gtester-report.1" || die
 208         # gdbus-codegen manpage installed by dev-util/gdbus-codegen
 209         rm "${ED}/usr/share/man/man1/gdbus-codegen.1" || die
 210 }
 211
 212 pkg_preinst() {
 213         xdg_pkg_preinst
 214
 215         # Make gschemas.compiled belong to glib alone
 216         local cache="/usr/share/glib-2.0/schemas/gschemas.compiled"
 217
 218         if [[ -e ${EROOT}${cache} ]]; then
 219                 cp "${EROOT}"${cache} "${ED}"/${cache} || die
 220         else
 221                 touch "${ED}"${cache} || die
 222         fi
 223
 224         multilib_pkg_preinst() {
 225                 # Make giomodule.cache belong to glib alone
 226                 local cache="/usr/$(get_libdir)/gio/modules/giomodule.cache"
 227
 228                 if [[ -e ${EROOT}${cache} ]]; then
 229                         cp "${EROOT}"${cache} "${ED}"${cache} || die
 230                 else
 231                         touch "${ED}"${cache} || die
 232                 fi
 233         }
 234
 235         # Don't run the cache ownership when cross-compiling, as it would end up with an empty cache
 236         # file due to inability to create it and GIO might not look at any of the modules there
 237         if ! tc-is-cross-compiler ; then
 238                 multilib_foreach_abi multilib_pkg_preinst
 239         fi
 240 }
 241
 242 pkg_postinst() {
 243         xdg_pkg_postinst
 244         # glib installs no schemas itself, but we force update for fresh install in case
 245         # something has dropped in a schemas file without direct glib dep; and for upgrades
 246         # in case the compiled schema format could have changed
 247         gnome2_schemas_update
 248
 249         multilib_pkg_postinst() {
 250                 gnome2_giomodule_cache_update \
 251                         || die "Update GIO modules cache failed (for ${ABI})"
 252         }
 253         if ! tc-is-cross-compiler ; then
 254                 multilib_foreach_abi multilib_pkg_postinst
 255         else
 256                 ewarn "Updating of GIO modules cache skipped due to cross-compilation."
 257                 ewarn "You might want to run gio-querymodules manually on the target for"
 258                 ewarn "your final image for performance reasons and re-run it when packages"
 259                 ewarn "installing GIO modules get upgraded or added to the image."
 260         fi
 261 }
 262
 263 pkg_postrm() {
 264         xdg_pkg_postrm
 265         gnome2_schemas_update
 266
 267         if [[ -z ${REPLACED_BY_VERSION} ]]; then
 268                 multilib_pkg_postrm() {
 269                         rm -f "${EROOT}"/usr/$(get_libdir)/gio/modules/giomodule.cache
 270                 }
 271                 multilib_foreach_abi multilib_pkg_postrm
 272                 rm -f "${EROOT}"/usr/share/glib-2.0/schemas/gschemas.compiled
 273         fi
 274 }