dev-libs/glib/glib-2.60.7-r2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 PYTHON_COMPAT=( python{3_6,3_7} )
   6
   7 inherit flag-o-matic gnome.org gnome2-utils linux-info meson multilib multilib-minimal python-any-r1 toolchain-funcs xdg
   8
   9 DESCRIPTION="The GLib library of C routines"
  10 HOMEPAGE="https://www.gtk.org/"
  11
  12 LICENSE="LGPL-2.1+"
  13 SLOT="2"
  14 IUSE="dbus debug elibc_glibc fam gtk-doc kernel_linux +mime selinux static-libs systemtap test utils xattr"
  15 RESTRICT="!test? ( test )"
  16
  17 KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv s390 sparc x86 ~amd64-linux ~x86-linux"
  18
  19 # * libelf isn't strictly necessary, but makes gresource tool more useful, and
  20 # the check is automagic in gio/meson.build. gresource is not a multilib tool
  21 # right now, thus it doesn't matter if non-native ABI libelf exists or not
  22 # (non-native binary is overwritten, it doesn't matter if libelf was linked to).
  23 # * Technically static-libs is needed on zlib, util-linux and perhaps more, but
  24 # these are used by GIO, which glib[static-libs] consumers don't really seem
  25 # to need at all, thus not imposing the deps for now and once some consumers
  26 # are actually found to static link libgio-2.0.a, we can revisit and either add
  27 # them or just put the (build) deps in that rare consumer instead of recursive
  28 # RDEPEND here (due to lack of recursive DEPEND).
  29 RDEPEND="
  30         !<dev-util/gdbus-codegen-${PV}
  31         >=virtual/libiconv-0-r1[${MULTILIB_USEDEP}]
  32         >=dev-libs/libpcre-8.31:3[${MULTILIB_USEDEP},static-libs?]
  33         >=virtual/libffi-3.0.13-r1:=[${MULTILIB_USEDEP}]
  34         >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
  35         >=virtual/libintl-0-r2[${MULTILIB_USEDEP}]
  36         kernel_linux? ( >=sys-apps/util-linux-2.23[${MULTILIB_USEDEP}] )
  37         selinux? ( >=sys-libs/libselinux-2.2.2-r5[${MULTILIB_USEDEP}] )
  38         xattr? ( !elibc_glibc? ( >=sys-apps/attr-2.4.47-r1[${MULTILIB_USEDEP}] ) )
  39         virtual/libelf:0=
  40         fam? ( >=virtual/fam-0-r1[${MULTILIB_USEDEP}] )
  41 "
  42 DEPEND="${RDEPEND}"
  43 # libxml2 used for optional tests that get automatically skipped
  44 BDEPEND="
  45         app-text/docbook-xsl-stylesheets
  46         dev-libs/libxslt
  47         >=sys-devel/gettext-0.19.8
  48         gtk-doc? ( >=dev-util/gtk-doc-1.20
  49                 app-text/docbook-xml-dtd:4.2
  50                 app-text/docbook-xml-dtd:4.5 )
  51         systemtap? ( >=dev-util/systemtap-1.3 )
  52         ${PYTHON_DEPS}
  53         test? ( >=sys-apps/dbus-1.2.14 )
  54         virtual/pkgconfig[${MULTILIB_USEDEP}]
  55 "
  56 # TODO: >=dev-util/gdbus-codegen-${PV} test dep once we modify gio/tests/meson.build to use external gdbus-codegen
  57
  58 PDEPEND="
  59         dbus? ( gnome-base/dconf )
  60         mime? ( x11-misc/shared-mime-info )
  61 "
  62 # shared-mime-info needed for gio/xdgmime, bug #409481
  63 # dconf is needed to be able to save settings, bug #498436
  64
  65 MULTILIB_CHOST_TOOLS=(
  66         /usr/bin/gio-querymodules$(get_exeext)
  67 )
  68
  69 pkg_setup() {
  70         if use kernel_linux ; then
  71                 CONFIG_CHECK="~INOTIFY_USER"
  72                 if use test ; then
  73                         CONFIG_CHECK="~IPV6"
  74                         WARNING_IPV6="Your kernel needs IPV6 support for running some tests, skipping them."
  75                 fi
  76                 linux-info_pkg_setup
  77         fi
  78         python-any-r1_pkg_setup
  79 }
  80
  81 src_prepare() {
  82         eapply "${FILESDIR}"/${PV}-gdbus-fixes.patch #700538, included in 2.62.3+
  83         eapply "${FILESDIR}"/CVE-2020-6750.patch
  84
  85         if use test; then
  86                 # TODO: Review the test exclusions, especially now with meson
  87                 # Disable tests requiring dev-util/desktop-file-utils when not installed, bug #286629, upstream bug #629163
  88                 if ! has_version dev-util/desktop-file-utils ; then
  89                         ewarn "Some tests will be skipped due dev-util/desktop-file-utils not being present on your system,"
  90                         ewarn "think on installing it to get these tests run."
  91                         sed -i -e "/appinfo\/associations/d" gio/tests/appinfo.c || die
  92                         sed -i -e "/g_test_add_func/d" gio/tests/desktop-app-info.c || die
  93                 fi
  94
  95                 # gdesktopappinfo requires existing terminal (gnome-terminal or any
  96                 # other), falling back to xterm if one doesn't exist
  97                 #if ! has_version x11-terms/xterm && ! has_version x11-terms/gnome-terminal ; then
  98                 #       ewarn "Some tests will be skipped due to missing terminal program"
  99                 # These tests seem to sometimes fail even with a terminal; skip for now and reevulate with meson
 100                 # Also try https://gitlab.gnome.org/GNOME/glib/issues/1601 once ready for backport (or in a bump) and file new issue if still fails
 101                 sed -i -e "/appinfo\/launch/d" gio/tests/appinfo.c || die
 102                 # desktop-app-info/launch* might fail similarly
 103                 sed -i -e "/desktop-app-info\/launch-as-manager/d" gio/tests/desktop-app-info.c || die
 104                 #fi
 105
 106                 # https://bugzilla.gnome.org/show_bug.cgi?id=722604
 107                 sed -i -e "/timer\/stop/d" glib/tests/timer.c || die
 108                 sed -i -e "/timer\/basic/d" glib/tests/timer.c || die
 109
 110                 ewarn "Tests for search-utils have been skipped"
 111                 sed -i -e "/search-utils/d" glib/tests/meson.build || die
 112
 113                 # Play nice with network-sandbox, but this approach would defeat the purpose of the test
 114                 #sed -i -e "s/localhost/127.0.0.1/g" gio/tests/gsocketclient-slow.c || die
 115         else
 116                 # Don't build tests, also prevents extra deps, bug #512022
 117                 sed -i -e '/subdir.*tests/d' {.,gio,glib}/meson.build || die
 118         fi
 119
 120         # Don't build fuzzing binaries - not used
 121         sed -i -e '/subdir.*fuzzing/d' meson.build || die
 122
 123         # gdbus-codegen is a separate package
 124         sed -i -e 's/install.*true/install : false/g' gio/gdbus-2.0/codegen/meson.build || die
 125         # Older than meson-0.50 doesn't know about install kwarg for configure_file; for that we need to remove the install_dir kwarg.
 126         # Upstream will remove the install kwarg in a future version to require only meson-0.49.2 or newer, at which point the
 127         # install_dir removal only should be kept.
 128         sed -i -e '/install_dir/d' gio/gdbus-2.0/codegen/meson.build || die
 129
 130         # Same kind of meson-0.50 issue with some installed-tests files; will likely be fixed upstream soon
 131         sed -i -e '/install_dir/d' gio/tests/meson.build || die
 132
 133         cat > "${T}/glib-test-ld-wrapper" <<-EOF
 134                 #!/usr/bin/env sh
 135                 exec \${LD:-ld} "\$@"
 136         EOF
 137         chmod a+x "${T}/glib-test-ld-wrapper" || die
 138         sed -i -e "s|'ld'|'${T}/glib-test-ld-wrapper'|g" gio/tests/meson.build || die
 139
 140         xdg_src_prepare
 141         gnome2_environment_reset
 142         # TODO: python_name sedding for correct python shebang? Might be relevant mainly for glib-utils only
 143 }
 144
 145 multilib_src_configure() {
 146         if use debug; then
 147                 append-cflags -DG_ENABLE_DEBUG
 148         else
 149                 append-cflags -DG_DISABLE_CAST_CHECKS # https://gitlab.gnome.org/GNOME/glib/issues/1833
 150         fi
 151
 152         # TODO: figure a way to pass appropriate values for all cross properties that glib uses (search for get_cross_property)
 153         #if tc-is-cross-compiler ; then
 154                 # https://bugzilla.gnome.org/show_bug.cgi?id=756473
 155                 # TODO-meson: This should be in meson cross file as 'growing_stack' property; and more, look at get_cross_property
 156                 #case ${CHOST} in
 157                 #hppa*|metag*) export glib_cv_stack_grows=yes ;;
 158                 #*)            export glib_cv_stack_grows=no ;;
 159                 #esac
 160         #fi
 161
 162         local emesonargs=(
 163                 -Ddefault_library=$(usex static-libs both shared)
 164                 $(meson_feature selinux)
 165                 $(meson_use xattr)
 166                 -Dlibmount=true # only used if host_system == 'linux'
 167                 -Dinternal_pcre=false
 168                 -Dman=true
 169                 $(meson_use systemtap dtrace)
 170                 $(meson_use systemtap)
 171                 -Dgtk_doc=$(multilib_native_usex gtk-doc true false)
 172                 $(meson_use fam)
 173                 -Dinstalled_tests=false
 174                 -Dnls=enabled
 175         )
 176         meson_src_configure
 177 }
 178
 179 multilib_src_compile() {
 180         meson_src_compile
 181 }
 182
 183 multilib_src_test() {
 184         export XDG_CONFIG_DIRS=/etc/xdg
 185         export XDG_DATA_DIRS=/usr/local/share:/usr/share
 186         export G_DBUS_COOKIE_SHA1_KEYRING_DIR="${T}/temp"
 187         export LC_TIME=C # bug #411967
 188         unset GSETTINGS_BACKEND # bug #596380
 189         python_setup
 190
 191         # Related test is a bit nitpicking
 192         mkdir "$G_DBUS_COOKIE_SHA1_KEYRING_DIR"
 193         chmod 0700 "$G_DBUS_COOKIE_SHA1_KEYRING_DIR"
 194
 195         meson_src_test --timeout-multiplier 2 --no-suite flaky
 196 }
 197
 198 multilib_src_install() {
 199         meson_src_install
 200         keepdir /usr/$(get_libdir)/gio/modules
 201 }
 202
 203 multilib_src_install_all() {
 204         einstalldocs
 205
 206         # These are installed by dev-util/glib-utils
 207         # TODO: With patching we might be able to get rid of the python-any deps and removals, and test depend on glib-utils instead; revisit now with meson
 208         rm "${ED}/usr/bin/glib-genmarshal" || die
 209         rm "${ED}/usr/share/man/man1/glib-genmarshal.1" || die
 210         rm "${ED}/usr/bin/glib-mkenums" || die
 211         rm "${ED}/usr/share/man/man1/glib-mkenums.1" || die
 212         rm "${ED}/usr/bin/gtester-report" || die
 213         rm "${ED}/usr/share/man/man1/gtester-report.1" || die
 214         # gdbus-codegen manpage installed by dev-util/gdbus-codegen
 215         rm "${ED}/usr/share/man/man1/gdbus-codegen.1" || die
 216 }
 217
 218 pkg_preinst() {
 219         xdg_pkg_preinst
 220
 221         # Make gschemas.compiled belong to glib alone
 222         local cache="/usr/share/glib-2.0/schemas/gschemas.compiled"
 223
 224         if [[ -e ${EROOT}${cache} ]]; then
 225                 cp "${EROOT}"${cache} "${ED}"/${cache} || die
 226         else
 227                 touch "${ED}"${cache} || die
 228         fi
 229
 230         multilib_pkg_preinst() {
 231                 # Make giomodule.cache belong to glib alone
 232                 local cache="/usr/$(get_libdir)/gio/modules/giomodule.cache"
 233
 234                 if [[ -e ${EROOT}${cache} ]]; then
 235                         cp "${EROOT}"${cache} "${ED}"${cache} || die
 236                 else
 237                         touch "${ED}"${cache} || die
 238                 fi
 239         }
 240
 241         # Don't run the cache ownership when cross-compiling, as it would end up with an empty cache
 242         # file due to inability to create it and GIO might not look at any of the modules there
 243         if ! tc-is-cross-compiler ; then
 244                 multilib_foreach_abi multilib_pkg_preinst
 245         fi
 246 }
 247
 248 pkg_postinst() {
 249         xdg_pkg_postinst
 250         # glib installs no schemas itself, but we force update for fresh install in case
 251         # something has dropped in a schemas file without direct glib dep; and for upgrades
 252         # in case the compiled schema format could have changed
 253         gnome2_schemas_update
 254
 255         multilib_pkg_postinst() {
 256                 gnome2_giomodule_cache_update \
 257                         || die "Update GIO modules cache failed (for ${ABI})"
 258         }
 259         if ! tc-is-cross-compiler ; then
 260                 multilib_foreach_abi multilib_pkg_postinst
 261         else
 262                 ewarn "Updating of GIO modules cache skipped due to cross-compilation."
 263                 ewarn "You might want to run gio-querymodules manually on the target for"
 264                 ewarn "your final image for performance reasons and re-run it when packages"
 265                 ewarn "installing GIO modules get upgraded or added to the image."
 266         fi
 267 }
 268
 269 pkg_postrm() {
 270         xdg_pkg_postrm
 271         gnome2_schemas_update
 272
 273         if [[ -z ${REPLACED_BY_VERSION} ]]; then
 274                 multilib_pkg_postrm() {
 275                         rm -f "${EROOT}"/usr/$(get_libdir)/gio/modules/giomodule.cache
 276                 }
 277                 multilib_foreach_abi multilib_pkg_postrm
 278                 rm -f "${EROOT}"/usr/share/glib-2.0/schemas/gschemas.compiled
 279         fi
 280 }