dev-libs/glib/glib-2.58.3-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} )
   6 GNOME2_EAUTORECONF=yes
   7
   8 inherit autotools bash-completion-r1 epunt-cxx flag-o-matic gnome2 libtool linux-info \
   9         multilib multilib-minimal pax-utils python-any-r1 toolchain-funcs virtualx
  10
  11 # Until bug #537330 glib is a reverse dependency of pkgconfig and, then
  12 # adding new dependencies end up making stage3 to grow. Every addition needs
  13 # then to be think very closely.
  14
  15 DESCRIPTION="The GLib library of C routines"
  16 HOMEPAGE="https://www.gtk.org/"
  17 SRC_URI="${SRC_URI}
  18         https://pkgconfig.freedesktop.org/releases/pkg-config-0.28.tar.gz" # pkg.m4 for eautoreconf
  19
  20 LICENSE="LGPL-2.1+"
  21 SLOT="2"
  22 IUSE="dbus debug fam gtk-doc kernel_linux +mime selinux static-libs systemtap test utils xattr"
  23
  24 KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~m68k ~mips ppc ppc64 ~riscv s390 ~sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
  25
  26 # Added util-linux multilib dependency to have libmount support (which
  27 # is always turned on on linux systems, unless explicitly disabled, but
  28 # this ebuild does not do that anyway) (bug #599586)
  29
  30 RDEPEND="
  31         !<dev-util/gdbus-codegen-${PV}
  32         >=dev-libs/libpcre-8.31:3[${MULTILIB_USEDEP},static-libs?]
  33         >=virtual/libiconv-0-r1[${MULTILIB_USEDEP}]
  34         >=virtual/libffi-3.0.13-r1:=[${MULTILIB_USEDEP}]
  35         >=virtual/libintl-0-r2[${MULTILIB_USEDEP}]
  36         >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
  37         kernel_linux? ( >=sys-apps/util-linux-2.23[${MULTILIB_USEDEP}] )
  38         selinux? ( >=sys-libs/libselinux-2.2.2-r5[${MULTILIB_USEDEP}] )
  39         xattr? ( >=sys-apps/attr-2.4.47-r1[${MULTILIB_USEDEP}] )
  40         fam? ( >=virtual/fam-0-r1[${MULTILIB_USEDEP}] )
  41         utils? (
  42                 >=dev-util/gdbus-codegen-${PV}
  43                 virtual/libelf:0=
  44         )
  45 "
  46 DEPEND="${RDEPEND}
  47         app-text/docbook-xml-dtd:4.1.2
  48         app-text/docbook-xsl-stylesheets
  49         >=dev-libs/libxslt-1.0
  50         >=sys-devel/gettext-0.11
  51         gtk-doc? ( >=dev-util/gtk-doc-1.20 )
  52         systemtap? ( >=dev-util/systemtap-1.3 )
  53         ${PYTHON_DEPS}
  54         test? (
  55                 sys-devel/gdb
  56                 >=dev-util/gdbus-codegen-${PV}
  57                 >=sys-apps/dbus-1.2.14 )
  58 "
  59 # configure.ac has gtk-doc-am stuff behind m4_ifdef, so we don't need a gtk-doc-am build dep
  60
  61 # Migration of glib-genmarshal, glib-mkenums and gtester-report to a separate
  62 # python depending package, which can be buildtime depended in packages that
  63 # need these tools, without pulling in python at runtime.
  64 RDEPEND="${RDEPEND}
  65         >=dev-util/glib-utils-${PV}"
  66 PDEPEND="
  67         dbus? ( gnome-base/dconf )
  68         mime? ( x11-misc/shared-mime-info )
  69 "
  70 # shared-mime-info needed for gio/xdgmime, bug #409481
  71 # dconf is needed to be able to save settings, bug #498436
  72
  73 MULTILIB_CHOST_TOOLS=(
  74         /usr/bin/gio-querymodules$(get_exeext)
  75 )
  76
  77 pkg_setup() {
  78         if use kernel_linux ; then
  79                 CONFIG_CHECK="~INOTIFY_USER"
  80                 if use test ; then
  81                         CONFIG_CHECK="~IPV6"
  82                         WARNING_IPV6="Your kernel needs IPV6 support for running some tests, skipping them."
  83                 fi
  84                 linux-info_pkg_setup
  85         fi
  86         python-any-r1_pkg_setup
  87 }
  88
  89 src_prepare() {
  90         # Prevent build failure in stage3 where pkgconfig is not available, bug #481056
  91         mv -f "${WORKDIR}"/pkg-config-*/pkg.m4 "${S}"/m4macros/ || die
  92
  93         if use test; then
  94                 # Disable tests requiring dev-util/desktop-file-utils when not installed, bug #286629, upstream bug #629163
  95                 if ! has_version dev-util/desktop-file-utils ; then
  96                         ewarn "Some tests will be skipped due dev-util/desktop-file-utils not being present on your system,"
  97                         ewarn "think on installing it to get these tests run."
  98                         sed -i -e "/appinfo\/associations/d" gio/tests/appinfo.c || die
  99                         sed -i -e "/g_test_add_func/d" gio/tests/desktop-app-info.c || die
 100                 fi
 101
 102                 # gdesktopappinfo requires existing terminal (gnome-terminal or any
 103                 # other), falling back to xterm if one doesn't exist
 104                 #if ! has_version x11-terms/xterm && ! has_version x11-terms/gnome-terminal ; then
 105                 #       ewarn "Some tests will be skipped due to missing terminal program"
 106                 # These tests seem to sometimes fail even with a terminal; skip for now and reevulate with meson
 107                 # Also try https://gitlab.gnome.org/GNOME/glib/issues/1601 once ready for backport (or in a bump) and file new issue if still fails
 108                 sed -i -e "/appinfo\/launch/d" gio/tests/appinfo.c || die
 109                 # desktop-app-info/launch* might fail similarly
 110                 sed -i -e "/desktop-app-info\/launch-as-manager/d" gio/tests/desktop-app-info.c || die
 111                 #fi
 112
 113                 # https://bugzilla.gnome.org/show_bug.cgi?id=722604
 114                 sed -i -e "/timer\/stop/d" glib/tests/timer.c || die
 115                 sed -i -e "/timer\/basic/d" glib/tests/timer.c || die
 116
 117                 ewarn "Tests for search-utils have been skipped"
 118                 sed -i -e "/search-utils/d" glib/tests/Makefile.am || die
 119         else
 120                 # Don't build tests, also prevents extra deps, bug #512022
 121                 sed -i -e 's/ tests//' {.,gio,glib}/Makefile.am || die
 122         fi
 123
 124         # gdbus-codegen is a separate package
 125         eapply "${FILESDIR}"/${PN}-2.58.2-external-gdbus-codegen.patch
 126
 127         # gdbus message upper limit check fix from glib-2-58
 128         eapply "${FILESDIR}"/${PV}-gdbusmessage-limit-fix.patch
 129         # gfile copy fallback security fix (wrong permissions at start)
 130         eapply "${FILESDIR}"/${PV}-CVE-2019-12450.patch
 131
 132         # Tarball doesn't come with gtk-doc.make and we can't unconditionally depend on dev-util/gtk-doc due
 133         # to circular deps during bootstramp. If actually not building gtk-doc, an almost empty file will do
 134         # fine as well - this is also what upstream autogen.sh does if gtkdocize is not found. If gtk-doc is
 135         # installed, eautoreconf will call gtkdocize, which overwrites the empty gtk-doc.make with a full copy.
 136         cat > gtk-doc.make << EOF
 137 EXTRA_DIST =
 138 CLEANFILES =
 139 EOF
 140
 141         gnome2_src_prepare
 142         epunt_cxx
 143 }
 144
 145 multilib_src_configure() {
 146         # Avoid circular depend with dev-util/pkgconfig and
 147         # native builds (cross-compiles won't need pkg-config
 148         # in the target ROOT to work here)
 149         if ! tc-is-cross-compiler && ! $(tc-getPKG_CONFIG) --version >& /dev/null; then
 150                 if has_version sys-apps/dbus; then
 151                         export DBUS1_CFLAGS="-I/usr/include/dbus-1.0 -I/usr/$(get_libdir)/dbus-1.0/include"
 152                         export DBUS1_LIBS="-ldbus-1"
 153                 fi
 154                 export LIBFFI_CFLAGS="-I$(echo /usr/$(get_libdir)/libffi-*/include)"
 155                 export LIBFFI_LIBS="-lffi"
 156                 export PCRE_CFLAGS=" " # test -n "$PCRE_CFLAGS" needs to pass
 157                 export PCRE_LIBS="-lpcre"
 158         fi
 159
 160         # These configure tests don't work when cross-compiling.
 161         if tc-is-cross-compiler ; then
 162                 # https://bugzilla.gnome.org/show_bug.cgi?id=756473
 163                 case ${CHOST} in
 164                 hppa*|metag*) export glib_cv_stack_grows=yes ;;
 165                 *)            export glib_cv_stack_grows=no ;;
 166                 esac
 167                 # https://bugzilla.gnome.org/show_bug.cgi?id=756474
 168                 export glib_cv_uscore=no
 169                 # https://bugzilla.gnome.org/show_bug.cgi?id=756475
 170                 export ac_cv_func_posix_get{pwuid,grgid}_r=yes
 171         fi
 172
 173         local myconf
 174
 175         case "${CHOST}" in
 176                 *-mingw*) myconf="${myconf} --with-threads=win32" ;;
 177                 *)        myconf="${myconf} --with-threads=posix" ;;
 178         esac
 179
 180         # libelf used only by the gresource bin
 181         ECONF_SOURCE="${S}" gnome2_src_configure ${myconf} \
 182                 $(usex debug --enable-debug=yes ' ') \
 183                 $(use_enable xattr) \
 184                 $(use_enable fam) \
 185                 $(multilib_native_use_enable gtk-doc) \
 186                 $(use_enable kernel_linux libmount) \
 187                 $(use_enable selinux) \
 188                 $(use_enable static-libs static) \
 189                 $(use_enable systemtap dtrace) \
 190                 $(use_enable systemtap systemtap) \
 191                 $(multilib_native_use_enable utils libelf) \
 192                 --with-python=${EPYTHON} \
 193                 --disable-compile-warnings \
 194                 --enable-man \
 195                 --with-pcre=system \
 196                 --with-xml-catalog="${EPREFIX}/etc/xml/catalog"
 197
 198         if multilib_is_native_abi; then
 199                 local d
 200                 for d in glib gio gobject; do
 201                         ln -s "${S}"/docs/reference/${d}/html docs/reference/${d}/html || die
 202                 done
 203         fi
 204 }
 205
 206 multilib_src_test() {
 207         export XDG_CONFIG_DIRS=/etc/xdg
 208         export XDG_DATA_DIRS=/usr/local/share:/usr/share
 209         export G_DBUS_COOKIE_SHA1_KEYRING_DIR="${T}/temp"
 210         export LC_TIME=C # bug #411967
 211         unset GSETTINGS_BACKEND # bug #596380
 212         python_setup
 213
 214         # Related test is a bit nitpicking
 215         mkdir "$G_DBUS_COOKIE_SHA1_KEYRING_DIR"
 216         chmod 0700 "$G_DBUS_COOKIE_SHA1_KEYRING_DIR"
 217
 218         # Hardened: gdb needs this, bug #338891
 219         if host-is-pax ; then
 220                 pax-mark -mr "${BUILD_DIR}"/tests/.libs/assert-msg-test \
 221                         || die "Hardened adjustment failed"
 222         fi
 223
 224         # Need X for dbus-launch session X11 initialization
 225         virtx emake check
 226 }
 227
 228 multilib_src_install() {
 229         emake DESTDIR="${D}" completiondir="$(get_bashcompdir)" install
 230         keepdir /usr/$(get_libdir)/gio/modules
 231 }
 232
 233 multilib_src_install_all() {
 234         einstalldocs
 235
 236         # These are installed by dev-util/glib-utils
 237         # TODO: With patching we might be able to get rid of the python-any deps and removals, and test depend on glib-utils instead; revisit with meson
 238         rm "${ED}usr/bin/glib-genmarshal" || die
 239         rm "${ED}usr/share/man/man1/glib-genmarshal.1" || die
 240         rm "${ED}usr/bin/glib-mkenums" || die
 241         rm "${ED}usr/share/man/man1/glib-mkenums.1" || die
 242         rm "${ED}usr/bin/gtester-report" || die
 243         rm "${ED}usr/share/man/man1/gtester-report.1" || die
 244
 245         # Do not install charset.alias even if generated, leave it to libiconv
 246         rm -f "${ED}/usr/$(get_libdir)/charset.alias"
 247
 248         # Don't install gdb python macros, bug 291328
 249         rm -rf "${ED}/usr/share/gdb/" "${ED}/usr/share/glib-2.0/gdb/"
 250
 251         # Completely useless with or without USE static-libs, people need to use pkg-config
 252         find "${ED}" -name '*.la' -delete || die
 253 }
 254
 255 pkg_preinst() {
 256         gnome2_pkg_preinst
 257
 258         # Make gschemas.compiled belong to glib alone
 259         local cache="usr/share/glib-2.0/schemas/gschemas.compiled"
 260
 261         if [[ -e ${EROOT}${cache} ]]; then
 262                 cp "${EROOT}"${cache} "${ED}"/${cache} || die
 263         else
 264                 touch "${ED}"/${cache} || die
 265         fi
 266
 267         multilib_pkg_preinst() {
 268                 # Make giomodule.cache belong to glib alone
 269                 local cache="usr/$(get_libdir)/gio/modules/giomodule.cache"
 270
 271                 if [[ -e ${EROOT}${cache} ]]; then
 272                         cp "${EROOT}"${cache} "${ED}"/${cache} || die
 273                 else
 274                         touch "${ED}"/${cache} || die
 275                 fi
 276         }
 277
 278         # Don't run the cache ownership when cross-compiling, as it would end up with an empty cache
 279         # file due to inability to create it and GIO might not look at any of the modules there
 280         if ! tc-is-cross-compiler ; then
 281                 multilib_foreach_abi multilib_pkg_preinst
 282         fi
 283 }
 284
 285 pkg_postinst() {
 286         # force (re)generation of gschemas.compiled
 287         GNOME2_ECLASS_GLIB_SCHEMAS="force"
 288
 289         gnome2_pkg_postinst
 290
 291         multilib_pkg_postinst() {
 292                 gnome2_giomodule_cache_update \
 293                         || die "Update GIO modules cache failed (for ${ABI})"
 294         }
 295         if ! tc-is-cross-compiler ; then
 296                 multilib_foreach_abi multilib_pkg_postinst
 297         else
 298                 ewarn "Updating of GIO modules cache skipped due to cross-compilation."
 299                 ewarn "You might want to run gio-querymodules manually on the target for"
 300                 ewarn "your final image for performance reasons and re-run it when packages"
 301                 ewarn "installing GIO modules get upgraded or added to the image."
 302         fi
 303 }
 304
 305 pkg_postrm() {
 306         gnome2_pkg_postrm
 307
 308         if [[ -z ${REPLACED_BY_VERSION} ]]; then
 309                 multilib_pkg_postrm() {
 310                         rm -f "${EROOT}"usr/$(get_libdir)/gio/modules/giomodule.cache
 311                 }
 312                 multilib_foreach_abi multilib_pkg_postrm
 313                 rm -f "${EROOT}"usr/share/glib-2.0/schemas/gschemas.compiled
 314         fi
 315 }