dev-libs/gjs/gjs-1.48.2.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit gnome2 pax-utils virtualx
   6
   7 DESCRIPTION="Javascript bindings for GNOME"
   8 HOMEPAGE="https://wiki.gnome.org/Projects/Gjs"
   9
  10 LICENSE="MIT || ( MPL-1.1 LGPL-2+ GPL-2+ )"
  11 SLOT="0"
  12 IUSE="+cairo examples gtk test"
  13 KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
  14
  15 RDEPEND="
  16         >=dev-libs/glib-2.52.1
  17         >=dev-libs/gobject-introspection-1.52.1:=
  18
  19         sys-libs/readline:0
  20         dev-lang/spidermonkey:38
  21         virtual/libffi
  22         cairo? ( x11-libs/cairo[X] )
  23         gtk? ( x11-libs/gtk+:3 )
  24 "
  25 DEPEND="${RDEPEND}
  26         gnome-base/gnome-common
  27         sys-devel/gettext
  28         virtual/pkgconfig
  29         test? ( sys-apps/dbus )
  30 "
  31
  32 PATCHES=(
  33         # Disable broken unittests, upstream bug #????
  34         "${FILESDIR}"/${PN}-1.48.2-disable-unittest.patch
  35 )
  36
  37 src_configure() {
  38         # FIXME: add systemtap/dtrace support, like in glib:2
  39         # FIXME: --enable-systemtap installs files in ${D}/${D} for some reason
  40         # XXX: Do NOT enable coverage, completely useless for portage installs
  41         gnome2_src_configure \
  42                 --disable-systemtap \
  43                 --disable-dtrace \
  44                 --disable-coverage \
  45                 $(use_with cairo cairo) \
  46                 $(use_with gtk) \
  47                 $(use_with test dbus-tests) \
  48                 $(use_with test xvfb-tests)
  49 }
  50
  51 src_test() {
  52         virtx emake check
  53 }
  54
  55 src_install() {
  56         # installation sometimes fails in parallel, bug #???
  57         gnome2_src_install -j1
  58
  59         if use examples; then
  60                 insinto /usr/share/doc/"${PF}"/examples
  61                 doins "${S}"/examples/*
  62         fi
  63
  64         # Required for gjs-console to run correctly on PaX systems
  65         pax-mark mr "${ED}/usr/bin/gjs-console"
  66 }