dev-libs/girara/girara-0.2.4.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit multilib toolchain-funcs
   8 [[ ${PV} == 9999* ]] && inherit git-2
   9
  10 DESCRIPTION="A library that implements a user interface that focuses on simplicity and minimalism"
  11 HOMEPAGE="http://pwmt.org/projects/girara/"
  12 if ! [[ ${PV} == 9999* ]]; then
  13 SRC_URI="http://pwmt.org/projects/${PN}/download/${P}.tar.gz"
  14 fi
  15 EGIT_REPO_URI="https://git.pwmt.org/pwmt/${PN}.git"
  16 EGIT_BRANCH="develop"
  17
  18 LICENSE="ZLIB"
  19 SLOT="3"
  20 if ! [[ ${PV} == 9999* ]]; then
  21 KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~x86-linux"
  22 else
  23 KEYWORDS=""
  24 fi
  25 IUSE="libnotify static-libs"
  26
  27 RDEPEND=">=dev-libs/glib-2.28
  28         >=x11-libs/gtk+-3.2:3
  29         dev-libs/json-c
  30         !<${CATEGORY}/${PN}-0.1.6
  31         libnotify? ( >=x11-libs/libnotify-0.7 )"
  32 DEPEND="${RDEPEND}
  33         sys-devel/gettext
  34         virtual/pkgconfig"
  35
  36 pkg_setup() {
  37         mygiraraconf=(
  38                 WITH_LIBNOTIFY=$(usex libnotify 1 0)
  39                 PREFIX="${EPREFIX}"/usr
  40                 LIBDIR='${PREFIX}'/$(get_libdir)
  41                 CC="$(tc-getCC)"
  42                 SFLAGS=''
  43                 VERBOSE=1
  44                 DESTDIR="${D}"
  45                 )
  46 }
  47
  48 src_prepare() {
  49         # Remove 'static' and 'install-static' targets
  50         if ! use static-libs; then
  51                 sed -i \
  52                         -e '/^${PROJECT}:/s:static::' \
  53                         -e '/^install:/s:install-static::' \
  54                         Makefile || die
  55         fi
  56 }
  57
  58 src_compile() {
  59         emake "${mygiraraconf[@]}"
  60 }
  61
  62 src_install() {
  63         emake "${mygiraraconf[@]}" install
  64         dodoc AUTHORS
  65 }