dev-libs/folks/folks-0.12.1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 VALA_USE_DEPEND="vapigen"
   6 VALA_MAX_API_VERSION="0.44" # tests-utils fails to build with newer with v0.12.1
   7
   8 inherit gnome.org gnome2-utils meson vala xdg
   9
  10 DESCRIPTION="Library for aggregating people from multiple sources"
  11 HOMEPAGE="https://wiki.gnome.org/Projects/Folks"
  12
  13 LICENSE="LGPL-2.1+"
  14 SLOT="0/25" # subslot = libfolks soname version
  15 KEYWORDS="~alpha amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc x86 ~x86-linux"
  16
  17 IUSE="bluetooth eds +telepathy test tracker utils"
  18 REQUIRED_USE="bluetooth? ( eds )"
  19 RESTRICT="!test? ( test )"
  20
  21 DEPEND="
  22         $(vala_depend)
  23         >=dev-libs/glib-2.44:2
  24         dev-libs/dbus-glib
  25         >=dev-libs/libgee-0.10:0.8[introspection]
  26         >=dev-libs/gobject-introspection-1.54:=
  27         telepathy? ( >=net-libs/telepathy-glib-0.19.9[vala] )
  28         tracker? ( app-misc/tracker:0/2.0 )
  29         eds? ( >=gnome-extra/evolution-data-server-3.13.90:=[vala] )
  30         dev-libs/libxml2:2
  31         utils? ( sys-libs/readline:0= )
  32 "
  33 # telepathy-mission-control needed at runtime; it is used by the telepathy
  34 # backend via telepathy-glib's AccountManager binding.
  35 RDEPEND="${DEPEND}
  36         bluetooth? ( >=net-wireless/bluez-5[obex] )
  37         telepathy? ( net-im/telepathy-mission-control )
  38 "
  39 BDEPEND="
  40         >=dev-util/meson-0.49
  41         >=sys-devel/gettext-0.19.8
  42         virtual/pkgconfig
  43 "
  44
  45 # FIXME:
  46 # test? ( bluetooth? ( dbusmock is missing in the tree ) )
  47 DEPEND="${COMMON_DEPEND}
  48         test? ( sys-apps/dbus
  49                 bluetooth? ( dev-python/dbusmock ) )
  50 "
  51
  52 PATCHES=(
  53         "${FILESDIR}"/${PV}-conditional-tests.patch # Allow not building lots of test executables when tests are disabled
  54         "${FILESDIR}"/${PV}-no-tracker-tests.patch # TODO: Tracker tests fail; this removed them for now
  55 )
  56
  57 src_prepare() {
  58         vala_src_prepare
  59         xdg_src_prepare
  60 }
  61
  62 src_configure() {
  63         local emesonargs=(
  64                 $(meson_use bluetooth bluez_backend)
  65                 $(meson_use eds eds_backend)
  66                 -Dlibsocialweb_backend=false # not packaged
  67                 $(meson_use eds ofono_backend)
  68                 $(meson_use telepathy telepathy_backend)
  69                 $(meson_use tracker tracker_backend)
  70                 -Dzeitgeist=false # last rited package
  71                 -Dimport_tool=true
  72                 $(meson_use utils inspect_tool)
  73                 $(meson_use test)
  74                 -Dinstalled_tests=false
  75                 -Ddocs=false # Needs find_program sedding to specific version; only dev docs, don't bother
  76         )
  77         meson_src_configure
  78 }
  79
  80 pkg_postinst() {
  81         xdg_pkg_postinst
  82         gnome2_schemas_update
  83 }
  84
  85 pkg_postrm() {
  86         xdg_pkg_postrm
  87         gnome2_schemas_update
  88 }