dev-libs/ffcall/ffcall-1.10-r2.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 inherit eutils flag-o-matic
   5
   6 # CLISP maintains ffcall now
   7 CLISP_PACKAGE="clisp-2.41"
   8
   9 DESCRIPTION="foreign function call libraries"
  10 HOMEPAGE="https://www.haible.de/bruno/packages-ffcall.html"
  11 SRC_URI="mirror://sourceforge/clisp/${CLISP_PACKAGE}.tar.bz2"
  12
  13 # "Ffcall is under GNU GPL. As a special exception, if used in GNUstep
  14 # or in derivate works of GNUstep, the included parts of ffcall are
  15 # under GNU LGPL." -ffcall author
  16 LICENSE="|| ( GPL-2 LGPL-2 )"
  17 SLOT="0"
  18 KEYWORDS="alpha amd64 ~hppa ia64 ~ppc ~ppc64 sparc x86 ~x86-fbsd"
  19 IUSE=""
  20
  21 S=${WORKDIR}/${CLISP_PACKAGE}/${PN}
  22
  23 DEPEND=""
  24 RDEPEND=""
  25
  26 src_compile() {
  27         # Because CHOST is set to (for example)
  28         # alphaev67-unknown-linux-gnu, CPU gets set to alphaev67 which
  29         # doesn't work in the Makefile (29 Jan 2004 agriffis)
  30         local cpu_setting
  31         [[ "${ARCH}" == "alpha" ]] && cpu_setting='CPU=alpha'
  32
  33         append-flags -fPIC
  34
  35         # Doc goes in datadir
  36         econf \
  37                 --datadir=/usr/share/doc/${PF} \
  38                 --enable-shared \
  39                 || die "./configure failed"
  40         # bug #298348
  41         emake -j1 ${cpu_setting} || die
  42 }
  43
  44 src_install() {
  45         dodoc NEWS README
  46         dodir /usr/share/man
  47         emake DESTDIR=${D} install || die "Install failed"
  48 }