dev-libs/fcgi/fcgi-2.4.1_pre0910052249-r2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit autotools
   7
   8 DESCRIPTION="FastCGI Developer's Kit"
   9 HOMEPAGE="http://www.fastcgi.com/"
  10 SRC_URI="http://www.fastcgi.com/dist/fcgi-2.4.1-SNAP-0910052249.tar.gz"
  11
  12 LICENSE="FastCGI"
  13 SLOT="0"
  14 KEYWORDS="~alpha amd64 arm ~arm64 hppa ~ia64 ~mips ppc ppc64 s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
  15 IUSE="html"
  16
  17 S="${WORKDIR}/${PN}-2.4.1-SNAP-0910052249"
  18
  19 PATCHES=(
  20         "${FILESDIR}"/${PN}-2.4.0-Makefile.patch
  21         "${FILESDIR}"/${PN}-2.4.0-clientdata-pointer.patch
  22         "${FILESDIR}"/${PN}-2.4.0-html-updates.patch
  23         "${FILESDIR}"/${PN}-2.4.1_pre0311112127-gcc44.patch
  24         "${FILESDIR}"/${P}-link.patch
  25         "${FILESDIR}"/${P}-poll.patch
  26 )
  27
  28 src_prepare() {
  29         default
  30         eautoreconf
  31 }
  32
  33 src_configure() {
  34         econf --disable-static
  35 }
  36
  37 src_install() {
  38         emake DESTDIR="${D}" install LIBRARY_PATH="${ED}"/usr/$(get_libdir)
  39         einstalldocs
  40
  41         # install the manpages into the right place
  42         doman doc/*.[13]
  43
  44         # Only install the html documentation if USE=html
  45         if use html; then
  46                 docinto html
  47                 dodoc -r doc/*/* images
  48         fi
  49
  50         # install examples in the right place
  51         docinto examples
  52         dodoc examples/*.c
  53
  54         # no static archives
  55         find "${D}" -name '*.la' -delete || die
  56 }