dev-libs/expat/expat-2.2.1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit autotools eutils libtool multilib toolchain-funcs multilib-minimal
   6
   7 DESCRIPTION="Stream-oriented XML parser library"
   8 HOMEPAGE="http://expat.sourceforge.net/"
   9 SRC_URI="mirror://sourceforge/expat/${P}.tar.bz2"
  10
  11 LICENSE="MIT"
  12 SLOT="0"
  13 KEYWORDS="alpha amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc x86 ~ppc-aix ~x64-cygwin ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
  14 IUSE="elibc_FreeBSD examples static-libs unicode"
  15 RDEPEND="abi_x86_32? ( !<=app-emulation/emul-linux-x86-baselibs-20130224-r6
  16                 !app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)] )"
  17
  18 DOCS=( AUTHORS Changes README )
  19
  20 src_prepare() {
  21         epatch "${FILESDIR}"/${P}-getrandom-detection.patch
  22         epatch "${FILESDIR}"/${P}-posix-shell.patch
  23         eapply_user
  24         eautoreconf
  25 }
  26
  27 multilib_src_configure() {
  28         local myconf="$(use_enable static-libs static)"
  29
  30         mkdir -p "${BUILD_DIR}"{u,w} || die
  31
  32         ECONF_SOURCE="${S}" econf ${myconf}
  33
  34         if use unicode; then
  35                 pushd "${BUILD_DIR}"w >/dev/null
  36                 CPPFLAGS="${CPPFLAGS} -DXML_UNICODE" ECONF_SOURCE="${S}" econf ${myconf}
  37                 popd >/dev/null
  38         fi
  39 }
  40
  41 multilib_src_compile() {
  42         emake
  43
  44         if use unicode; then
  45                 pushd "${BUILD_DIR}"w >/dev/null
  46                 emake buildlib LIBRARY=libexpatw.la
  47                 popd >/dev/null
  48         fi
  49 }
  50
  51 multilib_src_install() {
  52         emake install DESTDIR="${D}"
  53
  54         if use unicode; then
  55                 pushd "${BUILD_DIR}"w >/dev/null
  56                 emake installlib DESTDIR="${D}" LIBRARY=libexpatw.la
  57                 popd >/dev/null
  58
  59                 pushd "${ED}"/usr/$(get_libdir)/pkgconfig >/dev/null
  60                 cp expat.pc expatw.pc
  61                 sed -i -e '/^Libs/s:-lexpat:&w:' expatw.pc || die
  62                 popd >/dev/null
  63         fi
  64
  65         if multilib_is_native_abi ; then
  66                 # libgeom in /lib and ifconfig in /sbin require libexpat on FreeBSD since
  67                 # we stripped the libbsdxml copy starting from freebsd-lib-8.2-r1
  68                 use elibc_FreeBSD && gen_usr_ldscript -a expat
  69         fi
  70 }
  71
  72 multilib_src_install_all() {
  73         einstalldocs
  74
  75         # Note: Use of HTML_DOCS would add unwanted "doc" subfolder
  76         docinto html
  77         dodoc doc/*.{css,html,png}
  78
  79         if use examples; then
  80                 insinto /usr/share/doc/${PF}/examples
  81                 doins examples/*.c
  82         fi
  83
  84         prune_libtool_files
  85 }