dev-libs/ell/ell-9999.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit flag-o-matic multilib-minimal
   7
   8 DESCRIPTION="Embedded Linux Library provides core, low-level functionality for system daemons"
   9 HOMEPAGE="https://01.org/ell"
  10 if [[ "${PV}" == *9999 ]] ; then
  11         inherit autotools git-r3
  12         EGIT_REPO_URI="https://git.kernel.org/pub/scm/libs/ell/ell.git"
  13 else
  14         SRC_URI="https://mirrors.edge.kernel.org/pub/linux/libs/${PN}/${P}.tar.xz"
  15         KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
  16 fi
  17 LICENSE="LGPL-2.1"
  18 SLOT="0"
  19
  20 IUSE="glib pie"
  21
  22 RDEPEND="
  23         glib? ( dev-libs/glib:2[${MULTILIB_USEDEP}] )
  24 "
  25 DEPEND="${RDEPEND}"
  26
  27 src_prepare() {
  28         default
  29         [[ "${PV}" == *9999 ]] && eautoreconf
  30 }
  31
  32 multilib_src_configure() {
  33         append-cflags "-fsigned-char" #662694
  34         local myeconfargs=(
  35                 $(use_enable glib)
  36                 $(use_enable pie)
  37         )
  38         ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
  39 }
  40
  41 multilib_src_install_all() {
  42         local DOCS=( ChangeLog README )
  43         einstalldocs
  44
  45         find "${ED}" -name "*.la" -delete || die
  46 }