dev-libs/ell/ell-0.31.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit flag-o-matic linux-info multilib-minimal
   7
   8 DESCRIPTION="Embedded Linux Library provides core, low-level functionality for system daemons"
   9 HOMEPAGE="https://01.org/ell"
  10 if [[ "${PV}" == *9999 ]] ; then
  11         inherit autotools git-r3
  12         EGIT_REPO_URI="https://git.kernel.org/pub/scm/libs/ell/ell.git"
  13 else
  14         SRC_URI="https://mirrors.edge.kernel.org/pub/linux/libs/${PN}/${P}.tar.xz"
  15         KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
  16 fi
  17 LICENSE="LGPL-2.1"
  18 SLOT="0"
  19
  20 IUSE="glib pie test"
  21 RESTRICT="!test? ( test )"
  22
  23 RDEPEND="
  24         glib? ( dev-libs/glib:2[${MULTILIB_USEDEP}] )
  25 "
  26 DEPEND="
  27         ${RDEPEND}
  28         test? ( sys-apps/dbus )
  29 "
  30
  31 CONFIG_CHECK="
  32         ~TIMERFD
  33         ~EVENTFD
  34         ~CRYPTO_USER_API
  35         ~CRYPTO_USER_API_HASH
  36         ~CRYPTO_MD5
  37         ~CRYPTO_SHA1
  38         ~KEY_DH_OPERATIONS
  39 "
  40
  41 src_prepare() {
  42         default
  43         [[ "${PV}" == *9999 ]] && eautoreconf
  44 }
  45
  46 multilib_src_configure() {
  47         append-cflags "-fsigned-char" #662694
  48         local myeconfargs=(
  49                 $(use_enable glib)
  50                 $(use_enable pie)
  51         )
  52         ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
  53 }
  54
  55 multilib_src_install_all() {
  56         local DOCS=( ChangeLog README )
  57         einstalldocs
  58
  59         find "${ED}" -name "*.la" -delete || die
  60 }