dev-libs/elfutils/elfutils-0.177.ebuild

   1 # Copyright 2003-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit flag-o-matic multilib-minimal
   7
   8 DESCRIPTION="Libraries/utilities to handle ELF objects (drop in replacement for libelf)"
   9 HOMEPAGE="http://elfutils.org/"
  10 SRC_URI="https://sourceware.org/elfutils/ftp/${PV}/${P}.tar.bz2"
  11
  12 LICENSE="|| ( GPL-2+ LGPL-3+ ) utils? ( GPL-3+ )"
  13 SLOT="0"
  14 KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv s390 sparc x86 ~amd64-linux ~x86-linux"
  15 IUSE="bzip2 lzma nls static-libs test +threads +utils"
  16
  17 RDEPEND=">=sys-libs/zlib-1.2.8-r1[static-libs?,${MULTILIB_USEDEP}]
  18         bzip2? ( >=app-arch/bzip2-1.0.6-r4[static-libs?,${MULTILIB_USEDEP}] )
  19         lzma? ( >=app-arch/xz-utils-5.0.5-r1[static-libs?,${MULTILIB_USEDEP}] )
  20         !dev-libs/libelf"
  21 DEPEND="${RDEPEND}"
  22 BDEPEND="nls? ( sys-devel/gettext )
  23         >=sys-devel/flex-2.5.4a
  24         sys-devel/m4"
  25
  26 RESTRICT="!test? ( test )"
  27
  28 PATCHES=(
  29         "${FILESDIR}"/${PN}-0.118-PaX-support.patch
  30         "${FILESDIR}"/${PN}-0.175-disable-biarch-test-PR24158.patch
  31         "${FILESDIR}"/${PN}-0.177-disable-large.patch
  32 )
  33
  34 src_prepare() {
  35         default
  36
  37         if ! use static-libs; then
  38                 sed -i -e '/^lib_LIBRARIES/s:=.*:=:' -e '/^%.os/s:%.o$::' lib{asm,dw,elf}/Makefile.in || die
  39         fi
  40         # https://sourceware.org/PR23914
  41         sed -i 's:-Werror::' */Makefile.in || die
  42 }
  43
  44 src_configure() {
  45         use test && append-flags -g #407135
  46
  47         # Symbol aliases are implemented as asm statements.
  48         # Will require porting: https://gcc.gnu.org/PR48200
  49         filter-flags '-flto*'
  50
  51         multilib-minimal_src_configure
  52 }
  53
  54 multilib_src_configure() {
  55         ECONF_SOURCE="${S}" econf \
  56                 $(use_enable nls) \
  57                 $(use_enable threads thread-safety) \
  58                 --program-prefix="eu-" \
  59                 --with-zlib \
  60                 $(use_with bzip2 bzlib) \
  61                 $(use_with lzma)
  62 }
  63
  64 multilib_src_test() {
  65         env     LD_LIBRARY_PATH="${BUILD_DIR}/libelf:${BUILD_DIR}/libebl:${BUILD_DIR}/libdw:${BUILD_DIR}/libasm" \
  66                 LC_ALL="C" \
  67                 emake check VERBOSE=1
  68 }
  69
  70 multilib_src_install_all() {
  71         einstalldocs
  72         dodoc NOTES
  73         # These build quick, and are needed for most tests, so don't
  74         # disable their building when the USE flag is disabled.
  75         if ! use utils; then
  76                 rm -rf "${ED}"/usr/bin || die
  77         fi
  78 }