dev-libs/elfutils/elfutils-0.169-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit eutils flag-o-matic multilib-minimal
   7
   8 DESCRIPTION="Libraries/utilities to handle ELF objects (drop in replacement for libelf)"
   9 HOMEPAGE="http://elfutils.org/"
  10 SRC_URI="https://sourceware.org/elfutils/ftp/${PV}/${P}.tar.bz2"
  11
  12 LICENSE="|| ( GPL-2+ LGPL-3+ ) utils? ( GPL-3+ )"
  13 SLOT="0"
  14 KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh ~sparc x86 ~amd64-linux ~arm-linux ~x86-linux"
  15 IUSE="bzip2 lzma nls static-libs test +threads +utils"
  16
  17 RDEPEND=">=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
  18         bzip2? ( >=app-arch/bzip2-1.0.6-r4[${MULTILIB_USEDEP}] )
  19         lzma? ( >=app-arch/xz-utils-5.0.5-r1[${MULTILIB_USEDEP}] )
  20         !dev-libs/libelf"
  21 DEPEND="${RDEPEND}
  22         nls? ( sys-devel/gettext )
  23         >=sys-devel/flex-2.5.4a
  24         sys-devel/m4"
  25
  26 src_prepare() {
  27         default
  28         epatch "${FILESDIR}"/${PN}-0.118-PaX-support.patch
  29         if use static-libs; then
  30                 sed -i -e '/^lib_LIBRARIES/s:=.*:=:' -e '/^%.os/s:%.o$::' lib{asm,dw,elf}/Makefile.in || die
  31         fi
  32         sed -i 's:-Werror::' */Makefile.in || die
  33 }
  34
  35 src_configure() {
  36         use test && append-flags -g #407135
  37         multilib-minimal_src_configure
  38 }
  39
  40 multilib_src_configure() {
  41         ECONF_SOURCE="${S}" econf \
  42                 $(use_enable nls) \
  43                 $(use_enable threads thread-safety) \
  44                 --program-prefix="eu-" \
  45                 --with-zlib \
  46                 $(use_with bzip2 bzlib) \
  47                 $(use_with lzma)
  48 }
  49
  50 multilib_src_test() {
  51         env     LD_LIBRARY_PATH="${BUILD_DIR}/libelf:${BUILD_DIR}/libebl:${BUILD_DIR}/libdw:${BUILD_DIR}/libasm" \
  52                 LC_ALL="C" \
  53                 emake check
  54 }
  55
  56 multilib_src_install_all() {
  57         einstalldocs
  58         dodoc NOTES
  59         # These build quick, and are needed for most tests, so don't
  60         # disable their building when the USE flag is disabled.
  61         if ! use utils; then
  62                 rm -rf "${ED}"/usr/bin || die
  63         fi
  64 }