dev-libs/cdk/cdk-5.0.20141106.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 inherit eutils versionator
   7
   8 MY_P="${PN}-$(replace_version_separator 2 -)"
   9 DESCRIPTION="A library of curses widgets"
  10 HOMEPAGE="http://dickey.his.com/cdk/cdk.html"
  11 SRC_URI="ftp://invisible-island.net/cdk/${MY_P}.tgz"
  12
  13 LICENSE="BSD"
  14 SLOT="0/6" # subslot = soname version
  15 KEYWORDS="alpha amd64 hppa ia64 ppc ppc64 ~s390 sparc x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
  16 IUSE="examples static-libs unicode"
  17
  18 DEPEND=">=sys-libs/ncurses-5.2[unicode?]"
  19 RDEPEND="${DEPEND}"
  20
  21 S=${WORKDIR}/${MY_P}
  22
  23 src_prepare() {
  24         epatch "${FILESDIR}"/${PN}-5.0.20120323-parallel-make.patch
  25 }
  26
  27 src_configure() {
  28         econf \
  29                 --with-libtool \
  30                 --with-shared \
  31                 --with-ncurses$(usex unicode "w" "")
  32 }
  33
  34 src_install() {
  35         # parallel make installs duplicate libs
  36         emake -j1 \
  37                 DESTDIR="${ED}" \
  38                 DOCUMENT_DIR="${ED}/usr/share/doc/${PF}" install
  39
  40         if use examples ; then
  41                 for x in include c++ demos examples cli cli/utils cli/samples; do
  42                         docinto $x
  43                         find $x -maxdepth 1 -mindepth 1 -type f -print0 | xargs -0 dodoc
  44                 done
  45         fi
  46
  47         use static-libs || find "${ED}" \( -name '*.a' -or -name '*.la' \) -delete
  48 }