dev-libs/boehm-gc/boehm-gc-7.6.0.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit multilib-minimal libtool
   7
   8 MY_P="gc-${PV}"
   9
  10 DESCRIPTION="The Boehm-Demers-Weiser conservative garbage collector"
  11 HOMEPAGE="http://www.hboehm.info/gc/"
  12 SRC_URI="http://www.hboehm.info/gc/gc_source/${MY_P}.tar.gz"
  13
  14 LICENSE="boehm-gc"
  15 SLOT="0"
  16 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
  17 IUSE="cxx static-libs threads"
  18
  19 DEPEND="
  20         >=dev-libs/libatomic_ops-7.4[${MULTILIB_USEDEP}]
  21         virtual/pkgconfig"
  22
  23 S="${WORKDIR}/${MY_P}"
  24
  25 src_prepare() {
  26         default
  27         elibtoolize #594754
  28 }
  29
  30 multilib_src_configure() {
  31         local config=(
  32                 --with-libatomic-ops
  33                 $(use_enable cxx cplusplus)
  34                 $(use_enable static-libs static)
  35                 $(use threads || echo --disable-threads)
  36         )
  37
  38         ECONF_SOURCE=${S} econf "${config[@]}"
  39 }
  40
  41 multilib_src_install_all() {
  42         local HTML_DOCS=( doc/*.html )
  43         einstalldocs
  44         dodoc doc/README{.environment,.linux,.macros}
  45
  46         rm -r "${ED%/}"/usr/share/gc || die
  47
  48         # package provides .pc files
  49         find "${D}" -name '*.la' -delete || die
  50
  51         newman doc/gc.man GC_malloc.1
  52 }