dev-libs/bglibs/bglibs-2.04-r2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit toolchain-funcs
   7
   8 DESCRIPTION="Bruce Guenter's Libraries Collection"
   9 HOMEPAGE="https://untroubled.org/bglibs/"
  10 SRC_URI="https://untroubled.org/bglibs/archive/${P}.tar.gz"
  11
  12 LICENSE="LGPL-2.1+"
  13 SLOT="0/2"
  14 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 sparc ~x86"
  15 IUSE="doc"
  16
  17 RDEPEND=""
  18 DEPEND=""
  19 BDEPEND="sys-devel/libtool
  20         doc? (
  21                 app-doc/doxygen
  22                 dev-texlive/texlive-latexrecommended
  23                 dev-texlive/texlive-latex
  24                 dev-texlive/texlive-latexextra
  25                 virtual/latex-base
  26         )
  27 "
  28
  29 PATCHES=( "${FILESDIR}"/bglibs-2.04-stack-buffers.patch )
  30
  31 src_prepare() {
  32         default
  33         # disable tests as we want them manually
  34         sed -i '/^all:/s|selftests||' Makefile || die
  35         sed -i '/selftests/d' TARGETS || die
  36 }
  37
  38 src_configure() {
  39         echo "${ED}/usr/bin" > conf-bin || die
  40         echo "${ED}/usr/$(get_libdir)/bglibs" > conf-lib || die
  41         echo "${ED}/usr/include" > conf-include || die
  42         echo "${ED}/usr/share/man" > conf-man || die
  43         echo "$(tc-getCC) ${CFLAGS}" > conf-cc || die
  44         echo "$(tc-getCC) ${LDFLAGS}" > conf-ld || die
  45 }
  46
  47 src_compile() {
  48         # Parallel build fails, bug #343617
  49         MAKEOPTS+=" -j1" default
  50
  51         if use doc; then
  52                 emake -C doc/latex pdf
  53         fi
  54 }
  55
  56 src_test() {
  57         einfo "Running selftests"
  58         emake selftests
  59 }
  60
  61 src_install() {
  62         default
  63
  64         # Install .so into LDPATH
  65         mv "${ED}"/usr/$(get_libdir)/bglibs/libbg.so.2.0.0 "${ED}"/usr/$(get_libdir)/ || die
  66         dosym libbg.so.2.0.0 /usr/$(get_libdir)/libbg.so.2
  67         dosym libbg.so.2.0.0 /usr/$(get_libdir)/libbg.so
  68         dosym ../libbg.so.2.0.0 /usr/$(get_libdir)/bglibs/libbg.so.2.0.0
  69
  70         rm "${ED}"/usr/$(get_libdir)/bglibs/libbg.la || die
  71
  72         dodoc ANNOUNCEMENT NEWS README ChangeLog TODO VERSION
  73         dodoc -r doc/html/
  74         if use doc; then
  75                 dodoc doc/latex/refman.pdf
  76         fi
  77 }