dev-libs/bglibs/bglibs-2.04-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit toolchain-funcs
   7
   8 DESCRIPTION="Bruce Guenter's Libraries Collection"
   9 HOMEPAGE="https://untroubled.org/bglibs/"
  10 SRC_URI="https://untroubled.org/bglibs/archive/${P}.tar.gz"
  11
  12 LICENSE="LGPL-2.1+"
  13 SLOT="0/2"
  14 KEYWORDS="~alpha amd64 ~arm ~hppa ~mips ppc ~ppc64 ~sparc x86"
  15 IUSE="doc"
  16
  17 RDEPEND=""
  18 DEPEND=""
  19 BDEPEND="sys-devel/libtool
  20         doc? (
  21                 app-doc/doxygen
  22                 dev-texlive/texlive-latexrecommended
  23                 dev-texlive/texlive-latex
  24                 dev-texlive/texlive-latexextra
  25                 virtual/latex-base
  26         )
  27 "
  28
  29 src_prepare() {
  30         default
  31         # disable tests as we want them manually
  32         sed -i '/^all:/s|selftests||' Makefile || die
  33         sed -i '/selftests/d' TARGETS || die
  34 }
  35
  36 src_configure() {
  37         echo "${ED}/usr/bin" > conf-bin || die
  38         echo "${ED}/usr/$(get_libdir)/bglibs" > conf-lib || die
  39         echo "${ED}/usr/include" > conf-include || die
  40         echo "${ED}/usr/share/man" > conf-man || die
  41         echo "$(tc-getCC) ${CFLAGS}" > conf-cc || die
  42         echo "$(tc-getCC) ${LDFLAGS}" > conf-ld || die
  43 }
  44
  45 src_compile() {
  46         default
  47         if use doc; then
  48                 emake -C doc/latex pdf
  49         fi
  50 }
  51
  52 src_test() {
  53         einfo "Running selftests"
  54         emake selftests
  55 }
  56
  57 src_install() {
  58         default
  59
  60         # Install .so into LDPATH
  61         mv "${ED}"/usr/$(get_libdir)/bglibs/libbg.so.2.0.0 "${ED}"/usr/$(get_libdir)/ || die
  62         dosym libbg.so.2.0.0 /usr/$(get_libdir)/libbg.so.2
  63         dosym libbg.so.2.0.0 /usr/$(get_libdir)/libbg.so
  64         dosym ../libbg.so.2.0.0 /usr/$(get_libdir)/bglibs/libbg.so.2.0.0
  65
  66         rm "${ED}"/usr/$(get_libdir)/bglibs/libbg.la || die
  67
  68         dodoc ANNOUNCEMENT NEWS README ChangeLog TODO VERSION
  69         dodoc -r doc/html/
  70         if use doc; then
  71                 dodoc doc/latex/refman.pdf
  72         fi
  73 }