dev-libs/atk/atk-2.16.0-r1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="5"
   6 GCONF_DEBUG="no"
   7
   8 inherit gnome2 multilib-minimal
   9
  10 DESCRIPTION="GTK+ & GNOME Accessibility Toolkit"
  11 HOMEPAGE="https://projects.gnome.org/accessibility/"
  12
  13 LICENSE="LGPL-2+"
  14 SLOT="0"
  15 KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 ~s390 ~sh sparc x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
  16 IUSE="+introspection nls test"
  17
  18 RDEPEND="
  19         >=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
  20         introspection? ( >=dev-libs/gobject-introspection-0.6.7 )
  21         abi_x86_32? (
  22                 !<=app-emulation/emul-linux-x86-gtklibs-20140508
  23                 !app-emulation/emul-linux-x86-gtklibs[-abi_x86_32(-)]
  24         )
  25 "
  26 DEPEND="${RDEPEND}
  27         >=dev-lang/perl-5
  28         dev-util/gtk-doc-am
  29         >=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
  30         nls? ( sys-devel/gettext )
  31 "
  32
  33 src_prepare() {
  34         gnome2_src_prepare
  35
  36         if ! use test; then
  37                 # don't waste time building tests (bug #226353)
  38                 sed 's/^\(SUBDIRS =.*\)tests\(.*\)$/\1\2/' -i Makefile.am Makefile.in \
  39                         || die "sed failed"
  40         fi
  41
  42         # Building out of sources fails, https://bugzilla.gnome.org/show_bug.cgi?id=752507
  43         multilib_copy_sources
  44 }
  45
  46 multilib_src_configure() {
  47 #       ECONF_SOURCE=${S} \
  48         gnome2_src_configure \
  49                 $(multilib_native_use_enable introspection)
  50
  51         # work-around gtk-doc out-of-source brokedness
  52 #       if multilib_is_native_abi; then
  53 #               ln -s "${S}"/docs/html docs/html || die
  54 #       fi
  55 }
  56
  57 multilib_src_install() {
  58         gnome2_src_install
  59 }