dev-libs/appstream/appstream-0.11.5.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit meson xdg-utils
   7
   8 if [[ ${PV} = 9999 ]]; then
   9         inherit git-r3
  10         EGIT_REPO_URI="https://github.com/ximion/${PN}"
  11 else
  12         inherit versionator
  13         MY_PV="$(replace_all_version_separators '_')"
  14         MY_P="APPSTREAM_${MY_PV}"
  15         SRC_URI="https://github.com/ximion/${PN}/archive/${MY_P}.tar.gz -> ${P}.tar.gz"
  16         KEYWORDS="~amd64 ~arm ~arm64 ~x86"
  17         S="${WORKDIR}/${PN}-${MY_P}"
  18 fi
  19
  20 DESCRIPTION="Cross-distro effort for providing metadata for software in the Linux ecosystem"
  21 HOMEPAGE="https://www.freedesktop.org/wiki/Distributions/AppStream/"
  22
  23 LICENSE="LGPL-2.1+ GPL-2+"
  24 # check as_api_level
  25 SLOT="0/4"
  26 IUSE="apt doc qt5 test"
  27
  28 RDEPEND="
  29         dev-libs/glib:2
  30         dev-libs/gobject-introspection
  31         dev-libs/libxml2:2
  32         dev-libs/libyaml
  33         dev-libs/snowball-stemmer
  34         qt5? ( dev-qt/qtcore:5 )
  35 "
  36 DEPEND="${RDEPEND}
  37         app-text/docbook-xml-dtd:4.5
  38         dev-util/itstool
  39         >=dev-util/meson-0.42.0
  40         sys-devel/gettext
  41         test? (
  42                 qt5? ( dev-qt/qttest:5 )
  43         )
  44 "
  45
  46 src_configure() {
  47         xdg_environment_reset
  48
  49         local emesonargs=(
  50                 -Denable-docs=false
  51                 -Denable-maintainer=false
  52                 -Denable-stemming=true
  53                 -Denable-vapi=false
  54                 -Denable-apt-support=$(usex apt true false)
  55                 -Denable-apidocs=$(usex doc true false)
  56                 -Denable-qt=$(usex qt5 true false)
  57         )
  58
  59         meson_src_configure
  60 }