dev-libs/appstream/appstream-0.10.6.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6
   7 KDE_AUTODEPS="false"
   8 KDE_TEST="forceoptional-recursive"
   9 inherit kde5 xdg-utils
  10
  11 if [[ ${KDE_BUILD_TYPE} = live ]]; then
  12         EGIT_REPO_URI="https://github.com/ximion/${PN}"
  13 else
  14         inherit versionator
  15         MY_PV="$(replace_all_version_separators '_')"
  16         MY_P="APPSTREAM_${MY_PV}"
  17         SRC_URI="https://github.com/ximion/${PN}/archive/${MY_P}.tar.gz -> ${P}.tar.gz"
  18         KEYWORDS="~amd64 ~arm ~x86"
  19         S="${WORKDIR}/${PN}-${MY_P}"
  20 fi
  21
  22 DESCRIPTION="Cross-distro effort for providing metadata for software in the Linux ecosystem"
  23 HOMEPAGE="https://www.freedesktop.org/wiki/Distributions/AppStream/"
  24
  25 LICENSE="LGPL-2.1+ GPL-2+"
  26 # check APPSTREAM_LIB_API_LEVEL
  27 SLOT="0/4"
  28 IUSE="apt doc qt5"
  29
  30 RDEPEND="
  31         dev-libs/glib:2
  32         dev-libs/libxml2:2
  33         dev-libs/libyaml
  34         dev-libs/snowball-stemmer
  35         qt5? ( dev-qt/qtcore:5 )
  36 "
  37 DEPEND="${RDEPEND}
  38         app-text/docbook-xml-dtd:4.5
  39         dev-util/itstool
  40         sys-devel/gettext
  41         test? (
  42                 qt5? ( dev-qt/qttest:5 )
  43         )
  44 "
  45
  46 src_configure() {
  47         xdg_environment_reset
  48
  49         local mycmakeargs=(
  50                 -DSTEMMING=ON
  51                 -DL18N=ON
  52                 -DVAPI=OFF
  53                 -DMAINTAINER=OFF
  54                 -DSANITIZERS=OFF
  55                 -DDOCUMENTATION=OFF
  56                 -DAPT_SUPPORT=$(usex apt)
  57                 -DINSTALL_PREBUILT_DOCS=$(usex doc)
  58                 -DQT=$(usex qt5)
  59         )
  60
  61         kde5_src_configure
  62 }