dev-libs/appstream/appstream-0.10.6.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 KDE_AUTODEPS="false"
   7 KDE_TEST="forceoptional-recursive"
   8 inherit kde5 xdg-utils
   9
  10 if [[ ${KDE_BUILD_TYPE} = live ]]; then
  11         EGIT_REPO_URI="https://github.com/ximion/${PN}"
  12 else
  13         inherit versionator
  14         MY_PV="$(replace_all_version_separators '_')"
  15         MY_P="APPSTREAM_${MY_PV}"
  16         SRC_URI="https://github.com/ximion/${PN}/archive/${MY_P}.tar.gz -> ${P}.tar.gz"
  17         KEYWORDS="~amd64 ~arm ~x86"
  18         S="${WORKDIR}/${PN}-${MY_P}"
  19 fi
  20
  21 DESCRIPTION="Cross-distro effort for providing metadata for software in the Linux ecosystem"
  22 HOMEPAGE="https://www.freedesktop.org/wiki/Distributions/AppStream/"
  23
  24 LICENSE="LGPL-2.1+ GPL-2+"
  25 # check APPSTREAM_LIB_API_LEVEL
  26 SLOT="0/4"
  27 IUSE="apt doc qt5"
  28
  29 RDEPEND="
  30         dev-libs/glib:2
  31         dev-libs/libxml2:2
  32         dev-libs/libyaml
  33         dev-libs/snowball-stemmer
  34         qt5? ( dev-qt/qtcore:5 )
  35 "
  36 DEPEND="${RDEPEND}
  37         app-text/docbook-xml-dtd:4.5
  38         dev-util/itstool
  39         sys-devel/gettext
  40         test? (
  41                 qt5? ( dev-qt/qttest:5 )
  42         )
  43 "
  44
  45 src_configure() {
  46         xdg_environment_reset
  47
  48         local mycmakeargs=(
  49                 -DSTEMMING=ON
  50                 -DL18N=ON
  51                 -DVAPI=OFF
  52                 -DMAINTAINER=OFF
  53                 -DSANITIZERS=OFF
  54                 -DDOCUMENTATION=OFF
  55                 -DAPT_SUPPORT=$(usex apt)
  56                 -DINSTALL_PREBUILT_DOCS=$(usex doc)
  57                 -DQT=$(usex qt5)
  58         )
  59
  60         kde5_src_configure
  61 }