dev-libs/appstream/appstream-0.10.6-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit cmake-utils xdg-utils
   7
   8 if [[ ${PV} = 9999 ]]; then
   9         inherit git-r3
  10         EGIT_REPO_URI="https://github.com/ximion/${PN}"
  11 else
  12         inherit versionator
  13         MY_PV="$(replace_all_version_separators '_')"
  14         MY_P="APPSTREAM_${MY_PV}"
  15         SRC_URI="https://github.com/ximion/${PN}/archive/${MY_P}.tar.gz -> ${P}.tar.gz"
  16         KEYWORDS="amd64 ~arm ~arm64 x86"
  17         S="${WORKDIR}/${PN}-${MY_P}"
  18 fi
  19
  20 DESCRIPTION="Cross-distro effort for providing metadata for software in the Linux ecosystem"
  21 HOMEPAGE="https://www.freedesktop.org/wiki/Distributions/AppStream/"
  22
  23 LICENSE="LGPL-2.1+ GPL-2+"
  24 # check APPSTREAM_LIB_API_LEVEL
  25 SLOT="0/4"
  26 IUSE="apt doc qt5 test"
  27
  28 RDEPEND="
  29         dev-libs/glib:2
  30         dev-libs/gobject-introspection
  31         dev-libs/libxml2:2
  32         dev-libs/libyaml
  33         dev-libs/snowball-stemmer
  34         qt5? ( dev-qt/qtcore:5 )
  35 "
  36 DEPEND="${RDEPEND}
  37         app-text/docbook-xml-dtd:4.5
  38         dev-util/itstool
  39         sys-devel/gettext
  40         test? (
  41                 qt5? ( dev-qt/qttest:5 )
  42         )
  43 "
  44
  45 src_prepare() {
  46         cmake-utils_src_prepare
  47
  48         if ! use test; then
  49                 pushd qt > /dev/null || die
  50                 cmake_comment_add_subdirectory tests
  51                 popd > /dev/null || die
  52         fi
  53 }
  54
  55 src_configure() {
  56         xdg_environment_reset
  57
  58         local mycmakeargs=(
  59                 -DSTEMMING=ON
  60                 -DL18N=ON
  61                 -DVAPI=OFF
  62                 -DMAINTAINER=OFF
  63                 -DSANITIZERS=OFF
  64                 -DDOCUMENTATION=OFF
  65                 -DAPT_SUPPORT=$(usex apt)
  66                 -DINSTALL_PREBUILT_DOCS=$(usex doc)
  67                 -DQT=$(usex qt5)
  68         )
  69
  70         cmake-utils_src_configure
  71 }