dev-lang/vala/vala-0.46.9.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit gnome2
   7
   8 DESCRIPTION="Compiler for the GObject type system"
   9 HOMEPAGE="https://wiki.gnome.org/Projects/Vala"
  10
  11 LICENSE="LGPL-2.1+"
  12 SLOT="0.46"
  13 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~x86-linux"
  14 IUSE="test valadoc"
  15 RESTRICT="!test? ( test )"
  16
  17 RDEPEND="
  18         >=dev-libs/glib-2.48.0:2
  19         >=dev-libs/vala-common-${PV}
  20         valadoc? ( >=media-gfx/graphviz-2.16 )
  21         !<net-libs/libsoup-2.66.2[vala]
  22 " # Older libsoup generates a libsoup-2.4.vapi that isn't fine for vala:0.46 anymore
  23 # We block here, so libsoup[vala] consumers wouldn't have to >= it, which would be bad
  24 # as the newer is not required with older vala when those are picked instead of 0.46.
  25 # vala-0.45.91 ships a broken libsoup-2.4.vapi copy too, but that'll be fixed by 0.45.92
  26 DEPEND="${RDEPEND}
  27         dev-libs/libxslt
  28         sys-devel/flex
  29         virtual/pkgconfig
  30         virtual/yacc
  31         test? (
  32                 dev-libs/dbus-glib
  33                 >=dev-libs/glib-2.26:2
  34                 dev-libs/gobject-introspection )
  35 "
  36
  37 src_configure() {
  38         # weasyprint enables generation of PDF from HTML
  39         gnome2_src_configure \
  40                 --disable-unversioned \
  41                 $(use_enable valadoc) \
  42                 VALAC=: \
  43                 WEASYPRINT=:
  44 }
  45
  46 src_install() {
  47         default
  48         find "${D}" -name "*.la" -delete || die
  49 }