dev-lang/vala/vala-0.46.3.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit gnome2
   7
   8 DESCRIPTION="Compiler for the GObject type system"
   9 HOMEPAGE="https://wiki.gnome.org/Projects/Vala"
  10
  11 LICENSE="LGPL-2.1+"
  12 SLOT="0.46"
  13 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-linux"
  14 IUSE="test valadoc"
  15
  16 RDEPEND="
  17         >=dev-libs/glib-2.48.0:2
  18         >=dev-libs/vala-common-${PV}
  19         valadoc? ( >=media-gfx/graphviz-2.16 )
  20         !<net-libs/libsoup-2.66.2[vala]
  21 " # Older libsoup generates a libsoup-2.4.vapi that isn't fine for vala:0.46 anymore
  22 # We block here, so libsoup[vala] consumers wouldn't have to >= it, which would be bad
  23 # as the newer is not required with older vala when those are picked instead of 0.46.
  24 # vala-0.45.91 ships a broken libsoup-2.4.vapi copy too, but that'll be fixed by 0.45.92
  25 DEPEND="${RDEPEND}
  26         dev-libs/libxslt
  27         sys-devel/flex
  28         virtual/pkgconfig
  29         virtual/yacc
  30         test? (
  31                 dev-libs/dbus-glib
  32                 >=dev-libs/glib-2.26:2
  33                 dev-libs/gobject-introspection )
  34 "
  35
  36 src_configure() {
  37         # weasyprint enables generation of PDF from HTML
  38         gnome2_src_configure \
  39                 --disable-unversioned \
  40                 $(use_enable valadoc) \
  41                 VALAC=: \
  42                 WEASYPRINT=:
  43 }
  44
  45 src_install() {
  46         default
  47         find "${D}" -name "*.la" -delete || die
  48 }