dev-lang/tk/tk-8.5.17-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 inherit autotools eutils multilib prefix toolchain-funcs versionator virtualx
   7
   8 MY_P="${PN}${PV/_beta/b}"
   9
  10 DESCRIPTION="Tk Widget Set"
  11 HOMEPAGE="http://www.tcl.tk/"
  12 SRC_URI="mirror://sourceforge/tcl/${MY_P}-src.tar.gz"
  13
  14 LICENSE="tcltk"
  15 SLOT="0/8.5"
  16 KEYWORDS="~alpha amd64 arm hppa ia64 ~mips ppc ppc64 s390 sh sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  17 IUSE="debug threads truetype aqua xscreensaver"
  18 RESTRICT="!test? ( test )"
  19
  20 RDEPEND="
  21         !aqua? (
  22                 media-libs/fontconfig
  23                 media-libs/freetype:2
  24                 x11-libs/libX11
  25                 x11-libs/libXt
  26                 truetype? ( x11-libs/libXft )
  27                 xscreensaver? ( x11-libs/libXScrnSaver )
  28         )
  29         ~dev-lang/tcl-${PV}:0="
  30 DEPEND="${RDEPEND}
  31         !aqua? ( x11-base/xorg-proto )"
  32
  33 SPARENT="${WORKDIR}/${MY_P}"
  34 S="${SPARENT}"/unix
  35
  36 src_prepare() {
  37         epatch \
  38                 "${FILESDIR}"/${PN}-8.5.11-fedora-xft.patch \
  39                 "${FILESDIR}"/${PN}-8.5.13-multilib.patch
  40
  41         epatch "${FILESDIR}"/${PN}-8.4.15-aqua.patch
  42         eprefixify Makefile.in
  43
  44         # Bug 125971
  45         epatch "${FILESDIR}"/${PN}-8.5.14-conf.patch
  46
  47         # Bug 648570
  48         epatch "${FILESDIR}"/${PN}-8.6.8-libieee.patch
  49
  50         # Make sure we use the right pkg-config, and link against fontconfig
  51         # (since the code base uses Fc* functions).
  52         sed \
  53                 -e 's/FT_New_Face/XftFontOpen/g' \
  54                 -e "s:\<pkg-config\>:$(tc-getPKG_CONFIG):" \
  55                 -e 's:xft freetype2:xft freetype2 fontconfig:' \
  56                 -i configure.in || die
  57         rm -f configure || die
  58
  59         sed \
  60                 -e '/chmod/s:555:755:g' \
  61                 -i Makefile.in || die
  62
  63         tc-export CC
  64
  65         eautoconf
  66 }
  67
  68 src_configure() {
  69         local mylibdir=$(get_libdir)
  70
  71         econf \
  72                 --with-tcl="${EPREFIX}/usr/${mylibdir}" \
  73                 $(use_enable threads) \
  74                 $(use_enable aqua) \
  75                 $(use_enable truetype xft) \
  76                 $(use_enable xscreensaver xss) \
  77                 $(use_enable debug symbols)
  78 }
  79
  80 src_test() {
  81         Xemake test
  82 }
  83
  84 src_install() {
  85         #short version number
  86         local v1=$(get_version_component_range 1-2)
  87         local mylibdir=$(get_libdir)
  88
  89         S= default
  90
  91         # normalize $S path, bug #280766 (pkgcore)
  92         local nS="$(cd "${S}"; pwd)"
  93
  94         # fix the tkConfig.sh to eliminate refs to the build directory
  95         # and drop unnecessary -L inclusion to default system libdir
  96
  97         sed \
  98                 -e "/^TK_BUILD_LIB_SPEC=/s:-L${SPARENT}.*unix *::g" \
  99                 -e "/^TK_LIB_SPEC=/s:-L${EPREFIX}/usr/${mylibdir} *::g" \
 100                 -e "/^TK_SRC_DIR=/s:${SPARENT}:${EPREFIX}/usr/${mylibdir}/tk${v1}/include:g" \
 101                 -e "/^TK_BUILD_STUB_LIB_SPEC=/s:-L${SPARENT}.*unix *::g" \
 102                 -e "/^TK_STUB_LIB_SPEC=/s:-L${EPREFIX}/usr/${mylibdir} *::g" \
 103                 -e "/^TK_BUILD_STUB_LIB_PATH=/s:${SPARENT}.*unix:${EPREFIX}/usr/${mylibdir}:g" \
 104                 -e "/^TK_LIB_FILE=/s:'libtk${v1}..TK_DBGX..so':\"libk${v1}\$\{TK_DBGX\}.so\":g" \
 105                 -i "${ED}"/usr/${mylibdir}/tkConfig.sh || die
 106         if use prefix && [[ ${CHOST} != *-darwin* && ${CHOST} != *-mint* ]] ; then
 107                 sed \
 108                         -e "/^TK_CC_SEARCH_FLAGS=/s|'$|:${EPREFIX}/usr/${mylibdir}'|g" \
 109                         -e "/^TK_LD_SEARCH_FLAGS=/s|'$|:${EPREFIX}/usr/${mylibdir}'|" \
 110                         -i "${ED}"/usr/${mylibdir}/tkConfig.sh || die
 111         fi
 112
 113         # install private headers
 114         insinto /usr/${mylibdir}/tk${v1}/include/unix
 115         doins "${S}"/*.h
 116         insinto /usr/${mylibdir}/tk${v1}/include/generic
 117         doins "${SPARENT}"/generic/*.h
 118         rm -f "${ED}"/usr/${mylibdir}/tk${v1}/include/generic/{tk,tkDecls,tkPlatDecls}.h || die
 119
 120         # install symlink for libraries
 121         dosym libtk${v1}$(get_libname) /usr/${mylibdir}/libtk$(get_libname)
 122         dosym libtkstub${v1}.a /usr/${mylibdir}/libtkstub.a
 123
 124         dosym wish${v1} /usr/bin/wish
 125
 126         dodoc "${SPARENT}"/{ChangeLog*,README,changes}
 127 }