dev-lang/tk/tk-8.5.17-r1.ebuild

   1 # Copyright 1999-2018 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 inherit autotools eutils multilib prefix toolchain-funcs versionator virtualx
   7
   8 MY_P="${PN}${PV/_beta/b}"
   9
  10 DESCRIPTION="Tk Widget Set"
  11 HOMEPAGE="http://www.tcl.tk/"
  12 SRC_URI="mirror://sourceforge/tcl/${MY_P}-src.tar.gz"
  13
  14 LICENSE="tcltk"
  15 SLOT="0/8.5"
  16 KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 s390 sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  17 IUSE="debug threads truetype aqua xscreensaver"
  18
  19 RDEPEND="
  20         !aqua? (
  21                 media-libs/fontconfig
  22                 media-libs/freetype:2
  23                 x11-libs/libX11
  24                 x11-libs/libXt
  25                 truetype? ( x11-libs/libXft )
  26                 xscreensaver? ( x11-libs/libXScrnSaver )
  27         )
  28         ~dev-lang/tcl-${PV}:0="
  29 DEPEND="${RDEPEND}
  30         !aqua? ( x11-base/xorg-proto )"
  31
  32 SPARENT="${WORKDIR}/${MY_P}"
  33 S="${SPARENT}"/unix
  34
  35 src_prepare() {
  36         epatch \
  37                 "${FILESDIR}"/${PN}-8.5.11-fedora-xft.patch \
  38                 "${FILESDIR}"/${PN}-8.5.13-multilib.patch
  39
  40         epatch "${FILESDIR}"/${PN}-8.4.15-aqua.patch
  41         eprefixify Makefile.in
  42
  43         # Bug 125971
  44         epatch "${FILESDIR}"/${PN}-8.5.14-conf.patch
  45
  46         # Bug 648570
  47         epatch "${FILESDIR}"/${PN}-8.6.8-libieee.patch
  48
  49         # Make sure we use the right pkg-config, and link against fontconfig
  50         # (since the code base uses Fc* functions).
  51         sed \
  52                 -e 's/FT_New_Face/XftFontOpen/g' \
  53                 -e "s:\<pkg-config\>:$(tc-getPKG_CONFIG):" \
  54                 -e 's:xft freetype2:xft freetype2 fontconfig:' \
  55                 -i configure.in || die
  56         rm -f configure || die
  57
  58         sed \
  59                 -e '/chmod/s:555:755:g' \
  60                 -i Makefile.in || die
  61
  62         tc-export CC
  63
  64         eautoconf
  65 }
  66
  67 src_configure() {
  68         local mylibdir=$(get_libdir)
  69
  70         econf \
  71                 --with-tcl="${EPREFIX}/usr/${mylibdir}" \
  72                 $(use_enable threads) \
  73                 $(use_enable aqua) \
  74                 $(use_enable truetype xft) \
  75                 $(use_enable xscreensaver xss) \
  76                 $(use_enable debug symbols)
  77 }
  78
  79 src_test() {
  80         Xemake test
  81 }
  82
  83 src_install() {
  84         #short version number
  85         local v1=$(get_version_component_range 1-2)
  86         local mylibdir=$(get_libdir)
  87
  88         S= default
  89
  90         # normalize $S path, bug #280766 (pkgcore)
  91         local nS="$(cd "${S}"; pwd)"
  92
  93         # fix the tkConfig.sh to eliminate refs to the build directory
  94         # and drop unnecessary -L inclusion to default system libdir
  95
  96         sed \
  97                 -e "/^TK_BUILD_LIB_SPEC=/s:-L${SPARENT}.*unix *::g" \
  98                 -e "/^TK_LIB_SPEC=/s:-L${EPREFIX}/usr/${mylibdir} *::g" \
  99                 -e "/^TK_SRC_DIR=/s:${SPARENT}:${EPREFIX}/usr/${mylibdir}/tk${v1}/include:g" \
 100                 -e "/^TK_BUILD_STUB_LIB_SPEC=/s:-L${SPARENT}.*unix *::g" \
 101                 -e "/^TK_STUB_LIB_SPEC=/s:-L${EPREFIX}/usr/${mylibdir} *::g" \
 102                 -e "/^TK_BUILD_STUB_LIB_PATH=/s:${SPARENT}.*unix:${EPREFIX}/usr/${mylibdir}:g" \
 103                 -e "/^TK_LIB_FILE=/s:'libtk${v1}..TK_DBGX..so':\"libk${v1}\$\{TK_DBGX\}.so\":g" \
 104                 -i "${ED}"/usr/${mylibdir}/tkConfig.sh || die
 105         if use prefix && [[ ${CHOST} != *-darwin* && ${CHOST} != *-mint* ]] ; then
 106                 sed \
 107                         -e "/^TK_CC_SEARCH_FLAGS=/s|'$|:${EPREFIX}/usr/${mylibdir}'|g" \
 108                         -e "/^TK_LD_SEARCH_FLAGS=/s|'$|:${EPREFIX}/usr/${mylibdir}'|" \
 109                         -i "${ED}"/usr/${mylibdir}/tkConfig.sh || die
 110         fi
 111
 112         # install private headers
 113         insinto /usr/${mylibdir}/tk${v1}/include/unix
 114         doins "${S}"/*.h
 115         insinto /usr/${mylibdir}/tk${v1}/include/generic
 116         doins "${SPARENT}"/generic/*.h
 117         rm -f "${ED}"/usr/${mylibdir}/tk${v1}/include/generic/{tk,tkDecls,tkPlatDecls}.h || die
 118
 119         # install symlink for libraries
 120         dosym libtk${v1}$(get_libname) /usr/${mylibdir}/libtk$(get_libname)
 121         dosym libtkstub${v1}.a /usr/${mylibdir}/libtkstub.a
 122
 123         dosym wish${v1} /usr/bin/wish
 124
 125         dodoc "${SPARENT}"/{ChangeLog*,README,changes}
 126 }