dev-lang/swi-prolog/swi-prolog-8.1.32.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit cmake-utils eutils flag-o-matic multilib
   7
   8 PATCHSET_VER="0"
   9
  10 DESCRIPTION="versatile implementation of the Prolog programming language"
  11 HOMEPAGE="http://www.swi-prolog.org/"
  12 SRC_URI="http://www.swi-prolog.org/download/devel/src/swipl-${PV}.tar.gz"
  13
  14 LICENSE="BSD-2"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
  17 IUSE="archive berkdb debug doc +gmp java +libedit libressl minimal odbc pcre qt5 readline ssl test uuid X yaml"
  18 RESTRICT="!test? ( test )"
  19
  20 RDEPEND="sys-libs/ncurses:=
  21         sys-libs/zlib
  22         archive? ( app-arch/libarchive )
  23         berkdb? ( >=sys-libs/db-4:= )
  24         odbc? ( dev-db/unixODBC )
  25         pcre? ( dev-libs/libpcre )
  26         readline? ( sys-libs/readline:= )
  27         libedit? ( dev-libs/libedit )
  28         gmp? ( dev-libs/gmp:0 )
  29         ssl? (
  30                 !libressl? ( dev-libs/openssl:0 )
  31                 libressl? ( dev-libs/libressl )
  32         )
  33         java? ( >=virtual/jdk-1.7:= )
  34         uuid? ( dev-libs/ossp-uuid )
  35         qt5? (
  36                 dev-qt/qtwidgets:5
  37                 dev-qt/qtgui:5
  38         )
  39         X? (
  40                 virtual/jpeg:0
  41                 x11-libs/libX11
  42                 x11-libs/libXft
  43                 x11-libs/libXinerama
  44                 x11-libs/libXpm
  45                 x11-libs/libXt
  46                 x11-libs/libICE
  47                 x11-libs/libSM )
  48         yaml? ( dev-libs/libyaml )"
  49
  50 DEPEND="${RDEPEND}
  51         X? ( x11-base/xorg-proto )
  52         java? ( test? ( =dev-java/junit-3.8* ) )"
  53
  54 S="${WORKDIR}/swipl-${PV}"
  55 BUILD_DIR="${S}/build"
  56 CMAKE_USE_DIR="${S}"
  57
  58 src_prepare() {
  59         if [[ -d "${WORKDIR}"/${PV} ]] ; then
  60                 eapply "${WORKDIR}"/${PV}
  61         fi
  62         eapply_user
  63
  64         sed -i -e "s|\(SWIPL_INSTALL_PREFIX\)   lib/.*)|\1   $(get_libdir)/swipl)|" CMakeLists.txt || die
  65
  66         cmake-utils_src_prepare
  67 }
  68
  69 src_configure() {
  70         append-flags -fno-strict-aliasing
  71         use debug && append-flags -DO_DEBUG
  72
  73         mycmakeargs=(
  74                 -DSWIPL_INSTALL_PREFIX=$(get_libdir)/swipl
  75                 -DUSE_GMP=$(usex gmp)
  76                 -DINSTALL_DOCUMENTATION=$(use doc && usex archive)
  77                 -DSWIPL_PACKAGES_BASIC=$(usex !minimal)
  78                 -DSWIPL_PACKAGES_ARCHIVE=$(usex archive)
  79                 -DSWIPL_PACKAGES_ODBC=$(usex odbc)
  80                 -DSWIPL_PACKAGES_BDB=$(usex berkdb)
  81                 -DSWIPL_PACKAGES_PCRE=$(usex pcre)
  82                 -DSWIPL_PACKAGES_YAML=$(usex yaml)
  83                 -DSWIPL_PACKAGES_SSL=$(usex ssl)
  84                 -DSWIPL_PACKAGES_JAVA=$(usex java)
  85                 -DSWIPL_PACKAGES_QT=$(usex qt5)
  86                 -DSWIPL_PACKAGES_X=$(usex X)
  87                 -DSWIPL_PACKAGES_TERM=$(if use libedit || use readline; then echo yes; else echo no; fi)
  88                 )
  89
  90         cmake-utils_src_configure
  91 }
  92
  93 src_compile() {
  94         XDG_CONFIG_DIRS="${HOME}" \
  95         XDG_DATA_DIRS="${HOME}" \
  96                 cmake-utils_src_compile
  97 }
  98
  99 src_test() {
 100         USE_PUBLIC_NETWORK_TESTS=false \
 101         USE_ODBC_TESTS=false \
 102                 cmake-utils_src_test -V
 103 }