dev-lang/spidermonkey/spidermonkey-1.7.0-r3.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5
   6 inherit eutils toolchain-funcs multilib flag-o-matic
   7
   8 MY_P="js-${PV}"
   9 DESCRIPTION="Stand-alone JavaScript C library"
  10 HOMEPAGE="https://developer.mozilla.org/en-US/docs/Mozilla/Projects/SpiderMonkey"
  11 SRC_URI="http://archive.mozilla.org/pub/js/${MY_P}.tar.gz
  12         https://dev.gentoo.org/~axs/distfiles/${PN}-slot0-patches-01.tar.xz
  13         "
  14
  15 LICENSE="NPL-1.1"
  16 SLOT="0/js"
  17 KEYWORDS="~alpha amd64 ~arm ppc ppc64 x86"
  18 IUSE="threadsafe unicode"
  19
  20 S="${WORKDIR}/js/src"
  21
  22 RDEPEND="threadsafe? ( dev-libs/nspr )"
  23 DEPEND="${RDEPEND}"
  24
  25 src_prepare() {
  26         epatch "${WORKDIR}"/sm0/${PN}-1.5-build.patch \
  27                 "${WORKDIR}"/sm0/${PN}-1.6-header.patch \
  28                 "${WORKDIR}"/sm0/${P}-threadsafe.diff \
  29                 "${WORKDIR}"/sm0/${P}-ldflags.patch
  30
  31         # don't force owner for Prefix
  32         sed -i -e '/^INSTALL :=/s/-g 0 -o root//' Makefile.ref || die
  33
  34         if [[ ${CHOST} == *-freebsd* ]]; then
  35                 # Don't try to be smart, this does not work in cross-compile anyway
  36                 ln -s "${S}/config/Linux_All.mk" "${S}/config/$(uname -s)$(uname -r).mk"
  37         fi
  38 }
  39
  40 src_compile() {
  41         use unicode && append-flags "-DJS_C_STRINGS_ARE_UTF8"
  42         tc-export CC LD AR RANLIB
  43         local threadsafe=""
  44         use threadsafe && threadsafe="JS_THREADSAFE=1"
  45         emake -j1 -f Makefile.ref LIBDIR="$(get_libdir)" ${threadsafe} \
  46                 XLDFLAGS="$(raw-ldflags)" HOST_LDFLAGS="${LDFLAGS}"
  47 }
  48
  49 src_install() {
  50         emake -f Makefile.ref install DESTDIR="${ED}" LIBDIR="$(get_libdir)"
  51         dodoc ../jsd/README
  52         dohtml README.html
  53 }