dev-lang/php/php-5.6.11.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit eutils autotools flag-o-matic versionator depend.apache apache-module db-use libtool systemd
   8
   9 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
  10
  11 function php_get_uri ()
  12 {
  13         case "${1}" in
  14                 "php-pre")
  15                         echo "http://downloads.php.net/dsp/${2}"
  16                 ;;
  17                 "php")
  18                         echo "http://www.php.net/distributions/${2}"
  19                 ;;
  20                 "olemarkus")
  21                         echo "https://dev.gentoo.org/~olemarkus/php/${2}"
  22                 ;;
  23                 "gentoo")
  24                         echo "mirror://gentoo/${2}"
  25                 ;;
  26                 *)
  27                         die "unhandled case in php_get_uri"
  28                 ;;
  29         esac
  30 }
  31
  32 PHP_MV="$(get_major_version)"
  33 SLOT="$(get_version_component_range 1-2)"
  34
  35 # alias, so we can handle different types of releases (finals, rcs, alphas,
  36 # betas, ...) w/o changing the whole ebuild
  37 PHP_PV="${PV/_rc/RC}"
  38 PHP_PV="${PHP_PV/_alpha/alpha}"
  39 PHP_PV="${PHP_PV/_beta/beta}"
  40 PHP_RELEASE="php"
  41 [[ ${PV} == ${PV/_alpha/} ]] || PHP_RELEASE="php-pre"
  42 [[ ${PV} == ${PV/_beta/} ]] || PHP_RELEASE="php-pre"
  43 [[ ${PV} == ${PV/_rc/} ]] || PHP_RELEASE="php-pre"
  44 PHP_P="${PN}-${PHP_PV}"
  45
  46 PHP_SRC_URI="$(php_get_uri "${PHP_RELEASE}" "${PHP_P}.tar.bz2")"
  47
  48 PHP_FPM_CONF_VER="1"
  49
  50 SRC_URI="${PHP_SRC_URI}"
  51
  52 DESCRIPTION="The PHP language runtime engine: CLI, CGI, FPM/FastCGI, Apache2 and embed SAPIs"
  53 HOMEPAGE="http://php.net/"
  54 LICENSE="PHP-3"
  55
  56 S="${WORKDIR}/${PHP_P}"
  57
  58 # We can build the following SAPIs in the given order
  59 SAPIS="embed cli cgi fpm apache2"
  60
  61 # SAPIs and SAPI-specific USE flags (cli SAPI is default on):
  62 IUSE="${IUSE}
  63         ${SAPIS/cli/+cli}
  64         threads"
  65
  66 IUSE="${IUSE} bcmath berkdb bzip2 calendar cdb cjk
  67         crypt +ctype curl debug
  68         enchant exif frontbase +fileinfo +filter firebird
  69         flatfile ftp gd gdbm gmp +hash +iconv imap inifile
  70         intl iodbc ipv6 +json kerberos ldap ldap-sasl libedit mhash
  71         mssql mysql libmysqlclient mysqli nls
  72         oci8-instant-client odbc +opcache pcntl pdo +phar +posix postgres qdbm
  73         readline recode selinux +session sharedmem
  74         +simplexml snmp soap sockets spell sqlite ssl
  75         sybase-ct sysvipc systemd tidy +tokenizer truetype unicode vpx wddx
  76         +xml xmlreader xmlwriter xmlrpc xpm xslt zip zlib"
  77
  78 DEPEND="
  79         >=app-eselect/eselect-php-0.7.1-r3[apache2?,fpm?]
  80         >=dev-libs/libpcre-8.32[unicode]
  81         apache2? ( || ( >=www-servers/apache-2.4[apache2_modules_unixd,threads=]
  82                 <www-servers/apache-2.4[threads=] ) )
  83         berkdb? ( =sys-libs/db-4* )
  84         bzip2? ( app-arch/bzip2 )
  85         cdb? ( || ( dev-db/cdb dev-db/tinycdb ) )
  86         cjk? ( !gd? (
  87                 virtual/jpeg:0
  88                 media-libs/libpng:0=
  89                 sys-libs/zlib
  90         ) )
  91         crypt? ( >=dev-libs/libmcrypt-2.4 )
  92         curl? ( >=net-misc/curl-7.10.5 )
  93         enchant? ( app-text/enchant )
  94         exif? ( !gd? (
  95                 virtual/jpeg:0
  96                 media-libs/libpng:0=
  97                 sys-libs/zlib
  98         ) )
  99         firebird? ( dev-db/firebird )
 100         gd? ( virtual/jpeg:0 media-libs/libpng:0= sys-libs/zlib )
 101         gdbm? ( >=sys-libs/gdbm-1.8.0 )
 102         gmp? ( >=dev-libs/gmp-4.1.2 )
 103         iconv? ( virtual/libiconv )
 104         imap? ( virtual/imap-c-client[ssl=] )
 105         intl? ( dev-libs/icu:= )
 106         iodbc? ( dev-db/libiodbc )
 107         kerberos? ( virtual/krb5 )
 108         ldap? ( >=net-nds/openldap-1.2.11 )
 109         ldap-sasl? ( dev-libs/cyrus-sasl >=net-nds/openldap-1.2.11 )
 110         libedit? ( || ( sys-freebsd/freebsd-lib dev-libs/libedit ) )
 111         mssql? ( dev-db/freetds[mssql] )
 112         libmysqlclient? (
 113                 mysql? ( virtual/mysql )
 114                 mysqli? ( >=virtual/mysql-4.1 )
 115         )
 116         nls? ( sys-devel/gettext )
 117         oci8-instant-client? ( dev-db/oracle-instantclient-basic )
 118         odbc? ( >=dev-db/unixODBC-1.8.13 )
 119         postgres? ( dev-db/postgresql )
 120         qdbm? ( dev-db/qdbm )
 121         readline? ( sys-libs/readline )
 122         recode? ( app-text/recode )
 123         sharedmem? ( dev-libs/mm )
 124         simplexml? ( >=dev-libs/libxml2-2.6.8 )
 125         snmp? ( >=net-analyzer/net-snmp-5.2 )
 126         soap? ( >=dev-libs/libxml2-2.6.8 )
 127         spell? ( >=app-text/aspell-0.50 )
 128         sqlite? ( >=dev-db/sqlite-3.7.6.3 )
 129         ssl? ( >=dev-libs/openssl-0.9.7 )
 130         sybase-ct? ( dev-db/freetds )
 131         tidy? ( app-text/htmltidy )
 132         truetype? (
 133                 =media-libs/freetype-2*
 134                 >=media-libs/t1lib-5.0.0
 135                 !gd? (
 136                         virtual/jpeg:0 media-libs/libpng:0= sys-libs/zlib )
 137         )
 138         unicode? ( dev-libs/oniguruma )
 139         vpx? ( media-libs/libvpx )
 140         wddx? ( >=dev-libs/libxml2-2.6.8 )
 141         xml? ( >=dev-libs/libxml2-2.6.8 )
 142         xmlrpc? ( >=dev-libs/libxml2-2.6.8 virtual/libiconv )
 143         xmlreader? ( >=dev-libs/libxml2-2.6.8 )
 144         xmlwriter? ( >=dev-libs/libxml2-2.6.8 )
 145         xpm? (
 146                 x11-libs/libXpm
 147                 virtual/jpeg:0
 148                 media-libs/libpng:0= sys-libs/zlib
 149         )
 150         xslt? ( dev-libs/libxslt >=dev-libs/libxml2-2.6.8 )
 151         zip? ( sys-libs/zlib )
 152         zlib? ( sys-libs/zlib )
 153         virtual/mta
 154 "
 155
 156 php="=${CATEGORY}/${PF}"
 157
 158 REQUIRED_USE="
 159         truetype? ( gd )
 160         vpx? ( gd )
 161         cjk? ( gd )
 162         exif? ( gd )
 163
 164         xpm? ( gd )
 165         gd? ( zlib )
 166         simplexml? ( xml )
 167         soap? ( xml )
 168         wddx? ( xml )
 169         xmlrpc? ( || ( xml iconv ) )
 170         xmlreader? ( xml )
 171         xslt? ( xml )
 172         ldap-sasl? ( ldap )
 173         mhash? ( hash )
 174         phar? ( hash )
 175         libmysqlclient? ( || (
 176                 mysql
 177                 mysqli
 178                 pdo
 179         ) )
 180
 181         qdbm? ( !gdbm )
 182         readline? ( !libedit )
 183         recode? ( !imap !mysql !mysqli )
 184         sharedmem? ( !threads )
 185
 186         !cli? ( !cgi? ( !fpm? ( !apache2? ( !embed? ( cli ) ) ) ) )"
 187
 188 RDEPEND="${DEPEND}"
 189
 190 RDEPEND="${RDEPEND}
 191         fpm? (
 192                 selinux? ( sec-policy/selinux-phpfpm )
 193                 systemd? ( sys-apps/systemd ) )"
 194
 195 DEPEND="${DEPEND}
 196         sys-devel/flex
 197         >=sys-devel/m4-1.4.3
 198         >=sys-devel/libtool-1.5.18"
 199
 200 # Allow users to install production version if they want to
 201
 202 case "${PHP_INI_VERSION}" in
 203         production|development)
 204                 ;;
 205         *)
 206                 PHP_INI_VERSION="development"
 207                 ;;
 208 esac
 209
 210 PHP_INI_UPSTREAM="php.ini-${PHP_INI_VERSION}"
 211 PHP_INI_FILE="php.ini"
 212
 213 want_apache
 214
 215 pkg_setup() {
 216         depend.apache_pkg_setup
 217 }
 218
 219 php_install_ini() {
 220         local phpsapi="${1}"
 221
 222         # work out where we are installing the ini file
 223         php_set_ini_dir "${phpsapi}"
 224
 225         local phpinisrc="${PHP_INI_UPSTREAM}-${phpsapi}"
 226         cp "${PHP_INI_UPSTREAM}" "${phpinisrc}"
 227
 228         # default to /tmp for save_path, bug #282768
 229         sed -e 's|^;session.save_path .*$|session.save_path = "'"${EPREFIX}"'/tmp"|g' -i "${phpinisrc}"
 230
 231         # Set the extension dir
 232         sed -e "s|^extension_dir .*$|extension_dir = ${extension_dir}|g" -i "${phpinisrc}"
 233
 234         # Set the include path to point to where we want to find PEAR packages
 235         sed -e 's|^;include_path = ".:/php/includes".*|include_path = ".:'"${EPREFIX}"'/usr/share/php'${PHP_MV}':'"${EPREFIX}"'/usr/share/php"|' -i "${phpinisrc}"
 236
 237         dodir "${PHP_INI_DIR#${EPREFIX}}"
 238         insinto "${PHP_INI_DIR#${EPREFIX}}"
 239         newins "${phpinisrc}" "${PHP_INI_FILE}"
 240
 241         elog "Installing php.ini for ${phpsapi} into ${PHP_INI_DIR#${EPREFIX}}"
 242         elog
 243
 244         dodir "${PHP_EXT_INI_DIR#${EPREFIX}}"
 245         dodir "${PHP_EXT_INI_DIR_ACTIVE#${EPREFIX}}"
 246
 247         if use_if_iuse opcache; then
 248                 elog "Adding opcache to $PHP_EXT_INI_DIR"
 249                 echo "zend_extension=${PHP_DESTDIR}/$(get_libdir)/opcache.so" >> "${D}/${PHP_EXT_INI_DIR}"/opcache.ini
 250                 dosym "${PHP_EXT_INI_DIR#${EPREFIX}}/opcache.ini" "${PHP_EXT_INI_DIR_ACTIVE#${EPREFIX}}/opcache.ini"
 251         fi
 252
 253         # SAPI-specific handling
 254
 255         if [[ "${sapi}" == "fpm" ]] ; then
 256                 [[ -z ${PHP_FPM_CONF_VER} ]] && PHP_FPM_CONF_VER=0
 257                 einfo "Installing FPM CGI config file php-fpm.conf"
 258                 insinto "${PHP_INI_DIR#${EPREFIX}}"
 259                 newins "${FILESDIR}/php-fpm-r${PHP_FPM_CONF_VER}.conf" php-fpm.conf
 260
 261                 # Remove bogus /etc/php-fpm.conf.default (bug 359906)
 262                 [[ -f "${ED}/etc/php-fpm.conf.default" ]] && rm "${ED}/etc/php-fpm.conf.default"
 263         fi
 264
 265         # Install PHP ini files into /usr/share/php
 266
 267         dodoc php.ini-development
 268         dodoc php.ini-production
 269
 270 }
 271
 272 php_set_ini_dir() {
 273         PHP_INI_DIR="${EPREFIX}/etc/php/${1}-php${SLOT}"
 274         PHP_EXT_INI_DIR="${PHP_INI_DIR}/ext"
 275         PHP_EXT_INI_DIR_ACTIVE="${PHP_INI_DIR}/ext-active"
 276 }
 277
 278 src_prepare() {
 279         # USE=sharedmem (session/mod_mm to be exact) tries to mmap() this path
 280         # ([empty session.save_path]/session_mm_[sapi][gid].sem)
 281         # there is no easy way to circumvent that, all php calls during
 282         # install use -n, so no php.ini file will be used.
 283         # As such, this is the easiest way to get around
 284         addpredict /session_mm_cli250.sem
 285         addpredict /session_mm_cli0.sem
 286
 287         # Change PHP branding
 288         # Get the alpha/beta/rc version
 289         sed -re "s|^(PHP_EXTRA_VERSION=\").*(\")|\1-pl${PR/r/}-gentoo\2|g" \
 290                 -i configure.in || die "Unable to change PHP branding"
 291
 292         # Patch PHP to show Gentoo as the server platform
 293         sed -e 's/PHP_UNAME=`uname -a | xargs`/PHP_UNAME=`uname -s -n -r -v | xargs`/g' \
 294                 -i configure.in || die "Failed to fix server platform name"
 295
 296         # Prevent PHP from activating the Apache config,
 297         # as we will do that ourselves
 298         sed -i \
 299                 -e "s,-i -a -n php${PHP_MV},-i -n php${PHP_MV},g" \
 300                 -e "s,-i -A -n php${PHP_MV},-i -n php${PHP_MV},g" \
 301                 configure sapi/apache2filter/config.m4 sapi/apache2handler/config.m4
 302
 303         # Patch PHP to support heimdal instead of mit-krb5
 304         if has_version "app-crypt/heimdal" ; then
 305                 sed -e 's|gssapi_krb5|gssapi|g' -i acinclude.m4 \
 306                         || die "Failed to fix heimdal libname"
 307                 sed -e 's|PHP_ADD_LIBRARY(k5crypto, 1, $1)||g' -i acinclude.m4 \
 308                         || die "Failed to fix heimdal crypt library reference"
 309         fi
 310
 311         #Add user patches #357637
 312         epatch_user
 313
 314         #force rebuilding aclocal.m4
 315         rm aclocal.m4
 316         eautoreconf
 317
 318         if [[ ${CHOST} == *-darwin* ]] ; then
 319                 # http://bugs.php.net/bug.php?id=48795, bug #343481
 320                 sed -i -e '/BUILD_CGI="\\$(CC)/s/CC/CXX/' configure || die
 321         fi
 322 }
 323
 324 src_configure() {
 325         addpredict /usr/share/snmp/mibs/.index
 326         addpredict /var/lib/net-snmp/mib_indexes
 327
 328         PHP_DESTDIR="${EPREFIX}/usr/$(get_libdir)/php${SLOT}"
 329
 330         # This is a global variable and should be in caps. It isn't because the
 331         # phpconfutils eclass relies on exactly this name...
 332         # for --with-libdir see bug #327025
 333         my_conf="
 334                 --prefix="${PHP_DESTDIR}"
 335                 --mandir="${PHP_DESTDIR}"/man
 336                 --infodir="${PHP_DESTDIR}"/info
 337                 --libdir="${PHP_DESTDIR}"/lib
 338                 --with-libdir=$(get_libdir)
 339                 --without-pear
 340                 $(use_enable threads maintainer-zts)"
 341
 342         #                             extension           USE flag        shared
 343         my_conf+="
 344         $(use_enable bcmath bcmath )
 345         $(use_with bzip2 bz2 "${EPREFIX}"/usr)
 346         $(use_enable calendar calendar )
 347         $(use_enable ctype ctype )
 348         $(use_with curl curl "${EPREFIX}"/usr)
 349         $(use_enable xml dom )
 350         $(use_with enchant enchant "${EPREFIX}"/usr)
 351         $(use_enable exif exif )
 352         $(use_enable fileinfo fileinfo )
 353         $(use_enable filter filter )
 354         $(use_enable ftp ftp )
 355         $(use_with nls gettext "${EPREFIX}"/usr)
 356         $(use_with gmp gmp "${EPREFIX}"/usr)
 357         $(use_enable hash hash )
 358         $(use_with mhash mhash "${EPREFIX}"/usr)
 359         $(use_with iconv iconv $(use elibc_glibc || use elibc_musl || echo "${EPREFIX}"/usr))
 360         $(use_enable intl intl )
 361         $(use_enable ipv6 ipv6 )
 362         $(use_enable json json )
 363         $(use_with kerberos kerberos "${EPREFIX}"/usr)
 364         $(use_enable xml libxml )
 365         $(use_with xml libxml-dir "${EPREFIX}"/usr)
 366         $(use_enable unicode mbstring )
 367         $(use_with crypt mcrypt "${EPREFIX}"/usr)
 368         $(use_with mssql mssql "${EPREFIX}"/usr)
 369         $(use_with unicode onig "${EPREFIX}"/usr)
 370         $(use_with ssl openssl "${EPREFIX}"/usr)
 371         $(use_with ssl openssl-dir "${EPREFIX}"/usr)
 372         $(use_enable pcntl pcntl )
 373         $(use_enable phar phar )
 374         $(use_enable pdo pdo )
 375         $(use_enable opcache opcache )
 376         $(use_with postgres pgsql "${EPREFIX}"/usr)
 377         $(use_enable posix posix )
 378         $(use_with spell pspell "${EPREFIX}"/usr)
 379         $(use_with recode recode "${EPREFIX}"/usr)
 380         $(use_enable simplexml simplexml )
 381         $(use_enable sharedmem shmop )
 382         $(use_with snmp snmp "${EPREFIX}"/usr)
 383         $(use_enable soap soap )
 384         $(use_enable sockets sockets )
 385         $(use_with sqlite sqlite3 "${EPREFIX}"/usr)
 386         $(use_with sybase-ct sybase-ct "${EPREFIX}"/usr)
 387         $(use_enable sysvipc sysvmsg )
 388         $(use_enable sysvipc sysvsem )
 389         $(use_enable sysvipc sysvshm )
 390         $(use_with systemd fpm-systemd)
 391         $(use_with tidy tidy "${EPREFIX}"/usr)
 392         $(use_enable tokenizer tokenizer )
 393         $(use_enable wddx wddx )
 394         $(use_enable xml xml )
 395         $(use_enable xmlreader xmlreader )
 396         $(use_enable xmlwriter xmlwriter )
 397         $(use_with xmlrpc xmlrpc)
 398         $(use_with xslt xsl "${EPREFIX}"/usr)
 399         $(use_enable zip zip )
 400         $(use_with zlib zlib "${EPREFIX}"/usr)
 401         $(use_enable debug debug )"
 402
 403         # DBA support
 404         if use cdb || use berkdb || use flatfile || use gdbm || use inifile \
 405                 || use qdbm ; then
 406                 my_conf="${my_conf} --enable-dba${shared}"
 407         fi
 408
 409         # DBA drivers support
 410         my_conf+="
 411         $(use_with cdb cdb)
 412         $(use_with berkdb db4 ${EPREFIX}/usr)
 413         $(use_enable flatfile flatfile )
 414         $(use_with gdbm gdbm ${EPREFIX}/usr)
 415         $(use_enable inifile inifile )
 416         $(use_with qdbm qdbm ${EPREFIX}/usr)"
 417
 418         # Support for the GD graphics library
 419         my_conf+="
 420         $(use_with truetype freetype-dir ${EPREFIX}/usr)
 421         $(use_with truetype t1lib ${EPREFIX}/usr)
 422         $(use_enable cjk gd-jis-conv )
 423         $(use_with gd jpeg-dir ${EPREFIX}/usr)
 424         $(use_with gd png-dir ${EPREFIX}/usr)
 425         $(use_with xpm xpm-dir ${EPREFIX}/usr)
 426         $(use_with vpx vpx-dir ${EPREFIX}/usr)"
 427         # enable gd last, so configure can pick up the previous settings
 428         my_conf+="
 429         $(use_with gd gd)"
 430
 431         # IMAP support
 432         if use imap ; then
 433                 my_conf+="
 434                 $(use_with imap imap ${EPREFIX}/usr)
 435                 $(use_with ssl imap-ssl ${EPREFIX}/usr)"
 436         fi
 437
 438         # Interbase/firebird support
 439
 440         if use firebird ; then
 441                 my_conf+="
 442                 $(use_with firebird interbase ${EPREFIX}/usr)"
 443         fi
 444
 445         # LDAP support
 446         if use ldap ; then
 447                 my_conf+="
 448                 $(use_with ldap ldap ${EPREFIX}/usr)
 449                 $(use_with ldap-sasl ldap-sasl ${EPREFIX}/usr)"
 450         fi
 451
 452         # MySQL support
 453         local mysqllib="mysqlnd"
 454         local mysqlilib="mysqlnd"
 455         use libmysqlclient && mysqllib="${EPREFIX}/usr"
 456         use libmysqlclient && mysqlilib="${EPREFIX}/usr/bin/mysql_config"
 457
 458         my_conf+=" $(use_with mysql mysql $mysqllib)"
 459         my_conf+=" $(use_with mysqli mysqli $mysqlilib)"
 460
 461         local mysqlsock=" $(use_with mysql mysql-sock ${EPREFIX}/var/run/mysqld/mysqld.sock)"
 462         if use mysql ; then
 463                 my_conf+="${mysqlsock}"
 464         elif use mysqli ; then
 465                 my_conf+="${mysqlsock}"
 466         fi
 467
 468         # ODBC support
 469         if use odbc ; then
 470                 my_conf+="
 471                 $(use_with odbc unixODBC ${EPREFIX}/usr)"
 472         fi
 473
 474         if use iodbc ; then
 475                 my_conf+="
 476                 $(use_with iodbc iodbc ${EPREFIX}/usr)"
 477         fi
 478
 479         # Oracle support
 480         if use oci8-instant-client ; then
 481                 my_conf+="
 482                 $(use_with oci8-instant-client oci8)"
 483         fi
 484
 485         # PDO support
 486         if use pdo ; then
 487                 my_conf+="
 488                 $(use_with mssql pdo-dblib )
 489                 $(use_with mysql pdo-mysql ${mysqllib})
 490                 $(use_with postgres pdo-pgsql )
 491                 $(use_with sqlite pdo-sqlite ${EPREFIX}/usr)
 492                 $(use_with odbc pdo-odbc unixODBC,${EPREFIX}/usr)"
 493                 if use oci8-instant-client ; then
 494                         my_conf+="
 495                         $(use_with oci8-instant-client pdo-oci)"
 496                 fi
 497         fi
 498
 499         # readline/libedit support
 500         my_conf+="
 501         $(use_with readline readline ${EPREFIX}/usr)
 502         $(use_with libedit libedit ${EPREFIX}/usr)"
 503
 504         # Session support
 505         if use session ; then
 506                 my_conf+="
 507                 $(use_with sharedmem mm ${EPREFIX}/usr)"
 508         else
 509                 my_conf+="
 510                 $(use_enable session session )"
 511         fi
 512
 513         # Use pic for shared modules such as apache2's mod_php
 514         my_conf="${my_conf} --with-pic"
 515
 516         # we use the system copy of pcre
 517         # --with-pcre-regex affects ext/pcre
 518         # --with-pcre-dir affects ext/filter and ext/zip
 519         my_conf="${my_conf} --with-pcre-regex=${EPREFIX}/usr --with-pcre-dir=${EPREFIX}/usr"
 520
 521         # Catch CFLAGS problems
 522         # Fixes bug #14067.
 523         # Changed order to run it in reverse for bug #32022 and #12021.
 524         replace-cpu-flags "k6*" "i586"
 525
 526         # Support user-passed configuration parameters
 527         my_conf="${my_conf} ${EXTRA_ECONF:-}"
 528
 529         # Support the Apache2 extras, they must be set globally for all
 530         # SAPIs to work correctly, especially for external PHP extensions
 531
 532         mkdir -p "${WORKDIR}/sapis-build"
 533         for one_sapi in $SAPIS ; do
 534                 use "${one_sapi}" || continue
 535                 php_set_ini_dir "${one_sapi}"
 536
 537                 cp -r "${S}" "${WORKDIR}/sapis-build/${one_sapi}"
 538                 cd "${WORKDIR}/sapis-build/${one_sapi}"
 539
 540                 sapi_conf="${my_conf} --with-config-file-path=${PHP_INI_DIR}
 541                         --with-config-file-scan-dir=${PHP_EXT_INI_DIR_ACTIVE}"
 542
 543                 for sapi in $SAPIS ; do
 544                         case "$sapi" in
 545                                 cli|cgi|embed|fpm)
 546                                         if [[ "${one_sapi}" == "${sapi}" ]] ; then
 547                                                 sapi_conf="${sapi_conf} --enable-${sapi}"
 548                                         else
 549                                                 sapi_conf="${sapi_conf} --disable-${sapi}"
 550                                         fi
 551                                         ;;
 552
 553                                 apache2)
 554                                         if [[ "${one_sapi}" == "${sapi}" ]] ; then
 555                                                 sapi_conf="${sapi_conf} --with-apxs2=${EPREFIX}/usr/sbin/apxs"
 556                                         else
 557                                                 sapi_conf="${sapi_conf} --without-apxs2"
 558                                         fi
 559                                         ;;
 560                         esac
 561                 done
 562
 563                 econf ${sapi_conf}
 564         done
 565 }
 566
 567 src_compile() {
 568         # snmp seems to run during src_compile, too (bug #324739)
 569         addpredict /usr/share/snmp/mibs/.index
 570         addpredict /var/lib/net-snmp/mib_indexes
 571
 572         for sapi in ${SAPIS} ; do
 573                 if use "${sapi}"; then
 574                         cd "${WORKDIR}/sapis-build/$sapi" || "Failed to change dir to ${WORKDIR}/sapis-build/$1"
 575                         emake || die "emake failed"
 576                 fi
 577         done
 578 }
 579
 580 src_install() {
 581         # see bug #324739 for what happens when we don't have that
 582         addpredict /usr/share/snmp/mibs/.index
 583
 584         # grab the first SAPI that got built and install common files from there
 585         local first_sapi=""
 586         for sapi in $SAPIS ; do
 587                 if use $sapi ; then
 588                         first_sapi=$sapi
 589                         break
 590                 fi
 591         done
 592
 593         # Makefile forgets to create this before trying to write to it...
 594         dodir "${PHP_DESTDIR#${EPREFIX}}/bin"
 595
 596         # Install php environment (without any sapis)
 597         cd "${WORKDIR}/sapis-build/$first_sapi"
 598         emake INSTALL_ROOT="${D}" \
 599                 install-build install-headers install-programs \
 600                 || die "emake install failed"
 601
 602         local extension_dir="$("${ED}/${PHP_DESTDIR#${EPREFIX}}/bin/php-config" --extension-dir)"
 603
 604         # Create the directory where we'll put version-specific php scripts
 605         keepdir /usr/share/php${PHP_MV}
 606
 607         local sapi="", file=""
 608         local sapi_list=""
 609
 610         for sapi in ${SAPIS}; do
 611                 if use "${sapi}" ; then
 612                         einfo "Installing SAPI: ${sapi}"
 613                         cd "${WORKDIR}/sapis-build/${sapi}"
 614
 615                         if [[ "${sapi}" == "apache2" ]] ; then
 616                                 # We're specifically not using emake install-sapi as libtool
 617                                 # may cause unnecessary relink failures (see bug #351266)
 618                                 insinto "${PHP_DESTDIR#${EPREFIX}}/apache2/"
 619                                 newins ".libs/libphp5$(get_libname)" "libphp${PHP_MV}$(get_libname)"
 620                                 keepdir "/usr/$(get_libdir)/apache2/modules"
 621                         else
 622                                 # needed each time, php_install_ini would reset it
 623                                 local dest="${PHP_DESTDIR#${EPREFIX}}"
 624                                 into "${dest}"
 625                                 case "$sapi" in
 626                                         cli)
 627                                                 source="sapi/cli/php"
 628                                                 ;;
 629                                         cgi)
 630                                                 source="sapi/cgi/php-cgi"
 631                                                 ;;
 632                                         fpm)
 633                                                 source="sapi/fpm/php-fpm"
 634                                                 ;;
 635                                         embed)
 636                                                 source="libs/libphp${PHP_MV}$(get_libname)"
 637                                                 ;;
 638                                         *)
 639                                                 die "unhandled sapi in src_install"
 640                                                 ;;
 641                                 esac
 642
 643                                 if [[ "${source}" == *"$(get_libname)" ]]; then
 644                                         dolib.so "${source}" || die "Unable to install ${sapi} sapi"
 645                                 else
 646                                         dobin "${source}" || die "Unable to install ${sapi} sapi"
 647                                         local name="$(basename ${source})"
 648                                         dosym "${dest}/bin/${name}" "/usr/bin/${name}${SLOT}"
 649                                 fi
 650                         fi
 651
 652                         php_install_ini "${sapi}"
 653
 654                         # construct correct SAPI string for php-config
 655                         # thanks to ferringb for the bash voodoo
 656                         if [[ "${sapi}" == "apache2" ]]; then
 657                                 sapi_list="${sapi_list:+${sapi_list} }apache2handler"
 658                         else
 659                                 sapi_list="${sapi_list:+${sapi_list} }${sapi}"
 660                         fi
 661                 fi
 662         done
 663
 664         # Installing opcache module
 665         if use_if_iuse opcache ; then
 666                 dolib.so "modules/opcache$(get_libname)" || die "Unable to install opcache module"
 667         fi
 668
 669         # Install env.d files
 670         newenvd "${FILESDIR}/20php5-envd" \
 671                 "20php${SLOT}"
 672         sed -e "s|/lib/|/$(get_libdir)/|g" -i \
 673                 "${ED}/etc/env.d/20php${SLOT}"
 674         sed -e "s|php5|php${SLOT}|g" -i \
 675                 "${ED}/etc/env.d/20php${SLOT}"
 676
 677         # set php-config variable correctly (bug #278439)
 678         sed -e "s:^\(php_sapis=\)\".*\"$:\1\"${sapi_list}\":" -i \
 679                 "${ED}/usr/$(get_libdir)/php${SLOT}/bin/php-config"
 680
 681         if use fpm ; then
 682                 if use systemd; then
 683                         systemd_newunit "${FILESDIR}/php-fpm_at.service" "php-fpm@${SLOT}.service"
 684                 else
 685                         systemd_newunit "${FILESDIR}/php-fpm_at-simple.service" "php-fpm@${SLOT}.service"
 686                 fi
 687         fi
 688 }
 689
 690 src_test() {
 691         echo ">>> Test phase [test]: ${CATEGORY}/${PF}"
 692         PHP_BIN="${WORKDIR}/sapis-build/cli/sapi/cli/php"
 693         if [[ ! -x "${PHP_BIN}" ]] ; then
 694                 ewarn "Test phase requires USE=cli, skipping"
 695                 return
 696         else
 697                 export TEST_PHP_EXECUTABLE="${PHP_BIN}"
 698         fi
 699
 700         if [[ -x "${WORKDIR}/sapis/cgi/php-cgi" ]] ; then
 701                 export TEST_PHP_CGI_EXECUTABLE="${WORKDIR}/sapis/cgi/php-cgi"
 702         fi
 703
 704         REPORT_EXIT_STATUS=1 "${TEST_PHP_EXECUTABLE}" -n  -d "session.save_path=${T}" \
 705                 "${WORKDIR}/sapis-build/cli/run-tests.php" -n -q -d "session.save_path=${T}"
 706
 707         for name in ${EXPECTED_TEST_FAILURES}; do
 708                 mv "${name}.out" "${name}.out.orig" 2>/dev/null
 709         done
 710
 711         local failed="$(find -name '*.out')"
 712         if [[ ${failed} != "" ]] ; then
 713                 ewarn "The following test cases failed unexpectedly:"
 714                 for name in ${failed}; do
 715                         ewarn "  ${name/.out/}"
 716                 done
 717         else
 718                 einfo "No unexpected test failures, all fine"
 719         fi
 720
 721         if [[ ${PHP_SHOW_UNEXPECTED_TEST_PASS} == "1" ]] ; then
 722                 local passed=""
 723                 for name in ${EXPECTED_TEST_FAILURES}; do
 724                         [[ -f "${name}.diff" ]] && continue
 725                         passed="${passed} ${name}"
 726                 done
 727                 if [[ ${passed} != "" ]] ; then
 728                         einfo "The following test cases passed unexpectedly:"
 729                         for name in ${passed}; do
 730                                 ewarn "  ${passed}"
 731                         done
 732                 else
 733                         einfo "None of the known-to-fail tests passed, all fine"
 734                 fi
 735         fi
 736 }
 737
 738 pkg_postinst() {
 739         # Output some general info to the user
 740         if use apache2 ; then
 741                 APACHE2_MOD_DEFINE="PHP5"
 742                 APACHE2_MOD_CONF="70_mod_php5"  # actually provided by app-eselect/eselect-php
 743                 apache-module_pkg_postinst
 744         fi
 745
 746         # Create the symlinks for php
 747         for m in ${SAPIS}; do
 748                 [[ ${m} == 'embed' ]] && continue;
 749                 if use $m ; then
 750                         local ci=$(eselect php show $m)
 751                         if [[ -z $ci ]]; then
 752                                 eselect php set $m php${SLOT}
 753                                 einfo "Switched ${m} to use php:${SLOT}"
 754                                 einfo
 755                         elif [[ $ci != "php${SLOT}" ]] ; then
 756                                 elog "To switch $m to use php:${SLOT}, run"
 757                                 elog "    eselect php set $m php${SLOT}"
 758                                 elog
 759                         fi
 760                 fi
 761         done
 762
 763         elog "Make sure that PHP_TARGETS in ${EPREFIX}/etc/make.conf includes php${SLOT/./-} in order"
 764         elog "to compile extensions for the ${SLOT} ABI"
 765         elog
 766         if ! use readline && use cli ; then
 767                 ewarn "Note that in order to use php interactivly, you need to enable"
 768                 ewarn "the readline USE flag or php -a will hang"
 769         fi
 770         elog
 771         elog "This ebuild installed a version of php.ini based on php.ini-${PHP_INI_VERSION} version."
 772         elog "You can chose which version of php.ini to install by default by setting PHP_INI_VERSION to either"
 773         elog "'production' or 'development' in ${EPREFIX}/etc/make.conf"
 774         elog "Both versions of php.ini can be found in ${EPREFIX}/usr/share/doc/${PF}"
 775
 776         elog
 777         elog "For more details on how minor version slotting works (PHP_TARGETS) please read the upgrade guide:"
 778         elog "https://www.gentoo.org/proj/en/php/php-upgrading.xml"
 779         elog
 780 }
 781
 782 pkg_prerm() {
 783         eselect php cleanup
 784 }