dev-lang/nqp/nqp-2019.07.1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit java-pkg-opt-2 multibuild
   7
   8 if [[ ${PV} == "9999" ]]; then
   9         EGIT_REPO_URI="https://github.com/perl6/${PN}.git"
  10         inherit git-r3
  11         KEYWORDS=""
  12 else
  13         SRC_URI="https://github.com/perl6/${PN}/releases/download/${PV}/${P}.tar.gz"
  14         KEYWORDS="~amd64 ~x86"
  15 fi
  16
  17 DESCRIPTION="Not Quite Perl, a Perl 6 bootstrapping compiler"
  18 HOMEPAGE="https://rakudo.org"
  19
  20 LICENSE="Artistic-2"
  21 SLOT="0"
  22 IUSE="doc clang java +moar test"
  23 RESTRICT="!test? ( test )"
  24 REQUIRED_USE="|| ( java moar )"
  25
  26 CDEPEND="java? (
  27                 dev-java/asm:4
  28                 dev-java/jline:0
  29                 dev-java/jna:4
  30         )
  31         moar? ( ~dev-lang/moarvm-${PV}[clang=] )"
  32 RDEPEND="${CDEPEND}
  33         java? ( >=virtual/jre-1.8 )"
  34 DEPEND="${CDEPEND}"
  35 BDEPEND="${CDEPEND}
  36         clang? ( sys-devel/clang )
  37         java? ( >=virtual/jdk-1.8 )
  38         dev-lang/perl"
  39
  40 pkg_pretend() {
  41         if has_version dev-lang/rakudo || has_version dev-lang/nqp; then
  42                 ewarn "NQP is known to fail compilation/installation with Rakudo and/or NQP"
  43                 ewarn "already being installed. So if it fails, try uninstalling both"
  44                 ewarn "dev-lang/nqp and dev-lang/rakudo, then do a new installation."
  45                 ewarn "(see Bug #584394)"
  46         fi
  47 }
  48
  49 java_prepare() {
  50         # Don't clean stage0 jars.
  51         einfo "Cleaning upstream jars"
  52         java-pkg_clean 3rdparty/
  53
  54         # Don't use jars we just deleted.
  55         sed -i -r 's/(:3rdparty[^:]*)+/:${THIRDPARTY_JARS}/g' \
  56                 src/vm/jvm/runners/nqp-j || die
  57 }
  58
  59 src_prepare() {
  60         MULTIBUILD_VARIANTS=()
  61         use moar && MULTIBUILD_VARIANTS+=( moar )
  62         use java && MULTIBUILD_VARIANTS+=( jvm )
  63
  64         multibuild_copy_sources
  65
  66         # This will pull in conditional java_prepare
  67         default
  68 }
  69
  70 nqp_configure() {
  71         pushd "${BUILD_DIR}" > /dev/null || die
  72         local myconfargs=(
  73                 "--backend=${MULTIBUILD_VARIANT}"
  74                 "--prefix=${EPREFIX}/usr" )
  75
  76         perl Configure.pl "${myconfargs[@]}" || die
  77         popd || die
  78 }
  79
  80 nqp_compile() {
  81         if [[ "${MULTIBUILD_VARIANT}" = jvm ]]; then
  82                 emake -j1 \
  83                         -C "${BUILD_DIR}" \
  84                         THIRDPARTY_JARS=$(java-pkg_getjars --with-dependencies asm-4,jline,jna-4) \
  85                         JAVAC="$(java-pkg_get-javac) $(java-pkg_javac-args)"
  86         elif [[ "${MULTIBUILD_VARIANT}" = moar ]]; then
  87                 emake -j1 \
  88                         -C "${BUILD_DIR}"
  89         fi
  90 }
  91
  92 nqp_test() {
  93         emake -j1 \
  94                 -C "${BUILD_DIR}" \
  95                 test
  96 }
  97
  98 nqp_install() {
  99         # This is the actual reason we need multibuild.eclass.
 100         # We need to distinguish the install procedure for MoarVM and JVM backends.
 101         case "${MULTIBUILD_VARIANT}" in
 102                 moar)
 103                         emake \
 104                                 DESTDIR="${ED}" \
 105                                 -C "${BUILD_DIR}" \
 106                                 install
 107                         ;;
 108                 jvm)
 109                         pushd "${BUILD_DIR}" > /dev/null || die
 110                         # Set JAVA_PKG_JARDEST early.
 111                         java-pkg_init_paths_
 112
 113                         # Upstream sets the classpath to this location. Perhaps it's
 114                         # used to locate the additional libraries?
 115                         java-pkg_addcp "${JAVA_PKG_JARDEST}"
 116
 117                         insinto "${JAVA_PKG_JARDEST}"
 118                         local jar
 119
 120                         for jar in *.jar; do
 121                                 if has ${jar} ${PN}.jar ${PN}-runtime.jar; then
 122                                         # jars for NQP itself.
 123                                         java-pkg_dojar ${jar}
 124                                 else
 125                                         # jars used by NQP.
 126                                         doins ${jar}
 127                                 fi
 128                         done
 129
 130                         # Upstream uses -Xbootclasspath/a, which is faster due to lack
 131                         # of verification, but gjl isn't flexible enough yet. :(
 132                         java-pkg_dolauncher ${PN}-j --main ${PN}
 133                         dosym ${PN}-j /usr/bin/${PN}
 134                         dobin tools/jvm/eval-client.pl
 135                         popd > /dev/null || die
 136                         ;;
 137                 *)
 138                         die "Unknown MULTIBUILD_VARIANT ${MULTIBUILD_VARIANT}."
 139                         ;;
 140         esac
 141 }
 142
 143 src_configure() {
 144         multibuild_foreach_variant nqp_configure
 145 }
 146
 147 src_compile() {
 148         multibuild_foreach_variant nqp_compile
 149 }
 150
 151 src_test() {
 152         multibuild_foreach_variant nqp_test
 153 }
 154
 155 src_install() {
 156         multibuild_foreach_variant nqp_install
 157
 158         dodoc CREDITS README.pod
 159         use doc && dodoc -r docs/*
 160 }