dev-lang/mono/mono-6.6.0.161.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 KEYWORDS="amd64 ~arm ~arm64 ~ppc ~ppc64 x86 ~amd64-linux"
   7
   8 SLOT="0"
   9
  10 IUSE="nls minimal pax_kernel xen doc"
  11
  12 inherit autotools eutils linux-info mono-env flag-o-matic pax-utils multilib-minimal
  13
  14 DESCRIPTION="Mono runtime and class libraries, a C# compiler/interpreter"
  15 HOMEPAGE="http://www.mono-project.com/Main_Page"
  16 LICENSE="MIT LGPL-2.1 GPL-2 BSD-4 NPL-1.1 Ms-PL GPL-2-with-linking-exception IDPL"
  17
  18 SRC_URI="http://download.mono-project.com/sources/mono/${P}.tar.xz"
  19
  20 #Note: mono works incorrect with older versions of libgdiplus
  21 #details on dotnet overlay issue: https://github.com/gentoo/dotnet/issues/429
  22 COMMONDEPEND="
  23         !minimal? ( >=dev-dotnet/libgdiplus-6.0.2 )
  24         ia64? ( sys-libs/libunwind )
  25         nls? ( sys-devel/gettext )
  26 "
  27 RDEPEND="${COMMONDEPEND}"
  28 DEPEND="${COMMONDEPEND}
  29         sys-devel/bc
  30         virtual/yacc
  31         pax_kernel? ( sys-apps/elfix )
  32         dev-util/cmake
  33 "
  34
  35 PATCHES=(
  36         "${FILESDIR}"/${PN}-5.0.1.1-x86_32.patch
  37         "${FILESDIR}"/mono-5.12-try-catch.patch
  38 )
  39
  40 pkg_pretend() {
  41         linux-info_pkg_setup
  42         if use kernel_linux; then
  43                 if linux_config_exists; then
  44                         linux_chkconfig_builtin SYSVIPC || die "SYSVIPC not enabled in the kernel"
  45                 else
  46                         # https://github.com/gentoo/gentoo/blob/f200e625bda8de696a28338318c9005b69e34710/eclass/linux-info.eclass#L686
  47                         ewarn "kernel config not found"
  48                         ewarn "If CONFIG_SYSVIPC is not set in your kernel .config, mono will hang while compiling."
  49                         ewarn "See https://bugs.gentoo.org/261869 for more info."
  50                 fi
  51         fi
  52 }
  53
  54 pkg_setup() {
  55         mono-env_pkg_setup
  56 }
  57
  58 src_prepare() {
  59         # we need to sed in the paxctl-ng -mr in the runtime/mono-wrapper.in so it don't
  60         # get killed in the build proces when MPROTECT is enable. #286280
  61         # RANDMMAP kill the build proces to #347365
  62         # use paxmark.sh to get PT/XT logic #532244
  63         if use pax_kernel ; then
  64                 ewarn "We are disabling MPROTECT on the mono binary."
  65
  66                 # issue 9 : https://github.com/Heather/gentoo-dotnet/issues/9
  67                 sed '/exec "/ i\paxmark.sh -mr "$r/@mono_runtime@"' -i "${S}"/runtime/mono-wrapper.in || die "Failed to sed mono-wrapper.in"
  68         fi
  69
  70         # mono build system can fail otherwise
  71         strip-flags
  72
  73         default
  74
  75         # PATCHES contains configure.ac patch
  76         eautoreconf
  77         multilib_copy_sources
  78 }
  79
  80 multilib_src_configure() {
  81         local myeconfargs=(
  82                 $(use_with xen xen_opt)
  83                 --without-ikvm-native
  84                 --disable-dtrace
  85                 $(use_with doc mcs-docs)
  86                 $(use_enable nls)
  87         )
  88
  89         econf "${myeconfargs[@]}"
  90 }
  91
  92 multilib_src_test() {
  93         cd mcs/tests || die
  94         emake check
  95 }
  96
  97 multilib_src_install() {
  98         default_src_install
  99
 100         # Remove files not respecting LDFLAGS and that we are not supposed to provide, see Fedora
 101         # mono.spec and http://www.mail-archive.com/mono-devel-list@lists.ximian.com/msg24870.html
 102         # for reference.
 103         rm -f "${ED}"/usr/lib/mono/{2.0,4.5}/mscorlib.dll.so || die
 104         rm -f "${ED}"/usr/lib/mono/{2.0,4.5}/mcs.exe.so || die
 105 }