dev-lang/luajit/luajit-2.1.0_beta3.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit pax-utils toolchain-funcs versionator
   7
   8 MY_PV="$(get_version_component_range 1-4)"
   9 MY_PV="${MY_PV/_beta/-beta}"
  10 MY_P="LuaJIT-${MY_PV}"
  11
  12 DESCRIPTION="Just-In-Time Compiler for the Lua programming language"
  13 HOMEPAGE="http://luajit.org/"
  14 SRC_URI="http://luajit.org/download/${MY_P}.tar.gz"
  15
  16 LICENSE="MIT"
  17 # this should probably be pkgmoved to 2.0 for sake of consistency.
  18 SLOT="2"
  19 KEYWORDS=""
  20 IUSE="lua52compat static-libs"
  21
  22 PATCHES=( "${FILESDIR}/${PN}-2-ldconfig.patch" )
  23
  24 S="${WORKDIR}/${MY_P}"
  25
  26 _emake() {
  27         emake \
  28                 Q= \
  29                 PREFIX="${EPREFIX}/usr" \
  30                 MULTILIB="$(get_libdir)" \
  31                 DESTDIR="${D}" \
  32                 HOST_CC="$(tc-getBUILD_CC)" \
  33                 STATIC_CC="$(tc-getCC)" \
  34                 DYNAMIC_CC="$(tc-getCC) -fPIC" \
  35                 TARGET_LD="$(tc-getCC)" \
  36                 TARGET_AR="$(tc-getAR) rcus" \
  37                 BUILDMODE="$(usex static-libs mixed dynamic)" \
  38                 TARGET_STRIP="true" \
  39                 INSTALL_LIB="${ED%/}/usr/$(get_libdir)" \
  40                 "$@"
  41 }
  42
  43 src_compile() {
  44         _emake XCFLAGS="$(usex lua52compat "-DLUAJIT_ENABLE_LUA52COMPAT" "")"
  45 }
  46
  47 src_install() {
  48         _emake install
  49
  50         pax-mark m "${ED}usr/bin/luajit-${MY_PV}"
  51
  52         HTML_DOCS="doc/." einstalldocs
  53 }