dev-lang/luajit/luajit-2.0.5-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit pax-utils toolchain-funcs versionator
   7
   8 MY_PV="$(get_version_component_range 1-3)"
   9 MY_P="LuaJIT-${MY_PV}"
  10 if [[ -n $(get_version_component_range 4) ]]; then
  11         HOTFIX="v${PV}"
  12         HOTFIX="${HOTFIX/_p/_hotfix}.patch"
  13 fi
  14
  15 DESCRIPTION="Just-In-Time Compiler for the Lua programming language"
  16 HOMEPAGE="http://luajit.org/"
  17 SRC_URI="http://luajit.org/download/${MY_P}.tar.gz
  18         ${HOTFIX:+http://luajit.org/download/${HOTFIX}}"
  19
  20 LICENSE="MIT"
  21 # this should probably be pkgmoved to 2.0 for sake of consistency.
  22 SLOT="2"
  23 KEYWORDS="amd64 arm ppc x86 ~amd64-linux ~x86-linux"
  24 IUSE="lua52compat static-libs"
  25
  26 PATCHES=( "${FILESDIR}/${PN}-2-ldconfig.patch" )
  27
  28 S="${WORKDIR}/${MY_P}"
  29
  30 src_prepare() {
  31         if [[ -n ${HOTFIX} ]]; then
  32                 eapply "${DISTDIR}/${HOTFIX}"
  33         fi
  34         default
  35 }
  36
  37 _emake() {
  38         emake \
  39                 Q= \
  40                 PREFIX="${EPREFIX}/usr" \
  41                 MULTILIB="$(get_libdir)" \
  42                 DESTDIR="${D}" \
  43                 HOST_CC="$(tc-getBUILD_CC)" \
  44                 STATIC_CC="$(tc-getCC)" \
  45                 DYNAMIC_CC="$(tc-getCC) -fPIC" \
  46                 TARGET_LD="$(tc-getCC)" \
  47                 TARGET_AR="$(tc-getAR) rcus" \
  48                 BUILDMODE="$(usex static-libs mixed dynamic)" \
  49                 TARGET_STRIP="true" \
  50                 INSTALL_LIB="${ED%/}/usr/$(get_libdir)" \
  51                 "$@"
  52 }
  53
  54 src_compile() {
  55         _emake XCFLAGS="$(usex lua52compat "-DLUAJIT_ENABLE_LUA52COMPAT" "")"
  56 }
  57
  58 src_install() {
  59         _emake install
  60
  61         pax-mark m "${ED}usr/bin/luajit-${MY_PV}"
  62
  63         HTML_DOCS="doc/." einstalldocs
  64 }