dev-lang/execline/execline-2.3.0.3.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit versionator
   7
   8 DESCRIPTION="a non-interactive scripting language"
   9 HOMEPAGE="https://www.skarnet.org/software/execline/"
  10 SRC_URI="https://www.skarnet.org/software/${PN}/${P}.tar.gz"
  11
  12 LICENSE="ISC"
  13 SLOT="0/$(get_version_component_range 1-2)"
  14 KEYWORDS="~amd64 ~arm ~x86"
  15 IUSE="static static-libs"
  16
  17 DEPEND=">=sys-devel/make-3.81
  18         static? (
  19                 >=dev-libs/skalibs-2.6.0.1[static-libs]
  20         )
  21         !static? (
  22                 >=dev-libs/skalibs-2.6.0.1
  23         )
  24 "
  25 RDEPEND="
  26         !static? (
  27                 >=dev-libs/skalibs-2.6.0.1:=
  28         )
  29 "
  30
  31 HTML_DOCS="doc/*"
  32
  33 src_prepare() {
  34         default
  35
  36         # Remove QA warning about LDFLAGS addition
  37         sed -i "s/tryldflag LDFLAGS_AUTO -Wl,--hash-style=both/:/" "${S}/configure" || die
  38
  39         # configure overrides gentoo's -fstack-protector default
  40         sed -i "/^tryflag CFLAGS -fno-stack-protector$/d" "${S}/configure" || die
  41 }
  42
  43 src_configure() {
  44         econf \
  45                 --bindir=/bin \
  46                 --dynlibdir=/$(get_libdir) \
  47                 --libdir=/usr/$(get_libdir)/${PN} \
  48                 --with-dynlib=/$(get_libdir) \
  49                 --with-lib=/usr/$(get_libdir)/skalibs \
  50                 --with-sysdeps=/usr/$(get_libdir)/skalibs \
  51                 $(use_enable !static shared) \
  52                 $(use_enable static allstatic) \
  53                 $(use_enable static static-libc) \
  54                 $(use_enable static-libs static)
  55 }