dev-java/zemberek/zemberek-2.1.1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=2
   5 JAVA_PKG_IUSE="source doc test"
   6
   7 inherit eutils java-pkg-2 java-ant-2
   8
   9 DESCRIPTION="Zemberek NLP library"
  10 HOMEPAGE="https://github.com/ahmetaa/zemberek-nlp"
  11 SRC_URI="https://${PN}.googlecode.com/files/${P}-nolibs-src.zip"
  12
  13 LICENSE="MPL-1.1"
  14 SLOT="0"
  15 KEYWORDS="amd64 ppc64 x86"
  16 LANGS="tr tk"
  17
  18 S=${WORKDIR}/${P}-nolibs-src
  19
  20 IUSE="l10n_tk +l10n_tr"
  21
  22 RDEPEND=">=virtual/jre-1.5"
  23
  24 DEPEND=">=virtual/jdk-1.5
  25         test?
  26         (
  27                 dev-java/junit:4
  28                 dev-java/ant-junit4
  29                 dev-java/hamcrest-core
  30         )
  31         app-arch/unzip"
  32
  33 java_prepare() {
  34         use test && java-pkg_jarfrom --build-only --into lib/gelistirme junit-4 junit.jar
  35         # Added hamcrest-core as a workaround
  36         # Issue spotted by Markus Meier <maekke@gentoo.org>
  37         # See https://bugs.gentoo.org/show_bug.cgi?id=253753#c3
  38         use test && java-pkg_jarfrom --build-only --into lib/gelistirme hamcrest-core
  39         epatch "${FILESDIR}"/${P}-classpathfix.patch
  40 }
  41
  42 src_compile() {
  43         local anttargs langs="" jar
  44         for jar in ${LANGS}; do
  45                 use l10n_${jar} && langs+=" ${jar}"
  46         done
  47         for jar in cekirdek demo ${langs}; do
  48                 anttargs="${anttargs} jar-${jar}"
  49         done
  50         eant ${anttargs} $(use_doc javadocs)
  51 }
  52
  53 src_install() {
  54         local sourcetrees="" langs="" jar
  55         for jar in ${LANGS}; do
  56                 use l10n_${jar} && langs+=" ${jar}"
  57         done
  58         for jar in cekirdek demo ${langs}; do
  59                 java-pkg_newjar dagitim/jar/zemberek-${jar}-${PV}.jar zemberek2-${jar}.jar
  60                 sourcetrees="${sourcetrees} src/${jar}/net"
  61         done
  62         use source && java-pkg_dosrc ${sourcetrees}
  63         use doc && java-pkg_dojavadoc build/java-docs/api
  64         java-pkg_dolauncher zemberek-demo --main net.zemberek.demo.DemoMain
  65         dodoc dokuman/lisanslar/* || die
  66         dodoc surumler.txt || die
  67 }
  68
  69 src_test() {
  70         ANT_TASKS="ant-junit4" eant unit-test
  71 }