dev-java/xalan-serializer/xalan-serializer-2.7.2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 JAVA_PKG_IUSE="doc source"
   7
   8 inherit java-pkg-2 java-ant-2 versionator
   9
  10 MY_PN="xalan-j"
  11 MY_PV="$(replace_all_version_separators _)"
  12 MY_P="${MY_PN}_${MY_PV}"
  13
  14 DESCRIPTION="DOM Level 3 serializer from Apache Xalan, shared by Xalan and Xerces"
  15 HOMEPAGE="http://xalan.apache.org/"
  16 SRC_URI="mirror://apache/xalan/${MY_PN}/source/${MY_P}-src.tar.gz"
  17 LICENSE="Apache-2.0"
  18 SLOT="0"
  19 KEYWORDS="amd64 ~arm arm64 ppc64 x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  20
  21 RDEPEND=">=virtual/jre-1.3"
  22 DEPEND=">=virtual/jdk-1.3"
  23
  24 EANT_BUILD_TARGET="serializer.jar"
  25 EANT_DOC_TARGET="serializer.javadocs"
  26
  27 S="${WORKDIR}/${MY_P}"
  28
  29 java_prepare() {
  30         # kill all non-serializer sources to ease javadocs and dosrc
  31         find src/org/ -type f ! -path "src/org/apache/xml/serializer/*" -delete || die
  32
  33         # remove bundled jars
  34         find -name "*.jar" -delete || die
  35         rm src/*.tar.gz || die
  36 }
  37
  38 src_install() {
  39         java-pkg_dojar build/serializer.jar
  40
  41         use doc && java-pkg_dojavadoc build/docs/apidocs
  42         use source && java-pkg_dosrc src/org
  43 }