dev-java/tomcat-servlet-api/tomcat-servlet-api-7.0.94.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="6"
   5 JAVA_PKG_IUSE="source"
   6
   7 inherit eutils java-pkg-2 java-ant-2
   8
   9 MY_A="apache-${P}-src"
  10 MY_P="${MY_A/-servlet-api/}"
  11 DESCRIPTION="Tomcat's Servlet API 3.0/JSP API 2.2 implementation"
  12 HOMEPAGE="https://tomcat.apache.org/"
  13 SRC_URI="mirror://apache/tomcat/tomcat-7/v${PV}/src/${MY_P}.tar.gz"
  14
  15 LICENSE="Apache-2.0"
  16 SLOT="3.0"
  17 KEYWORDS="amd64 ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux ~x64-solaris ~x86-solaris"
  18 IUSE=""
  19
  20 DEPEND=">=virtual/jdk-1.6"
  21 RDEPEND=">=virtual/jre-1.6"
  22
  23 S="${WORKDIR}/${MY_P}/"
  24
  25 src_prepare() {
  26         default
  27
  28         cp "${FILESDIR}/${SLOT}-build.xml" build.xml || die "Could not replace build.xml"
  29         rm -fR */*/build.xml ||die
  30         java-pkg_clean
  31
  32         java-pkg-2_src_prepare
  33 }
  34
  35 src_install() {
  36         java-pkg_dojar "${S}"/output/build/lib/*.jar
  37         use source && java-pkg_dosrc java/javax/servlet/
  38 }