dev-java/tomcat-servlet-api/tomcat-servlet-api-6.0.53-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 JAVA_PKG_IUSE="source"
   6
   7 inherit eutils java-pkg-2 java-ant-2
   8
   9 MY_A="apache-${P}-src"
  10 MY_P="${MY_A/-servlet-api/}"
  11 DESCRIPTION="Tomcat's Servlet API 2.5/JSP API 2.1 implementation"
  12 HOMEPAGE="https://tomcat.apache.org/"
  13 SRC_URI="https://archive.apache.org/dist/tomcat/tomcat-6/v${PV}/src/${MY_P}.tar.gz"
  14
  15 LICENSE="Apache-2.0"
  16 SLOT="2.5"
  17 KEYWORDS="amd64 ~arm ppc64 x86 ~amd64-linux ~x86-linux ~x64-macos ~x64-solaris ~x86-solaris"
  18 IUSE=""
  19
  20 DEPEND=">=virtual/jdk-1.8"
  21 RDEPEND=">=virtual/jre-1.8"
  22
  23 S="${WORKDIR}/${MY_P}"
  24
  25 src_prepare() {
  26         default
  27
  28         cp "${FILESDIR}/${SLOT}-build-r1.xml" build.xml || die "Could not replace build.xml"
  29         rm -r */*/build.xml java/javax/{annotation,ejb,mail,persistence,xml}/ || die
  30         find -name '*.jar' -delete || die
  31 }
  32
  33 src_install() {
  34         java-pkg_dojar "${S}"/output/build/lib/*.jar
  35         use source && java-pkg_dosrc java/javax
  36 }