dev-java/tomcat-jstl-compat/tomcat-jstl-compat-1.2.5-r1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 JAVA_PKG_IUSE="doc source"
   7
   8 inherit java-pkg-2 java-ant-2 eutils
   9
  10 MY_PN="taglibs-standard"
  11 MY_P="${MY_PN}-${PV}"
  12 MY_COMPAT="${MY_PN}-compat"
  13
  14 DESCRIPTION="JSP Standard Tag Library (JSTL) - Compat jar"
  15 HOMEPAGE="https://tomcat.apache.org/taglibs/standard/"
  16 SRC_URI="http://apache.mirrors.ovh.net/ftp.apache.org/dist/tomcat/taglibs/${MY_P}/${MY_P}-source-release.zip"
  17
  18 LICENSE="Apache-2.0"
  19 SLOT="0"
  20 KEYWORDS="amd64 x86"
  21 IUSE="test"
  22
  23 CDEPEND="java-virtuals/servlet-api:3.0
  24         dev-java/tomcat-jstl-spec:0
  25         dev-java/tomcat-jstl-impl:0"
  26 RDEPEND=">=virtual/jre-1.6
  27         ${CDEPEND}"
  28 DEPEND=">=virtual/jdk-1.6
  29         test? (
  30                 dev-java/ant-junit:0
  31                 dev-java/easymock:3.2
  32         )
  33         ${CDEPEND}"
  34
  35 S="${WORKDIR}/${MY_P}"
  36
  37 JAVA_ANT_REWRITE_CLASSPATH="yes"
  38 EANT_GENTOO_CLASSPATH="servlet-api-3.0,tomcat-jstl-spec,tomcat-jstl-impl"
  39 EANT_BUILD_TARGET="package"
  40 EANT_BUILD_XML="compat/build.xml"
  41
  42 java_prepare() {
  43         cp "${FILESDIR}"/${P}-build.xml "${S}"/compat/build.xml
  44 }
  45
  46 EANT_TEST_TARGET="test"
  47 EANT_TEST_GENTOO_CLASSPATH="${EANT_GENTOO_CLASSPATH},easymock-3.2"
  48
  49 src_test() {
  50         java-pkg-2_src_test
  51 }
  52
  53 src_install() {
  54         java-pkg_newjar "${S}"/compat/target/${MY_COMPAT}-${PV}.jar ${MY_COMPAT}.jar
  55
  56         if use doc; then
  57                 java-pkg_dohtml -r "${S}"/compat/target/site/apidocs/
  58         fi
  59
  60         if use source; then
  61                 java-pkg_dosrc "${S}"/compat/src/*
  62         fi
  63 }