dev-java/swingx-ws/swingx-ws-1.0-r1.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 JAVA_PKG_IUSE="doc source"
   7
   8 inherit java-pkg-2 java-pkg-simple
   9
  10 DESCRIPTION="Utilities and widgets to integrate Swing GUIs with web applications"
  11 HOMEPAGE="https://java.net/projects/swingx-ws/"
  12 SRC_URI="http://central.maven.org/maven2/org/swinglabs/${PN}/${PV}/${P}-sources.jar"
  13 LICENSE="LGPL-2.1"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86"
  16
  17 CP_DEPEND="
  18         dev-java/commons-httpclient:3
  19         dev-java/jdom:0
  20         dev-java/json:0
  21         dev-java/jtidy:0
  22         dev-java/rome:0
  23         dev-java/swingx:1.6
  24         dev-java/swingx-beaninfo:0
  25         dev-java/xerces:2
  26         dev-java/xml-commons-external:1.4"
  27
  28 RDEPEND="
  29         ${CP_DEPEND}
  30         >=virtual/jre-1.6"
  31
  32 DEPEND="
  33         ${CP_DEPEND}
  34         >=virtual/jdk-1.6
  35         app-arch/unzip"
  36
  37 src_prepare() {
  38         default
  39
  40         # Fixes for newer swingx-beaninfo.
  41         sed -i "s:BeanInfoSupport:org.jdesktop.beans.\0:g" org/jdesktop/swingx/*.java || die
  42         find -name "*.java" -exec sed -i -r "s:org\.jdesktop\.swingx\.(editors|BeanInfoSupport|EnumerationValue):org.jdesktop.beans.\1:g" {} + || die
  43
  44         # GraphicsUtilities moved in later SwingX versions.
  45         sed -i "s:org\.jdesktop\.swingx\.graphics\.GraphicsUtilities:org.jdesktop.swingx.util.GraphicsUtilities:g" \
  46                 org/jdesktop/swingx/mapviewer/AbstractTileFactory.java || die
  47
  48         java-pkg-2_src_prepare
  49 }
  50
  51 src_compile() {
  52         java-pkg-simple_src_compile
  53         java-pkg_addres ${PN}.jar .
  54 }