dev-java/sun-jms/sun-jms-1.1-r2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit java-pkg-2
   7
   8 DOWNLOAD_PAGE="http://download.oracle.com/otndocs/jcp/7542-jms-1.1-fr-doc-oth-JSpec/"
   9 At="jms-${PV/./_}-fr-apidocs.zip"
  10
  11 DESCRIPTION="The Java Message Service (JMS) API"
  12 HOMEPAGE="http://java.sun.com/products/jms/"
  13 SRC_URI="${At}"
  14
  15 LICENSE="sun-bcla-jms"
  16 SLOT=0
  17 KEYWORDS="amd64 ppc64 x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris ~x86-solaris"
  18 IUSE="doc"
  19
  20 RDEPEND=">=virtual/jre-1.3"
  21 DEPEND="app-arch/unzip
  22         >=virtual/jdk-1.3"
  23
  24 RESTRICT="bindist fetch"
  25
  26 S="${WORKDIR}/${PN//sun-/}${PV}"
  27
  28 pkg_nofetch() {
  29         einfo
  30         einfo " Due to license restrictions, we cannot fetch the"
  31         einfo " distributables automagically."
  32         einfo
  33         einfo " 1. Visit ${DOWNLOAD_PAGE}"
  34         einfo " 2. Accept the License Agreement"
  35         einfo " 3. Download ${At}"
  36         einfo " 4. Move the file to your DISTDIR directory"
  37         einfo
  38 }
  39
  40 src_prepare() {
  41         default
  42         rm -v lib/*.jar || die
  43 }
  44
  45 src_compile() {
  46         mkdir build || die
  47         cd src/share || die
  48         ejavac -nowarn -d "${S}"/build $(find . -name "*.java") || die
  49         if use doc ; then
  50                 mkdir "${S}"/api || die
  51                 javadoc -d "${S}"/api -quiet javax.jms || die
  52         fi
  53
  54         cd "${S}" || die
  55         jar cf jms.jar -C build . || die
  56 }
  57
  58 src_install() {
  59         java-pkg_dojar jms.jar
  60         use doc && java-pkg_dohtml -r api
  61 }