dev-java/spring-expression/spring-expression-3.2.4.ebuild

   1 # Copyright 1999-2013 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="5"
   6
   7 JAVA_PKG_IUSE="doc source test"
   8
   9 inherit java-pkg-2 java-ant-2
  10
  11 DESCRIPTION="A comprehensive programming and configuration model for modern Java-based enterprise applications"
  12 HOMEPAGE="http://www.springsource.org/spring-framework"
  13 SRC_URI="https://github.com/SpringSource/spring-framework/archive/v${PV}.RELEASE.tar.gz -> spring-framework-${PV}.tar.gz
  14                 https://dev.gentoo.org/~ercpe/distfiles/dev-java/spring-framework/spring-framework-${PV}-buildscripts.tar.bz2"
  15
  16 LICENSE="Apache-2.0"
  17 SLOT="3.2"
  18 KEYWORDS="~amd64 ~x86"
  19
  20 IUSE=""
  21
  22 CDEPEND="dev-java/spring-core:${SLOT}"
  23
  24 DEPEND=">=virtual/jdk-1.7
  25         test? (
  26                 dev-java/hamcrest-core:1.3
  27                 dev-java/hamcrest-library:1.3
  28                 dev-java/junit:4
  29                 dev-java/mockito:0
  30                 dev-java/ant-junit4:0
  31                 dev-java/xmlunit:1
  32         )
  33         ${CDEPEND}"
  34
  35 RDEPEND=">=virtual/jre-1.7
  36         ${CDEPEND}"
  37
  38 S="${WORKDIR}/spring-framework-${PV}.RELEASE/"
  39
  40 EANT_BUILD_XML=${S}/${PN}/build.xml
  41 JAVA_ANT_REWRITE_CLASSPATH="true"
  42
  43 EANT_GENTOO_CLASSPATH="spring-core-${SLOT}"
  44
  45 EANT_TEST_GENTOO_CLASSPATH="${EANT_GENTOO_CLASSPATH}
  46         hamcrest-library-1.3
  47         hamcrest-core-1.3
  48         junit-4
  49         mockito
  50         xmlunit-1"
  51
  52 src_install() {
  53         java-pkg_dojar "${S}"/${PN}/dist/${PN}.jar
  54
  55         use source && java-pkg_dosrc "${S}"/${PN}/src/main/java/org/
  56         use doc && java-pkg_dojavadoc "${S}"/${PN}/dist/apidocs/
  57 }
  58
  59 src_test() {
  60         java-pkg-2_src_test
  61 }