dev-java/snakeyaml/snakeyaml-1.16.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5
   6 JAVA_PKG_IUSE="doc source"
   7
   8 inherit java-pkg-2 java-pkg-simple vcs-snapshot
   9
  10 DESCRIPTION="A YAML 1.1 parser and emitter for Java 5"
  11 HOMEPAGE="https://bitbucket.org/asomov/snakeyaml"
  12 SRC_URI="https://bitbucket.org/asomov/${PN}/get/v${PV}.tar.bz2 -> ${P}.tar.bz2"
  13 LICENSE="Apache-2.0"
  14 SLOT="0"
  15 KEYWORDS="amd64 x86"
  16 IUSE="test"
  17 RESTRICT="!test? ( test )"
  18
  19 DEPEND=">=virtual/jdk-1.6
  20         test? (
  21                 dev-java/joda-time:0
  22                 dev-java/junit:4 )"
  23
  24 RDEPEND=">=virtual/jre-1.6"
  25
  26 S="${WORKDIR}/${P}"
  27 JAVA_SRC_DIR="src/main/java"
  28
  29 java_prepare() {
  30         # Remove some tests with tricky dependencies.
  31         rm -rv src/test/java/{examples/SpringTest.java,org/yaml/snakeyaml/{emitter/template/VelocityTest.java,issues/issue9}} || die
  32 }
  33
  34 src_install() {
  35         java-pkg-simple_src_install
  36         dodoc README.md src/etc/announcement.msg
  37 }
  38
  39 src_test() {
  40         local DIR="src/test/java"
  41         local CP="${DIR}/../resources:${DIR}:${PN}.jar:$(java-pkg_getjars joda-time,junit-4)"
  42
  43         local TESTS=$(find "${DIR}" -name "*Test.java" ! -name AbstractTest.java ! -name PyImportTest.java)
  44         TESTS="${TESTS//src\/test\/java\/}"
  45         TESTS="${TESTS//.java}"
  46         TESTS="${TESTS//\//.}"
  47
  48         ejavac -cp "${CP}" -d "${DIR}" $(find "${DIR}" -name "*.java")
  49         ejunit4 -classpath "${CP}" ${TESTS}
  50 }