dev-java/simplyhtml/simplyhtml-0.13.1-r1.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5 JAVA_PKG_IUSE="doc source"
   6 inherit versionator java-pkg-2 java-ant-2
   7
   8 MY_PN="SimplyHTML"
   9 MY_PV="$(replace_all_version_separators _)"
  10
  11 DESCRIPTION="Text processing application based on HTML and CSS files"
  12 HOMEPAGE="http://simplyhtml.sourceforge.net"
  13 SRC_URI="mirror://sourceforge/${PN}/${MY_PN}_src_${MY_PV}.tar.gz"
  14 LICENSE="GPL-2"
  15 SLOT="0"
  16 KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris"
  17 IUSE=""
  18
  19 CDEPEND="
  20         dev-java/javahelp:0
  21         dev-java/gnu-regexp:1"
  22
  23 DEPEND="
  24         ${CDEPEND}
  25         >=virtual/jdk-1.6"
  26
  27 RDEPEND="
  28         ${CDEPEND}
  29         >=virtual/jre-1.6"
  30
  31 S="${WORKDIR}/${PN}-${MY_PV}"
  32
  33 JAVA_PKG_FILTER_COMPILER="jikes"
  34 JAVA_ANT_REWRITE_CLASSPATH="yes"
  35
  36 EANT_GENTOO_CLASSPATH="
  37         javahelp
  38         gnu-regexp-1
  39 "
  40 EANT_BUILD_TARGET="jar"
  41 EANT_BUILD_XML="src/build.xml"
  42
  43 java_prepare() {
  44         # Avoid copying lib jars.
  45         sed -i '/copy file/d' src/build.xml || die
  46 }
  47
  48 src_install() {
  49         local my_jars=(
  50                 "${MY_PN}.jar"
  51                 "${MY_PN}Help.jar"
  52         )
  53
  54         for my_jar in "${my_jars[@]}"; do
  55                 java-pkg_dojar "dist/lib/${my_jar}"
  56         done
  57
  58         dodoc readme.txt
  59         use doc && java-pkg_dojavadoc dist/api
  60         use source && java-pkg_dosrc src/com src/de
  61 }