dev-java/relaxngcc/relaxngcc-1.12-r3.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="5"
   6
   7 JAVA_PKG_IUSE="doc examples source"
   8
   9 inherit java-pkg-2 java-ant-2
  10
  11 MY_DATE="20031218"
  12
  13 DESCRIPTION="RELAX NG Compiler Compiler"
  14 HOMEPAGE="http://relaxngcc.sourceforge.net/"
  15 SRC_URI="mirror://sourceforge/${PN}/${PN}-${MY_DATE}.zip"
  16
  17 LICENSE="Apache-2.0"
  18 SLOT="0"
  19 KEYWORDS="~amd64 ~x86 ~x86-fbsd"
  20 IUSE=""
  21
  22 RDEPEND=">=virtual/jre-1.6
  23         dev-java/msv:0
  24         dev-java/xsdlib:0
  25         dev-java/ant-core:0
  26         dev-java/iso-relax:0
  27         dev-java/relaxng-datatype:0"
  28
  29 DEPEND=">=virtual/jdk-1.6
  30         app-arch/unzip"
  31
  32 S="${WORKDIR}/${PN}-${MY_DATE}"
  33
  34 java_prepare() {
  35         mv relaxngcc.jar relaxngcc.orig.zip || die
  36
  37         rm -v *.jar || die
  38         rm -v sample/*/*.class || die
  39
  40         mkdir lib || die
  41         cd lib || die
  42
  43         java-pkg_jarfrom msv
  44         java-pkg_jarfrom xsdlib
  45         java-pkg_jarfrom ant-core
  46         java-pkg_jarfrom iso-relax
  47         java-pkg_jarfrom relaxng-datatype
  48
  49         cd "${S}" || die
  50
  51         cp "${FILESDIR}/build.xml-1.12-r1" build.xml || die "cp failed"
  52
  53         epatch \
  54                 "${FILESDIR}"/${PV}-*.patch \
  55                 "${FILESDIR}"/"${P}"-SwitchBlockInfo.java.patch
  56
  57         rm -rf "src/relaxngcc/maven"
  58         java-pkg_filter-compiler jikes
  59 }
  60
  61 EANT_DOC_TARGET=""
  62
  63 src_install() {
  64         java-pkg_dojar "${PN}".jar
  65
  66         use source && java-pkg_dosrc src/*
  67         use examples && java-pkg_doexamples sample
  68
  69         dodoc readme.txt
  70         use doc && dohtml -r doc/en/*
  71 }