dev-java/radeox/radeox-1.0_beta2-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 JAVA_PKG_IUSE="doc source"
   7
   8 inherit java-pkg-2 java-ant-2
   9
  10 MY_P="${P/_beta/-BETA-}"
  11 DESCRIPTION="Radeox Wiki render engine"
  12 HOMEPAGE="http://www.radeox.org"
  13 SRC_URI="ftp://snipsnap.org/radeox/${MY_P}-src.tgz"
  14
  15 LICENSE="LGPL-2.1+"
  16 SLOT="1"
  17 KEYWORDS="amd64 x86"
  18 IUSE=""
  19
  20 RDEPEND=">=virtual/jre-1.4:*
  21         =dev-java/commons-logging-1*:0"
  22 DEPEND=">=virtual/jdk-1.4
  23         ${RDEPEND}"
  24
  25 S=${WORKDIR}/${MY_P}
  26
  27 EANT_BUILD_TARGET="jar jar-api"
  28
  29 src_prepare() {
  30         default
  31
  32         # TOOD:
  33         # these would get bundled to the final jar
  34         # we should try to run the tests though
  35         rm -rf  src/org/radeox/example/ \
  36                 src/test/ src/org/radeox/test/ || die
  37
  38         rm -v lib/*.jar || die
  39         rm -v src/org/radeox/filter/*.class || die
  40         rm -v src/org/radeox/*/*/*.class || die
  41
  42         cd lib || die
  43         java-pkg_jar-from commons-logging
  44 }
  45
  46 src_install() {
  47         dodoc Changes.txt README Radeox.version
  48         use doc && java-pkg_dojavadoc docs/api
  49         use source && java-pkg_dosrc src/org
  50         java-pkg_dojar lib/{radeox,radeox-api}.jar
  51 }