dev-java/prefuse/prefuse-20071021_beta.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 JAVA_PKG_IUSE="doc examples source"
   7
   8 inherit java-pkg-2 java-ant-2
   9
  10 MY_PV=${PV/_beta/}
  11 MY_P=${PN}-beta-${MY_PV}
  12 DESCRIPTION="UI toolkit for building highly interactive visualizations of un-/structured data"
  13 SRC_URI="mirror://sourceforge/prefuse/${MY_P}.zip"
  14 HOMEPAGE="http://prefuse.org"
  15 LICENSE="BSD"
  16 SLOT="2006"
  17 KEYWORDS="amd64 x86"
  18
  19 COMMON_DEP="dev-java/lucene:1"
  20
  21 DEPEND=">=virtual/jdk-1.4
  22         ${COMMON_DEP}
  23         >=app-arch/unzip-5.50-r1"
  24 RDEPEND=">=virtual/jre-1.4
  25         ${COMMON_DEP}"
  26
  27 S=${WORKDIR}/${PN}-beta
  28
  29 java_prepare() {
  30         find lib/ -name "*.jar" | xargs rm -v
  31 }
  32
  33 src_compile() {
  34         java-pkg_filter-compiler jikes
  35         local targets="prefuse"
  36         use examples && targets="${targets} demos"
  37         eant $(use_doc api) ${targets} \
  38                 -Dlucene.lib=$(java-pkg_getjars lucene-1)
  39 }
  40
  41 src_install() {
  42         java-pkg_dojar build/${PN}.jar
  43
  44         dodoc readme.txt
  45         use doc && java-pkg_dojavadoc doc/api
  46         use source && java-pkg_dosrc src/*
  47         use examples && java-pkg_doexamples demos/*
  48 }