dev-java/openjdk-bin/openjdk-bin-8.252_p09.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit eapi7-ver java-vm-2
   7
   8 abi_uri() {
   9         echo "${2-$1}? (
  10                         https://github.com/AdoptOpenJDK/openjdk${SLOT}-binaries/releases/download/jdk${MY_PV}/OpenJDK8U-jdk_${1}_linux_hotspot_${MY_PV/-/}.tar.gz
  11                 )"
  12 }
  13
  14 MY_PV=$(ver_rs 1 'u' 2 '-' ${PV//p/b})
  15 SLOT="$(ver_cut 1)"
  16
  17 DESCRIPTION="Prebuilt Java JDK binaries provided by AdoptOpenJDK"
  18 HOMEPAGE="https://adoptopenjdk.net"
  19 SRC_URI="
  20         $(abi_uri aarch64 arm64)
  21         $(abi_uri arm)
  22         $(abi_uri ppc64le ppc64)
  23         $(abi_uri x64 amd64)
  24 "
  25
  26 LICENSE="GPL-2-with-classpath-exception"
  27 KEYWORDS="~amd64 ~arm ~arm64 ~ppc64"
  28
  29 IUSE="alsa cups examples headless-awt nsplugin selinux source webstart"
  30
  31 RDEPEND="
  32         media-libs/fontconfig:1.0
  33         media-libs/freetype:2
  34         >=sys-apps/baselayout-java-0.1.0-r1
  35         >=sys-libs/glibc-2.2.5:*
  36         sys-libs/zlib
  37         alsa? ( media-libs/alsa-lib )
  38         cups? ( net-print/cups )
  39         selinux? ( sec-policy/selinux-java )
  40         !headless-awt? (
  41                 x11-libs/libX11
  42                 x11-libs/libXext
  43                 x11-libs/libXi
  44                 x11-libs/libXrender
  45                 x11-libs/libXtst
  46         )"
  47
  48 PDEPEND="webstart? ( >=dev-java/icedtea-web-1.6.1:0 )
  49         nsplugin? ( >=dev-java/icedtea-web-1.6.1:0[nsplugin] )"
  50
  51 RESTRICT="preserve-libs strip"
  52 QA_PREBUILT="*"
  53
  54 S="${WORKDIR}/jdk${MY_PV}"
  55
  56 src_install() {
  57         local dest="/opt/${P}"
  58         local ddest="${ED%/}/${dest#/}"
  59
  60         rm ASSEMBLY_EXCEPTION LICENSE THIRD_PARTY_README || die
  61
  62         # this does not exist on arm64 hence -f
  63         rm -fv jre/lib/*/libfreetype.so* || die
  64
  65         if ! use alsa ; then
  66                 rm -v jre/lib/*/libjsoundalsa.so* || die
  67         fi
  68
  69         if ! use examples ; then
  70                 rm -vr sample || die
  71         fi
  72
  73         if use headless-awt ; then
  74                 rm -fvr {,jre/}lib/*/lib*{[jx]awt,splashscreen}* \
  75                         {,jre/}bin/policytool bin/appletviewer || die
  76         fi
  77
  78         if ! use source ; then
  79                 rm -v src.zip || die
  80         fi
  81
  82         rm -v jre/lib/security/cacerts || die
  83         dosym ../../../../../etc/ssl/certs/java/cacerts \
  84                 "${dest}"/jre/lib/security/cacerts
  85
  86         dodir "${dest}"
  87         cp -pPR * "${ddest}" || die
  88
  89         java-vm_install-env "${FILESDIR}"/${PN}-${SLOT}.env.sh
  90         java-vm_set-pax-markings "${ddest}"
  91         java-vm_revdep-mask
  92         java-vm_sandbox-predict /dev/random /proc/self/coredump_filter
  93 }