dev-java/openjdk/openjdk-8.242.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit check-reqs eapi7-ver flag-o-matic java-pkg-2 java-vm-2 multiprocessing pax-utils toolchain-funcs
   7
   8 MY_PV=$(ver_rs 1 'u' 2 '-' ${PV}-ga)
   9
  10 BASE_URI="https://hg.${PN}.java.net/jdk8u/jdk8u"
  11
  12 DESCRIPTION="Open source implementation of the Java programming language"
  13 HOMEPAGE="https://openjdk.java.net"
  14 SRC_URI="
  15         ${BASE_URI}/archive/jdk${MY_PV}.tar.bz2 -> ${P}.tar.bz2
  16         ${BASE_URI}/corba/archive/jdk${MY_PV}.tar.bz2 -> ${PN}-corba-${PV}.tar.bz2
  17         ${BASE_URI}/hotspot/archive/jdk${MY_PV}.tar.bz2 -> ${PN}-hotspot-${PV}.tar.bz2
  18         ${BASE_URI}/jaxp/archive/jdk${MY_PV}.tar.bz2 -> ${PN}-jaxp-${PV}.tar.bz2
  19         ${BASE_URI}/jaxws/archive/jdk${MY_PV}.tar.bz2 -> ${PN}-jaxws-${PV}.tar.bz2
  20         ${BASE_URI}/jdk/archive/jdk${MY_PV}.tar.bz2 -> ${PN}-jdk-${PV}.tar.bz2
  21         ${BASE_URI}/langtools/archive/jdk${MY_PV}.tar.bz2 -> ${PN}-langtools-${PV}.tar.bz2
  22         ${BASE_URI}/nashorn/archive/jdk${MY_PV}.tar.bz2 -> ${PN}-nashorn-${PV}.tar.bz2
  23 "
  24
  25 LICENSE="GPL-2"
  26 SLOT="$(ver_cut 1)"
  27 KEYWORDS="amd64 ppc64 ~x86"
  28 IUSE="alsa debug cups doc examples headless-awt +jbootstrap nsplugin +pch selinux source webstart"
  29
  30 COMMON_DEPEND="
  31         media-libs/freetype:2=
  32         media-libs/giflib:0/7
  33         sys-libs/zlib
  34 "
  35 # Many libs are required to build, but not to run, make is possible to remove
  36 # by listing conditionally in RDEPEND unconditionally in DEPEND
  37 RDEPEND="
  38         ${COMMON_DEPEND}
  39         >=sys-apps/baselayout-java-0.1.0-r1
  40         !headless-awt? (
  41                 x11-libs/libX11
  42                 x11-libs/libXext
  43                 x11-libs/libXi
  44                 x11-libs/libXrender
  45                 x11-libs/libXt
  46                 x11-libs/libXtst
  47         )
  48         alsa? ( media-libs/alsa-lib )
  49         cups? ( net-print/cups )
  50         selinux? ( sec-policy/selinux-java )
  51 "
  52
  53 DEPEND="
  54         ${COMMON_DEPEND}
  55         app-arch/zip
  56         media-libs/alsa-lib
  57         net-print/cups
  58         x11-base/xorg-proto
  59         x11-libs/libX11
  60         x11-libs/libXext
  61         x11-libs/libXi
  62         x11-libs/libXrender
  63         x11-libs/libXt
  64         x11-libs/libXtst
  65         || (
  66                 dev-java/openjdk-bin:${SLOT}
  67                 dev-java/icedtea-bin:${SLOT}
  68                 dev-java/openjdk:${SLOT}
  69                 dev-java/icedtea:${SLOT}
  70         )
  71 "
  72
  73 PDEPEND="
  74         webstart? ( >=dev-java/icedtea-web-1.6.1:0 )
  75         nsplugin? ( >=dev-java/icedtea-web-1.6.1:0[nsplugin] )
  76 "
  77
  78 S="${WORKDIR}/jdk${SLOT}u-jdk${MY_PV}"
  79
  80 # The space required to build varies wildly depending on USE flags,
  81 # ranging from 2GB to 16GB. This function is certainly not exact but
  82 # should be close enough to be useful.
  83 openjdk_check_requirements() {
  84         local M
  85         M=2048
  86         M=$(( $(usex debug 3 1) * $M ))
  87         M=$(( $(usex jbootstrap 2 1) * $M ))
  88         M=$(( $(usex doc 320 0) + $(usex source 128 0) + 192 + $M ))
  89
  90         CHECKREQS_DISK_BUILD=${M}M check-reqs_pkg_${EBUILD_PHASE}
  91 }
  92
  93 pkg_pretend() {
  94         openjdk_check_requirements
  95         has ccache ${FEATURES} && die "FEATURES=ccache doesn't work with ${PN}"
  96 }
  97
  98 pkg_setup() {
  99         openjdk_check_requirements
 100
 101         JAVA_PKG_WANT_BUILD_VM="openjdk-${SLOT} openjdk-bin-${SLOT} icedtea-${SLOT} icedtea-bin-${SLOT}"
 102         JAVA_PKG_WANT_SOURCE="${SLOT}"
 103         JAVA_PKG_WANT_TARGET="${SLOT}"
 104
 105         java-vm-2_pkg_setup
 106         java-pkg-2_pkg_setup
 107 }
 108
 109 src_prepare() {
 110         default
 111         chmod +x configure || die
 112         local repo
 113         for repo in corba hotspot jdk jaxp jaxws langtools nashorn; do
 114                 ln -s ../"${repo}-jdk${MY_PV}" "${repo}" || die
 115         done
 116         # new warnings in new gcc https://bugs.gentoo.org/685426
 117         sed -i '/^WARNINGS_ARE_ERRORS/ s/-Werror/-Wno-error/' \
 118                 hotspot/make/linux/makefiles/gcc.make || die
 119 }
 120
 121 src_configure() {
 122         # general build info found here:
 123         #https://hg.openjdk.java.net/jdk8/jdk8/raw-file/tip/README-builds.html
 124
 125         # Work around stack alignment issue, bug #647954.
 126         use x86 && append-flags -mincoming-stack-boundary=2
 127
 128         local myconf=(
 129                         --disable-ccache
 130                         --enable-unlimited-crypto
 131                         --with-boot-jdk="${JDK_HOME}"
 132                         --with-extra-cflags="${CFLAGS}"
 133                         --with-extra-cxxflags="${CXXFLAGS}"
 134                         --with-extra-ldflags="${LDFLAGS}"
 135                         --with-giflib=system
 136                         --with-jtreg=no
 137                         --with-jobs=1
 138                         --with-num-cores=1
 139                         --with-update-version="$(ver_cut 2)"
 140                         --with-build-number="b$(ver_cut 4)"
 141                         --with-milestone="fcs" # magic variable that means "release version"
 142                         --with-vendor-name="Gentoo"
 143                         --with-vendor-url="https://gentoo.org"
 144                         --with-vendor-bug-url="https://bugs.gentoo.org"
 145                         --with-vendor-vm-bug-url="https://bugs.openjdk.java.net"
 146                         --with-zlib=system
 147                         --with-native-debug-symbols=$(usex debug internal none)
 148                         $(usex headless-awt --disable-headful '')
 149                 )
 150
 151         # PaX breaks pch, bug #601016
 152         if use pch && ! host-is-pax; then
 153                 myconf+=( --enable-precompiled-headers )
 154         else
 155                 myconf+=( --disable-precompiled-headers )
 156         fi
 157
 158         (
 159                 unset _JAVA_OPTIONS JAVA JAVA_TOOL_OPTIONS JAVAC XARGS
 160                 CFLAGS= CXXFLAGS= LDFLAGS= \
 161                 CONFIG_SITE=/dev/null \
 162                 econf "${myconf[@]}"
 163         )
 164 }
 165
 166 src_compile() {
 167         local myemakeargs=(
 168                 JOBS=$(makeopts_jobs)
 169                 LOG=debug
 170                 $(usex doc docs '')
 171                 $(usex jbootstrap bootcycle-images images)
 172         )
 173         emake "${myemakeargs[@]}" -j1 #nowarn
 174 }
 175
 176 src_install() {
 177         local dest="/usr/$(get_libdir)/${PN}-${SLOT}"
 178         local ddest="${ED%/}/${dest#/}"
 179
 180         cd "${S}"/build/*-release/images/j2sdk-image || die
 181
 182         if ! use alsa; then
 183                 rm -v jre/lib/$(get_system_arch)/libjsoundalsa.* || die
 184         fi
 185
 186         # stupid build system does not remove that
 187         if use headless-awt ; then
 188                 rm -fvr jre/lib/$(get_system_arch)/lib*{[jx]awt,splashscreen}* \
 189                 {,jre/}bin/policytool bin/appletviewer || die
 190         fi
 191
 192         if ! use examples ; then
 193                 rm -vr demo/ || die
 194         fi
 195
 196         if ! use source ; then
 197                 rm -v src.zip || die
 198         fi
 199
 200         dodir "${dest}"
 201         cp -pPR * "${ddest}" || die
 202
 203         dosym ../../../../../../etc/ssl/certs/java/cacerts "${dest}"/jre/lib/security/cacerts
 204
 205         java-vm_install-env "${FILESDIR}"/${PN}-${SLOT}.env.sh
 206         java-vm_set-pax-markings "${ddest}"
 207         java-vm_revdep-mask
 208         java-vm_sandbox-predict /dev/random /proc/self/coredump_filter
 209
 210         if use doc ; then
 211                 docinto html
 212                 dodoc -r "${S}"/build/*-release/docs/*
 213         fi
 214 }
 215
 216 pkg_postinst() {
 217         java-vm-2_pkg_postinst
 218 }